Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ABMDBAN

ABMDBAN.m

Go to the documentation of this file. 
  1. ABMDBAN ; IHS/SD/SDR - 3P Billing Banner ; 
  1.  ;;2.6;IHS Third Party Billing;**1,9,27**;NOV 12, 2009;Build 486
  1.  ;ORIGINAL - TMD, BILLINGS AREA OFFICE
  1.  ;
  1.  ;IHS/SD/SDR 2.5*12 UFMS If user is logged into cashiering session and they are exiting TPB they should get a message letting
  1.  ;   them know they are still logged in.  Also added warning msg for "outstanding" open and closed sessions.
  1.  ;
  1.  ;IHS/SD/SDR 2.6*1 NO HEAT Added patch# to menu header
  1.  ;IHS/SD/SDR 2.6*27 CR8894 Added check for 3P Fee Table cleanup/correction message
  1.  ;
  1.  S ABMM(0)=$S($D(Y(0)):$P(Y(0),U,2),$D(XQY0):$P(XQY0,U,2),1:$P($G(^XUTL("XQ",$J,"S")),U,3))
  1.  ;
  1. BEG ;
  1.  G XIT:'$D(DUZ(2))
  1.  S ABMM("SITE")=$P(^DIC(4,DUZ(2),0),"^",1)
  1.  G XIT:$G(XQNO1)]""
  1.  I '$D(IOF)!'$D(IO) S IOP="HOME" D ^%ZIS
  1. NCNV ;CONVERSION NOT COMPLETE
  1.  I '$D(^ABMCNVRT("ABMCNVRT","COMPLETE")) D
  1.  .W $$EN^ABMVDF("IOF")
  1.  .W !!!,$$EN^ABMVDF("RVN"),*7,"WARNING:",$$EN^ABMVDF("RVF")
  1.  .W " Version 2.0 conversion has NOT completed. Contact your Site Manager."
  1.  .W !!,"Do not use package until conversion has completed."
  1.  .F  W ! Q:$Y+4>IOSL
  1.  .S DIR(0)="E" D ^DIR K DIR
  1.  W !,$$EN^ABMVDF("IOF"),!!
  1.  I ABMM(0)["Third Party Billing" D
  1.  .S ABMM(0)="Main Menu"
  1.  .I '$D(ABMM("OUT")) S ABM("F1")=1
  1.  W !?11,"+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+"
  1.  W !?11,"|"
  1.  S ABMM("VER")=$O(^DIC(9.4,"C","ABM",""))
  1.  I ABMM("VER")]"",$D(^DIC(9.4,ABMM("VER"),"VERSION"))
  1.  S ABMM("VER")=$S('$T:"VERSION 1.0",1:"VERSION "_^DIC(9.4,ABMM("VER"),"VERSION"))
  1.  S ABMM("VER")=ABMM("VER")_$S(+$$LAST^ABMENVCK("IHS 3P BILLING SYSTEM",$P(ABMM("VER")," ",2))'=0:"p"_+$$LAST^ABMENVCK("IHS 3P BILLING SYSTEM",$P(ABMM("VER")," ",2)),1:"")  ;abm*2.6*1 NO HEAT
  1.  S ABMM("TITL")="THIRD PARTY BILLING SYSTEM - VER "_$P(ABMM("VER")," ",2) W ?80-$L(ABMM("TITL"))\2,ABMM("TITL"),?69,"|"
  1.  W !,?11,"+",?80-$L(ABMM(0))\2,$$EN^ABMVDF("RVN"),ABMM(0),$$EN^ABMVDF("RVF"),?69,"+"
  1.  W !?11,"|"
  1.  W ?80-$L(ABMM("SITE"))\2,ABMM("SITE")
  1.  W ?69,"|"
  1.  ;
  1. END ;
  1.  W !?11,"+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+"
  1.  I $D(^VA(200,DUZ,0)) D
  1.  .W !,?11,"User: ",$P(^VA(200,DUZ,0),U),?52+$S($E(DT,6,7)<10:1,1:0)
  1.  .D NOW^%DTC
  1.  .W $$MDT^ABMDUTL(%)
  1.  I $G(ABM("F1")) D
  1.  .S X2=+$G(^ABMDPARM(DUZ(2),1,2))
  1.  .S X1=DT
  1.  .D ^%DTC
  1.  .I X>1!(X="") D
  1.  ..S Y=+$G(^ABMDPARM(DUZ(2),1,2))
  1.  ..D DD^%DT
  1.  ..W !!,$$EN^ABMVDF("RVN"),*7,"WARNING:",$$EN^ABMVDF("RVF")," The Claim Generator has not run since ",Y,"."
  1.  ..W !?9,"Contact your Site Manager to investigate this problem."
  1.  .I $P($G(^ABMDPARM(DUZ(2),1,0)),U,15)'="Y" D
  1.  ..W *7,!!?5,"SITE PARAMETERS have not yet been reviewed. Access to the Claim"
  1.  ..W !?5,"Editor is prevented until they are! The Site Parameters can be",!?5,"reviewed through the Table Maintenace Menu."
  1.  .D FINDAOPN^ABMUCUTL  ;find all open sessions
  1.  .S ABMFLG=0
  1.  .S ABMSDT=0
  1.  .F  S ABMSDT=$O(ABMO(ABMSDT)) Q:+ABMSDT=0  D  Q:ABMFLG=1
  1.  ..I (DT)>($P(ABMSDT,".")) S ABMFLG=1
  1.  .I $G(ABMFLG)=1 W !,"WARNING: Open cashiering sessions exist that should be reconciled for UFMS"
  1.  .S ABMFLG="CLOSED"
  1.  .D FINDACLS^ABMUCUTL  ;find all closed sessions
  1.  .I $D(ABMO) W !,"WARNING: Cashiering sessions are closed and awaiting export to UFMS"
  1.  .;start new code abm*2.6*9 NOHEAT
  1.  .I $P($G(^ABMDPARM(DUZ(2),1,4)),U,15)="" D
  1.  ..W !!,$$EN^ABMVDF("RVN"),*7,"WARNING:",$$EN^ABMVDF("RVF")," UFMS PARAMETERS have not been completed."
  1.  .;end new code
  1.  .;start new abm*2.6*27 IHS/SD/SDR CR8894
  1.  .I $$FEETBCHK()=1 D
  1.  ..W !!,$$EN^ABMVDF("RVN"),*7,"WARNING:",$$EN^ABMVDF("RVF")," FEE SCHEDULES NEED TO BE REVIEWED/COMPLETED BEFORE ALL FEES WILL",!,"   BE ACCURATE"
  1.  .;end new abm*2.6*27 IHS/SD/SDR CR8894
  1.  K ABM("F1")
  1.  ;
  1. XIT ;
  1.  D EN^XBVK("ABM")  ;local variable killer
  1.  K X,Y,I,X1,X2,DUOUT,DTOUT,DIROUT,POP,ZTSK,ZTSAVE,ZTRTN,ZTDESC,%ZIS,TO,FR,BY,FLDS,PG,DIR,DIC,DIE,DIK,DA,DR,L,%X,%Y
  1.  Q
  1.  ;
  1. OUT ;EP - Entry Point for all Option Exits
  1.  K DIQ
  1.  S ABMM(0)=$S($G(^XUTL("XQ",$J,"T")):$P($G(^XUTL("XQ",$J,^("T")-1)),U,3),1:"")
  1.  I $P($G(Y(0)),U)="ABMMENU"!($P($G(XQY0),U)="ABMMENU") D SESSCK G XIT
  1.  S ABMM("OUT")=""
  1.  G BEG
  1.  ;
  1. SESSCK ;EP - Check if user has open session for UFMS
  1.  S ABMUOPNS=$$FINDOPEN^ABMUCUTL(DUZ)
  1.  I +$G(ABMUOPNS)'=0 D
  1.  .W !!,"NOTE: You are still logged into your cashiering session.  To Close"
  1.  .W !?6,"your session select Cashiering Options (UCSH), then Cashiering Sign In/"
  1.  .W !?6,"Sign Out (CIO).",!
  1.  .S DIR(0)="E",DIR("A")="Enter RETURN to Continue" D ^DIR K DIR
  1.  Q
  1.  ;start new abm*2.6*27 IHS/SD/SDR CR8894
  1. FEETBCHK() ;EP
  1.  S ABMT=0
  1.  S ABMT("TB")=0
  1.  F  S ABMT("TB")=$O(^ABMDFEE(ABMT("TB"))) Q:'ABMT("TB")  D
  1.  .I $P($G(^ABMDFEE(ABMT("TB"),0)),U,6)="" S ABMT=1
  1.  Q ABMT
  1.  ;end new abm*2.6*27 IHS/SD/SDR CR8894