Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ABMDF25A

ABMDF25A.m

Go to the documentation of this file. 
  1. ABMDF25A ; IHS/ASDST/DMJ - ADA 2000 Dental Export -part 2 ;    
  1.  ;;2.6;IHS 3P BILLING SYSTEM;;NOV 12, 2009
  1.  ;Original;TMD;08/13/96 11:47 AM
  1.  ;
  1.  ; IHS/SD/SDR - v2.5 p9 - IM19380
  1.  ;   Corrections to getting secondary insurer
  1.  ;
  1.  ; IHS/SD/SDR - v2.5 p10 - IM20337
  1.  ;   Added code for page 9F
  1.  ;
  1.  ; IHS/SD/SDR - v2.5 p10 - IM21043
  1.  ;   Changed treatment addresss to physical address
  1.  ;
  1.  ; *********************************************************************
  1.  ;
  1. ENT ; EP for getting data
  1.  S ABMP("B0")=^ABMDBILL(DUZ(2),ABMP("BDFN"),0)  ; 3P Bill file 0 node
  1.  S ABMP("INS")=$P(ABMP("B0"),U,8)               ; Active insurer
  1.  S ABMP("PDFN")=$P(ABMP("B0"),U,5)              ; Patient IEN
  1.  S ABMP("LDFN")=$P(ABMP("B0"),U,3)              ; Location IEN
  1.  S ABMP("VTYP")=$P(ABMP("B0"),U,7)              ; Visit Type
  1.  S ABMP("BTYP")=$P(ABMP("B0"),U,2)              ; Bill Type
  1.  Q:'ABMP("PDFN")!'ABMP("LDFN")!'ABMP("INS")
  1.  S ABMP("VDT")=$P(^ABMDBILL(DUZ(2),ABMP("BDFN"),7),U)  ; Visit Date
  1.  ;
  1. BADDR ;
  1.  ; Billing Address
  1.  S ABM("J")=ABMP("BDFN")
  1.  S ABM("I")=$P(^AUTNINS(ABMP("INS"),0),U)_"-"_ABMP("INS")
  1.  S ABM("INS",ABM("I"),ABM("J"))=""
  1.  I $P($G(^AUTNINS(ABMP("INS"),2)),U)="N" D
  1.  .S ABM("INS",ABM("I"),ABM("J"))=ABMP("PDFN")
  1.  S ABM("IDFN")=ABMP("INS")
  1.  D BADDR^ABMDLBL1
  1.  G PAT:'$D(ABM("ADD"))
  1.  S ABMF(8)=$P(ABM("ADD"),U,1)                ; Ins Name (3)
  1.  S ABMF(9)=$P(ABM("ADD"),U,2)                ; Ins Address  (3)
  1.  S ABMF(10)=$P(ABMCSZ,U)    ; City     (3)
  1.  S ABMSTATE=$P(ABMCSZ,"^",2)           ; State    (3)
  1.  S ABMF(10)=ABMF(10)_", "_$P($G(^DIC(5,+ABMSTATE,0)),"^",2)
  1.  S ABMF(10)=ABMF(10)_"  "_$P(ABMCSZ,"^",3)  ; Zip      (3)
  1.  K ABMCSZ,ABMSTATE
  1.  ; Secondary information
  1.  S ABMPIIEN=$O(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,"B",ABMP("INS"),0))
  1.  K ABMSCNT,ABMSINS,ABMP("INS2")
  1.  I +$G(ABMPIIEN)'=0 D
  1.  .S ABMPINS=$P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABMPIIEN,0)),U,2)  ;get priority of active insurer
  1.  .S ABMIFLG=0
  1.  .S ABMSCNT=ABMPINS
  1.  .F  S ABMSCNT=$O(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,"C",ABMSCNT)) Q:+ABMSCNT=0  D  Q:ABMIFLG=1
  1.  ..S ABMSINS=$O(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,"C",ABMSCNT,0))
  1.  ..I $P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABMSINS,0)),U,3)="U" Q  ;unbillable
  1.  ..S ABMIFLG=1
  1.  I $G(ABMSINS)'="" S ABMP("INS2")=$P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABMSINS,0)),U)
  1.  I $G(ABMP("INS2"))'="" D
  1.  .S ABMPISAV=ABMP("INS")
  1.  .S ABMP("INS")=ABMP("INS2")
  1.  .S ABM("J")=ABMP("BDFN")
  1.  .S ABM("I")=$P(^AUTNINS(ABMP("INS"),0),U)_"-"_ABMP("INS")
  1.  .S ABM("INS",ABM("I"),ABM("J"))=""
  1.  .I $P($G(^AUTNINS(ABMP("INS"),2)),U)="N" D
  1.  ..S ABM("INS",ABM("I"),ABM("J"))=ABMP("PDFN")
  1.  .S ABM("IDFN")=ABMP("INS")
  1.  .D BADDR^ABMDLBL1
  1.  .G PAT:'$D(ABM("ADD"))
  1.  .S $P(ABMF(21),U)=$P(ABM("ADD"),U,1)                ; Secondary Name (11)
  1.  .S $P(ABMF(22),U)=$P(ABM("ADD"),U,2)                ; Secondary Address  (11)
  1.  .S $P(ABMF(23),U)=$P(ABMCSZ,U)    ; Secondary City     (11)
  1.  .S ABMSTATE=$P(ABMCSZ,"^",2)           ; Secondary State    (11)
  1.  .S $P(ABMF(23),U)=$P(ABMF(23),U)_", "_$P($G(^DIC(5,+ABMSTATE,0)),"^",2)  ;Secondary State (11)
  1.  .S $P(ABMF(23),U)=$P(ABMF(23),U)_"  "_$P(ABMCSZ,"^",3)  ; Secondary Zip      (11)
  1.  .K ABMCSZ,ABMSTATE
  1.  .S ABMP("INS")=ABMPISAV
  1.  .;
  1.  .; secondary group# (9)
  1.  .I $P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABMSINS,0)),U,4) S ABMX("PH")=ABMP("PDFN")
  1.  .I $P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABMSINS,0)),U,5) S ABMX("PH")=ABMP("PDFN")
  1.  .I $P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABMSINS,0)),U,6) S ABMX("PH")=$P($G(^AUPNMCD($P(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABMSINS,0),U,6),0)),U,9)
  1.  . I $P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABMSINS,0)),U,8),($P(^AUPNPRVT(ABMP("PDFN"),11,$P(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABMSINS,0),U,8),0),U,8)'="") D
  1.  .. S ABMX("PH")=$P(^AUPNPRVT(ABMP("PDFN"),11,$P(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABMSINS,0),U,8),0),U,8)
  1.  .I +$G(ABMX("PH"))'=0 D
  1.  ..S ABMX("GRP")=$P($G(^AUPN3PPH(+ABMX("PH"),0)),U,6)
  1.  ..I $P($G(^AUPN3PPH(+ABMX("PH"),0)),U,8)="M" S $P(ABMF(17),U,2)="X"  ;Gender (7)
  1.  ..I $P($G(^AUPN3PPH(+ABMX("PH"),0)),U,8)="F" S $P(ABMF(17),U,3)="X"  ;Gender (7)
  1.  ..S $P(ABMF(17),U,4)=$P($G(^AUPN3PPH(+ABMX("PH"),0)),U,4)  ;Policy Number (8)
  1.  .I $G(ABMX("GRP"))'="" D
  1.  ..I $D(^AUTNEGRP(ABMX("GRP"),0)) D
  1.  ...S $P(ABMF(19),U)=$S($D(^AUTNEGRP(ABMX("GRP"),11,ABMP("VTYP"),0)):$P(^(0),U,2),1:$P(^AUTNEGRP(ABMX("GRP"),0),U,2))
  1.  ;
  1. PAT ;
  1.  ; Patient Information
  1.  S ABM("P0")=^DPT(ABMP("PDFN"),0)                ; 0 node patient file
  1.  S ABMF(18)=$P(ABM("P0"),U)                       ; Name     (20)
  1.  S ABM("P11")=$G(^DPT(ABMP("PDFN"),.11))
  1.  S $P(ABMF(19),U,6)=$P(ABM("P11"),U)              ; Mailing address (20)
  1.  S $P(ABMF(20),U)=$P(ABM("P11"),U,4)            ; Mailing - city  (20)
  1.  S $P(ABMF(20),U)=$P(ABMF(20),U)_", "_$P(^DIC(5,$P(ABM("P11"),U,5),0),U,2) ; Mailing - State (20)
  1.  S $P(ABMF(20),U)=$P(ABMF(20),U)_"  "_$P(ABM("P11"),U,6)  ;Mailing - Zip (20)
  1.  ;
  1.  S $P(ABMF(23),U,2)=$P(ABM("P0"),U,3)                      ; dob (21)
  1.  ;
  1.  I $P(ABM("P0"),U,2)="M" S $P(ABMF(23),U,3)="X"   ; sex - male      (22)
  1.  E  S $P(ABMF(23),U,4)="X"                        ; sex - female    (22)
  1.  K ABM("P0"),ABM("P11")
  1.  ;
  1.  S (ABMV("X1"),ABMV("X2"),ABMV("X3"))=""
  1.  D PAT^ABMDE1X
  1.  D REMPL^ABMDE1X1
  1.  D LOC^ABMDE1X1
  1.  K ABME
  1.  ;
  1. LOC ;
  1.  ; Location info
  1.  S $P(ABMF(55),U)=$S($P(ABMV("X1"),U,2)]"":$P(ABMV("X1"),U,2),1:$P($P(ABMV("X1"),U),";",2))                                ; billing entity name  (48)
  1.  S $P(ABMF(56),U)=$P(ABMV("X1"),U,3)       ; address              (48) 
  1.  S ABMCSZ=$P(ABMV("X1"),"^",4)
  1.  S $P(ABMF(57),U)=$P(ABMCSZ,",",1) ; City               (48)
  1.  S ABMCSZ=$P(ABMCSZ,",",2)
  1.  S $P(ABMF(57),U)=$P(ABMF(57),U)_", "_$P(ABMCSZ," ",2)  ; State         (48)
  1.  S $P(ABMF(57),U)=$P(ABMF(57),U)_"  "_$P(ABMCSZ," ",4)  ; zip           (48)
  1.  K ABMCSZ
  1.  ;
  1.  S $P(ABMF(60),U,3)=$P(ABMV("X1"),U,6)     ; SSN/TIN              (51)
  1.  S $P(ABMF(61),U,1)=$P(ABMV("X1"),U,5)     ; Phone                (52)
  1.  S ABMLOC=$P(ABMP("B0"),U,3)
  1.  S ABMV("X1")=$G(^AUTTLOC(ABMLOC,0))
  1.  S $P(ABMF(59),U)=$P(ABMV("X1"),U,12)           ;address            (56)
  1.  S $P(ABMF(60),U,4)=$P(ABMV("X1"),U,13)         ;city               (56)
  1.  S ABML=$P(ABMV("X1"),U,14)
  1.  S $P(ABMF(60),U,4)=$P(ABMF(60),U,4)_", "_$P(^DIC(5,ABML,0),U,2)     ;state              (56)
  1.  S $P(ABMF(60),U,4)=$P(ABMF(60),U,4)_"  "_$P(ABMV("X1"),U,15)         ;zip                (56)
  1.  I $P($G(^AUTNINS(ABMP("INS"),0)),U)["DELTA DENTAL" D
  1.  .S $P(ABMF(59),U)=$P($G(^DIC(4,ABMP("LDFN"),1)),U)  ;address  (56)
  1.  .S $P(ABMF(60),U,4)=$P($G(^DIC(4,ABMP("LDFN"),1)),U,3)  ;city  (56)
  1.  .S ABMX("STATE")=$P($G(^DIC(4,ABMP("LDFN"),0)),U,2)  ;state  (56)
  1.  .S ABMX("STATE")=$P($G(^DIC(5,+ABMX("STATE"),0)),U,2)
  1.  .I ABMX("STATE")'="" D
  1.  ..S $P(ABMF(60),U,4)=$P(ABMF(60),U,4)_", "_ABMX("STATE")_" "_$P($G(^DIC(4,ABMP("LDFN"),1)),U,4)  ;zip  (56)
  1.  ;
  1. INSNUM ; 
  1.  ; Insurer Information
  1.  S ABM("INUM")=$P($G(^ABMNINS(ABMP("LDFN"),ABMP("INS"),1,$P(ABMP("B0"),U,7),0)),U,8)
  1.  S:ABM("INUM")="" ABM("INUM")=$P($G(^AUTNINS(ABMP("INS"),15,ABMP("LDFN"),0)),U,2)
  1.  I ABM("INUM")="" D
  1.  .S ABMPRV=$O(^ABMDBILL(DUZ(2),ABMP("BDFN"),41,"C","A",0))
  1.  .S:ABMPRV ABMPRV=$P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),41,ABMPRV,0)),U)
  1.  .S:ABMPRV ABM("INUM")=$P($G(^VA(200,ABMPRV,9999999.18,ABMP("INS"),0)),U,2)
  1.  S $P(ABMF(60),U)=ABM("INUM")            ; Dentist License     (54)
  1.  S ABMP("ITYP")=$P($G(^AUTNINS(ABMP("INS"),2)),U)  ; Ins. type
  1.  I ABMP("ITYP")="D" D
  1.  .S ABMMCD=$P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABMP("INS"),0)),U,6)
  1.  ;
  1. PRV ;
  1.  ; Provider?
  1.  S ABM("X")=$O(^ABMDBILL(DUZ(2),ABMP("BDFN"),41,"C","A",0))
  1.  I ABM("X") D
  1.  .D SELBILL^ABMDE4X
  1.  .D PAYED^ABMERUTL
  1.  .S $P(ABMF(55),U,2)=$P(ABM("A"),U)  ;  (53)
  1.  .S $P(ABMF(55),U,3)=DT  ;  (53)
  1.  .S $P(ABMF(60),U,2)=$$SLN^ABMEEPRV($P(ABM("A"),U,2))            ; Dentist License     (50)
  1.  .S $P(ABMF(57),U,3)=$$SLN^ABMEEPRV($P(ABM("A"),U,2))  ;  (55)
  1.  .S $P(ABMF(57),U,2)=ABM("PNUM")          ; Provider number  (49)
  1.  .S $P(ABMF(61),U,2)=$P($G(^VA(200,$P(ABM("A"),U,2),.13)),"^",2)  ;office phone (57)
  1.  .I $P(ABMF(61),U,2)="" S $P(ABMF(61),U,2)=$P($G(^AUTTLOC(ABMP("LDFN"),0)),"^",11)  ;location phone (57)
  1.  .S $P(ABMF(61),U,3)=$$PTAX^ABMEEPRV($P(ABM("A"),U,2))  ;specialty (taxonomy code) (58)
  1.  ;
  1. POL ;
  1.  ; Policy Information
  1.  N I
  1.  S I=0
  1.  F  S I=$O(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,I)) Q:'I  D
  1.  .I $P(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,I,0),"^",3)="I" S ABM("XIEN")=I
  1.  S Y=ABMP("INS")
  1.  S ABMP("GL")="^ABMDBILL(DUZ(2),"_ABMP("BDFN")_","
  1.  D SEL^ABMDE2X            ; ABMV("X2")           ; Policy holder info
  1.  I ABM("ADD")["NON-BEN" D
  1.  .S ABM("ADD")=ABMV("X2")
  1.  S $P(ABMF(6),U)=$P($P(ABMV("X2"),U),";",2)     ; Subscriber name (12)
  1.  S $P(ABMF(7),U)=$P(ABMV("X2"),U,3)             ; Address         (12)
  1.  S ABMCSZ=$P(ABMV("X2"),"^",4)
  1.  S $P(ABMF(8),U,2)=$P(ABMCSZ,",",1)     ; City            (12)
  1.  S ABMCSZ=$P(ABMCSZ,",",2)
  1.  S $P(ABMF(8),U,2)=$P(ABMF(8),U,2)_", "_$P(ABMCSZ," ",2) ; State           (12)
  1.  S $P(ABMF(8),U,2)=$P(ABMF(8),U,2)_"  "_$P(ABMCSZ," ",4) ; Zip             (12)
  1.  K ABMCSZ
  1.  ;
  1.  S $P(ABMF(11),U,$S($P(ABMV("X2"),U,6)="M":2,1:3))="X"  ; Sex      (14)
  1.  S $P(ABMF(11),U,4)=$P(ABMV("X1"),U,4)             ; Emp. id         (15)
  1.  ;
  1.  S $P(ABMF(11),U)=$P(ABMV("X2"),U,7)     ; dob  (13)
  1.  ;
  1.  S ABMSTAT=$P($P(ABMV("X3"),U,5),";")
  1.  I $P(ABMV("X3"),U)="STUDENT" D  ;check if marked as student
  1.  . I ABMSTAT=1 S $P(ABMF(16),U,5)="X"  ;full-time student (19)
  1.  . I ABMSTAT=2 S $P(ABMF(16),U,6)="X"  ;part-time student (19)
  1.  ;
  1. EMPL ;
  1.  ; Employer information
  1.  I ABMP("ITYP")'="P" S $P(ABMF(13),U,4)=$P(ABMV("X3"),U)             ; Employer name   (17)
  1.  E  D
  1.  .S ABMP("PH")=$P(ABMV("X2"),U)
  1.  .S ABMEMPL=$P($G(^AUPN3PPH(+ABMP("PH"),0)),U,16)
  1.  .S:+ABMEMPL $P(ABMF(13),U,4)=$P($G(^AUTNEMPL(ABMEMPL,0)),U)
  1.  S $P(ABMF(13),U,3)=$P(ABMV("X3"),U,7)           ; Group number    (16)
  1.  ;
  1. REL ;
  1.  ; Relationship
  1.  G INS:'$P(ABMV("X2"),U,2)
  1.  S ABM=+$P($G(^AUTTRLSH(+$P(ABMV("X2"),U,2),0)),U,2)
  1.  I ABM,ABM<8,ABM'=2 S $P(ABMF(16),U,$S(ABM=1:1,1:4))="X"   ; Relationship to subscriber(18)
  1.  E  S $P(ABMF(16),U,$S(ABM=2:2,ABM=1:1,1:4))="X"
  1.  ;
  1. INS ;
  1.  ; Insurer Information
  1.  S ABM("I")=0
  1.  F  S ABM("I")=$O(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,"C",ABM("I"))) Q:'ABM("I")  D
  1.  .S ABM=$O(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,"C",ABM("I"),0))
  1.  .S ABM=$P(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABM,0),U)
  1.  .I ABM'=ABMP("INS") D  Q
  1.  ..I $P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),13,ABM,0)),U,3)="U" Q
  1.  ..S Y=ABM
  1.  ..S ABMP("GL")="^ABMDBILL(DUZ(2),"_ABMP("BDFN")_","
  1.  ..D SEL^ABMDE2X
  1.  ..S $P(ABMF(15),U)=$P(ABMV("X3"),U)                   ; (5)
  1.  ..S $P(ABMF(17),U)=$P(ABMV("X2"),U,7)         ; (6)
  1.  ..;
  1.  ..S $P(ABMF(13),U,2)="X"          ; Other coverage        (4)
  1.  S:$P($G(ABMF(13)),U,2)="" $P(ABMF(13),U)="X"    ; No other coverage (4)
  1.  S $P(ABMF(2),U)="X"   ;statement of actual services (1)
  1.  I $P($G(^AUTNINS(ABMP("INS"),2)),"^")="D" S $P(ABMF(3),U)="X"  ;EPSDT/Title 19 (1)
  1.  ;
  1. BNODES ;
  1.  ; Bill nodes
  1.  I $D(^ABMDBILL(DUZ(2),ABMP("BDFN"),0)) D
  1.  .S ABM("B4")=$G(^ABMDBILL(DUZ(2),ABMP("BDFN"),4))
  1.  .S ABM("B5")=$G(^ABMDBILL(DUZ(2),ABMP("BDFN"),5))
  1.  .S ABM("B7")=$G(^ABMDBILL(DUZ(2),ABMP("BDFN"),7))
  1.  .S ABM("B8")=$G(^ABMDBILL(DUZ(2),ABMP("BDFN"),8))
  1.  .S ABM("B9")=$G(^ABMDBILL(DUZ(2),ABMP("BDFN"),9))
  1.  ;
  1.  S $P(ABMF(5),U)=$P(ABM("B5"),U,8)           ; Prior Auth         (2)
  1.  I $P(ABM("B9"),U)]"" S $P(ABMF(50),U,3)="X"  ;Occupational illness (45)
  1.  ;
  1. ACCD ;
  1.  ; Accident?
  1.  I $P(ABM("B8"),U,3)'="" D
  1.  .I "12"[$P(ABM("B8"),U,3) D  Q
  1.  ..S $P(ABMF(50),U,4)="X"                       ; auto accident  (45)
  1.  ..S $P(ABMF(51),U)=$P(ABM("B8"),U,2)   ;accident date (46)
  1.  ..S $P(ABMF(51),U,2)=$P($G(^DIC(5,$P(ABM("B8"),U,16),0)),"^",2)  ;accident state (47)
  1.  .I "5"[$P(ABM("B8"),U,3) D  Q
  1.  ..S $P(ABMF(50),U,5)="X"                        ; other accident (45)
  1.  .S $P(ABMF(51),U)=$P(ABM("B8"),U,2)   ;accident date (46)
  1.  .S $P(ABMF(51),U,2)=$P($G(^DIC(5,$P(ABM("B8"),U,16),0)),"^",2)  ;accident state (47)
  1.  ;
  1.  ;
  1. FSYM ;
  1.  I $P(ABM("B7"),U,4)="Y" D                      ; Release of Info
  1.  .S $P(ABMF(46),U)="SIGNATURE ON FILE"                             ;  (36)
  1.  .S $P(ABMF(46),U,2)=DT                                      ;  (36)
  1.  I $P(ABM("B7"),U,5)="Y" D                      ; Assignment of Benefits
  1.  .S $P(ABMF(50),U)="SIGNATURE ON FILE"                     ;  (37)
  1.  .S $P(ABMF(50),U,2)=DT                                      ;  (37)
  1.  S $P(ABMF(44),U,4)="X"                        ; office place of tx (38)
  1.  S $P(ABMF(44),U,5)=$P($G(ABM("B4")),U,3)     ;Radiographs (39)
  1.  S $P(ABMF(44),U,6)=$P($G(ABM("B9")),U,18)    ;Oral Images (39)
  1.  S $P(ABMF(44),U,7)=$P($G(ABM("B9")),U,19)     ;Models (39)
  1.  ;
  1. XRAY ;
  1.  ; Number of X-rays included
  1.  ;
  1. ORTHO ;
  1.  ; Orthodontic Related?
  1.  S $P(ABMF(46),U,$S($P(ABM("B4"),U,4):4,1:3))="X"                ;  (40)
  1.  ; Orthodontic Placement Date
  1.  I $P(ABM("B4"),U,4) S $P(ABMF(46),U,5)=$P(ABM("B4"),U,5)        ;  (41)
  1.  ;
  1. PROTH ;
  1.  ; Prothesis Included?
  1.  S $P(ABMF(48),U,$S($P(ABM("B4"),U,6):3,1:2))="X"                ;  (43)
  1.  ; Prior Placement Date
  1.  I $P(ABM("B4"),U,6) S $P(ABMF(48),U,4)=$P(ABM("B4"),U,7)          ;  (44)
  1.  ;
  1.  S ABMBIL=$P(ABMP("B0"),U)                       ; Bill number
  1.  S ABMSFX=$P($G(^ABMDPARM(DUZ(2),1,2)),U,4)    ; Bill Number suffix
  1.  S ABMAHRN=$P($G(^ABMDPARM(DUZ(2),1,1,3)),U,3)   ; Append HRN?
  1.  S ABMHRN=$P($G(^AUPNPAT(ABMP("PDFN"),41,ABMP("LDFN"),0)),U,2)  ; HRN
  1.  S $P(ABMF(23),U,5)=ABMBIL_"-"_ABMSFX_" "_ABMHRN  ;Patient ID (23)
  1.  I $D(^ABMDBILL(DUZ(2),ABMP("BDFN"),61,0)) D
  1.  .S ABMIEN=0
  1.  .S ABMLINE=41
  1.  .F  S ABMIEN=$O(^ABMDBILL(DUZ(2),ABMP("BDFN"),61,ABMIEN)) Q:+ABMIEN=0!(ABMLINE>43)  D
  1.  ..S ABMF(ABMLINE)=$G(^ABMDBILL(DUZ(2),ABMP("BDFN"),61,ABMIEN,0))
  1.  ..S ABMLINE=ABMLINE+1
  1.  ;
  1. XIT ;
  1.  K ABM,ABMV
  1.  Q