Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ABMMUPVP

ABMMUPVP.m

Go to the documentation of this file. 
  1. ABMMUPVP ;IHS/SD/SDR - MU Patient Volume EP Report ;
  1.  ;;2.6;IHS 3P BILLING SYSTEM;**7,8,10,11,12**;NOV 12, 2009;Build 187
  1.  ;
  1.  I $P($G(^ABMMUPRM(1,0)),U,2)="" D  Q
  1.  .W !!,"Setup has not been done.  Please do MUP option prior to running any reports",!
  1.  .S DIR(0)="E",DIR("A")="Enter RETURN to Continue" D ^DIR K DIR
  1.  ;
  1.  ;
  1. EN ;
  1.  K ABMF,ABMPRVDR,ABMY,ABM
  1.  D FAC Q:$D(DTOUT)!$D(DUOUT)!$D(DIROUT)!'$D(ABMF)
  1.  ;
  1.  W !!,"The SEL report determines if INDIVIDUAL Eligible Professionals have met the"
  1.  W !,"minimum patient volume requirements on their own patient encounters during a"
  1.  W !,"continuous 90-day period in order to be eligible for the Medicaid EHR Incentive"
  1.  W !,"Program (Meaningful Use EHR Incentive Program)."
  1.  ;
  1.  W !!,"The GRP report may be used for EPs who wish to use encounters of all providers"
  1.  W !,"at a facility to meet the minimum patient volume requirements during a"
  1.  W !,"continuous 90-day period in order to be eligible for the Medicaid EHR Incentive"
  1.  W !,"Program (Meaningful Use EHR Incentive Program).  When used, all EPs at the"
  1.  W !,"facility must use the Group Method.  All provider encounters for the entire"
  1.  W !,"facility are included in the calculation."
  1.  W !!
  1.  D RTYPE
  1.  ;I ABMY("RTYP")="GRP" W !!,"GRP not available at this time...defaulting to SEL" S ABMY("RTYP")="SEL"  ;abm*2.6*8
  1.  Q:$D(DTOUT)!$D(DUOUT)!$D(DIROUT)  ;abm*2.6*8
  1.  I ABMY("RTYP")="SEL" D  Q:$D(DTOUT)!$D(DUOUT)!$D(DIROUT)!'$D(ABMPRVDR)
  1.  .D PRVDR Q:$D(DTOUT)!$D(DUOUT)!$D(DIROUT)!'$D(ABMPRVDR)
  1.  D PARTYR Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
  1.  ;start new code abm*2.6*11 MU4
  1.  I (ABMY("PYR")>2012) D  Q
  1.  .W !!?5,"**NOTE** For CY 2013+, you should use report options within menu "
  1.  .W !?15,"MUS2 PARTICIPATION CY 2013+ PATIENT VOLUME REPORTS"
  1.  .W ! S DIR(0)="E",DIR("A")="Enter RETURN to Continue" D ^DIR K DIR
  1.  ;end new code MU4
  1.  D 90DAY Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
  1.  D RFORMAT Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
  1.  D SUMMARY
  1.  D ^XBFMK
  1.  S DIR(0)="S^P:Print Report;R:Return to Selection Criteria -Erases ALL previous selections"
  1.  S DIR("A")="<P> to Print or <R> to Reselect"
  1.  D ^DIR K DIR Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
  1.  ;I $P(Y,U)="R" K ABMY,ABMPRVDR,ABMF G EN  ;abm*2.6*8
  1.  I $P(Y,U)="R" K ABMY,ABMPRVDR,ABMF,ABMP,ABMPRV G EN  ;abm*2.6*8
  1.  W !!,"Note: This report will take a while to run based on the amount of data you have"
  1.  S ABMQ("RX")="POUT^ABMDRUTL"
  1.  S ABMQ("NS")="ABM"
  1.  S ABMQ("RP")="COMPUTE^ABMMUPV1"
  1.  D ^ABMDRDBQ
  1.  Q
  1.  ;
  1. RTYPE ;
  1.  K ^XTMP("ABM-PVP",$J)
  1.  D ^XBFMK
  1.  ;S DIR(0)="S^SEL:Encounter method for each EP;GRP:Group method for facilities (not available at this time)"  ;abm*2.6*8
  1.  S DIR(0)="S^SEL:Encounter method for each EP;GRP:Group method for facilities"  ;abm*2.6*8
  1.  S DIR("A")="Select report type"
  1.  D ^DIR K DIR
  1.  Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
  1.  S ABMY("RTYP")=Y
  1.  Q
  1. PRVDR ;EP
  1.  W !
  1.  F  D  Q:(+Y<0)
  1.  .D ^XBFMK
  1.  .S DIC="^VA(200,"
  1.  .S DIC(0)="AEMQ"
  1.  .D ^DIC
  1.  .S ABMPRV=+Y
  1.  .I +Y<0 Q  ;nothing selected
  1.  .I +$$GET1^DIQ(200,ABMPRV,53.5,"I")=0 D  Q
  1.  ..W !!,"Provider "_$$GET1^DIQ(200,ABMPRV,".01","E")_" does not have a Provider Class so they can't be"
  1.  ..W !,"considered for this report"
  1.  ..W !,"Please enter a different Eligible Professional's name.",!!
  1.  .;
  1.  .I '$D(^ABMMUPRM(1,2,"B",$$GET1^DIQ(200,ABMPRV,53.5,"I"))) D  Q
  1.  ..W !!,"Provider "_$$GET1^DIQ(200,ABMPRV,".01","E")_" ("_$$GET1^DIQ(200,ABMPRV,53.5,"E")_")"
  1.  ..W !,"is not an Eligible Professional for the Medicaid MU EHR Program"
  1.  ..W !,"Please enter a different Eligible Professional's name.",!!
  1.  .;
  1.  .I $$GET1^DIQ(200,ABMPRV,53.5,"E")="PHYSICIAN ASSISTANT" D  Q:ABMPAFLG=0
  1.  ..S ABMPAFLG=0
  1.  ..I $D(^ABMMUPRM(1,1,"B")) D
  1.  ...S ABMFQ=0
  1.  ...F  S ABMFQ=$O(^ABMMUPRM(1,1,ABMFQ)) Q:'ABMFQ  D
  1.  ....I $P($G(^ABMMUPRM(1,1,ABMFQ,0)),U,2)=1 S ABMPAFLG=1
  1.  ..Q:ABMPAFLG=1
  1.  ..W !!,"Provider "_$$GET1^DIQ(200,ABMPRV,".01","E")_" ("_$$GET1^DIQ(200,ABMPRV,53.5,"E")_")"
  1.  ..W !,"can't be included because the facility has to be led by a PA for a PA"
  1.  ..W !,"to qualify"
  1.  .S ABMPRVDR(ABMPRV)=""
  1.  M ABMP=ABMPRVDR
  1.  Q
  1. FAC ;
  1.  D GETFACS^ABMMUMUP  ;get list of facilities
  1.  W !!
  1.  K ABMFANS,ABMF
  1.  F  D  Q:+$G(Y)<0!(Y=ABMTOT)!$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)  ;they didn't answer or ALL was selected
  1.  .D ^XBFMK
  1.  .D FACLST
  1.  .S DIR(0)="SO^"_$G(ABMDIR)
  1.  .S:'$D(ABMF) DIR(0)="S^"_$G(ABMDIR)
  1.  .I ABMFQHC=1 D
  1.  ..;S DIR("A",1)="Note: you cannot select a combination of FQHC/RHC and non-FQHC/RHC data on"  ;abm*2.6*10 HEAT61752
  1.  ..S DIR("A",1)="Note: you cannot select a combination of FQHC/RHC/Tribal and non-FQHC/RHC/Tribal"  ;abm*2.6*10 HEAT61752
  1.  ..S DIR("A",2)="data on this report"
  1.  ..S DIR("A",3)=""
  1.  .S DIR("A")="Select one or more facilities to use for calculating patient volume"
  1.  .D ^DIR K DIR
  1.  .Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
  1.  .S ABMFANS=Y
  1.  .;I ABMFANS'=ABMTOT,$D(ABMF),(ABMFQHC>1),'$D(^ABMMUPRM(1,1,"B",ABMFLIST(ABMFANS)))  W !!,"only FQHCs are allowed based on your first selection" H 1 Q  ;abm*2.6*10 HEAT61752
  1.  .I ABMFANS'=ABMTOT,$D(ABMF),(ABMFQHC>1),'$D(^ABMMUPRM(1,1,"B",ABMFLIST(ABMFANS)))  W !!,"only FQHC/RHC/Tribals are allowed based on your first selection" H 1 Q  ;abm*2.6*10 HEAT61752
  1.  .;I ABMFANS'=ABMTOT,$D(ABMF),(ABMFQHC=1),$D(^ABMMUPRM(1,1,"B",ABMFLIST(ABMFANS)))  W !!,"only non-FQHCs are allowed based on your first selection" H 1 Q  ;abm*1.6*10 HEAT61501
  1.  .I ABMFANS'=ABMTOT,$D(ABMF),(ABMFQHC=0),$D(^ABMMUPRM(1,1,"B",ABMFLIST(ABMFANS)))  W !!,"only non-FQHC/RHC/Tribal clinics are allowed based on your first selection" H 1 Q  ;abm*1.6*10 HEAT61501, HEAT61752
  1.  .I ABMFANS'=ABMTOT,$D(^ABMMUPRM(1,1,"B",ABMFLIST(ABMFANS))) S ABMFQHC=2
  1.  .I ABMFANS'=(ABMTOT) S ABMF($G(ABMFLIST(ABMFANS)))=""
  1.  .I ABMFANS=(ABMTOT) D
  1.  ..S ABMCNT=0
  1.  ..F  S ABMCNT=$O(ABMFLIST(ABMCNT)) Q:'ABMCNT  S ABMF($G(ABMFLIST(ABMCNT)))=""
  1.  Q:+$G(Y)<0!(Y=ABMTOT)!$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
  1.  K ABMFQHC
  1.  Q
  1. FACLST ;
  1.  S ABMCNT=0,ABMDIR="",ABMFQHC=0,ABMNFQHC=0
  1.  F  S ABMCNT=$O(ABMFLIST(ABMCNT)) Q:'ABMCNT  D
  1.  .S:ABMDIR'="" ABMDIR=ABMDIR_";"_ABMCNT_":"_$$GET1^DIQ(9999999.06,$G(ABMFLIST(ABMCNT)),.01,"E")
  1.  .S:ABMDIR="" ABMDIR=ABMCNT_":"_$$GET1^DIQ(9999999.06,$G(ABMFLIST(ABMCNT)),.01,"E")
  1.  .;S ABMDIR=ABMDIR_$S($D(^ABMMUPRM(1,1,"B",ABMFLIST(ABMCNT))):" (FQHC/RHC)",1:"")  ;abm*2.6*10 HEAT61752
  1.  .S ABMDIR=ABMDIR_$S($D(^ABMMUPRM(1,1,"B",ABMFLIST(ABMCNT))):" (FQHC/RHC/Tribal)",1:"")  ;abm*2.6*10 HEAT61752
  1.  .S ABMDIR=ABMDIR_$S($D(ABMF($G(ABMFLIST(ABMCNT)))):" *",1:"")
  1.  .I $D(^ABMMUPRM(1,1,"B",ABMFLIST(ABMCNT))) S ABMFQHC=1
  1.  .I '$D(^ABMMUPRM(1,1,"B",ABMFLIST(ABMCNT))) S ABMNFQHC=1
  1.  S ABMCNT=$O(ABMFLIST(99999),-1)  ;get last entry#
  1.  S (ABMCNT,ABMTOT)=ABMCNT+1
  1.  ;I ABMFQHC=0!(ABMCNT<2) S ABMDIR=ABMDIR_";"_ABMCNT_":All facilities"
  1.  I ((ABMFQHC=0&(ABMNFQHC=1))!((ABMFQHC=1)&(ABMNFQHC=0)))!(ABMCNT<2) S ABMDIR=ABMDIR_";"_ABMCNT_":All facilities"
  1.   Q
  1. PARTYR ;
  1.  I ABMY("RTYP")="SEL"!(ABMY("RTYP")="GRP") D
  1.  .W !!!,"For EPs, the Participation year is a calendar year."
  1.  .W !!,"Note:  The qualification year is the year prior to the participation year."
  1.  .W !,"Patient Volume is calculated on encounters that occurred in the qualification"
  1.  .W !,"year, which is the year prior to the participation year.  To view volume for"
  1.  .W !,"the current year, select next year as the participation year.",!
  1.  D ^XBFMK
  1.  S DIR(0)="NA^1960:2030"
  1.  S DIR("A")="Enter the Participation year for this report: "
  1.  I ABMY("RTYP")="HOS" S DIR("A")="Enter the Participation Fiscal year for this report: "  ;abm*2.6*8
  1.  D ^DIR K DIR
  1.  Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
  1.  S ABMY("PYR")=+Y
  1.  S ABMY("QYR")=ABMY("PYR")-1
  1.  Q
  1. 90DAY ;
  1.  W !!,"Report will be run for a 90-day reporting period. The 90-day period may be "
  1.  W !,"automatically calculated or user may select a specific start date.",!
  1.  W !,"The automated calculation will return the first 90-day period in the "
  1.  W ABMY("PYR")_" year"
  1.  W !,"in which required patient volumes are met or the 90-day period with the"
  1.  W !,"highest volume percentage (first occurrence in the year)."
  1.  D ^XBFMK
  1.  S DIR(0)="S^A:Automated 90-Day Report;B:Specific 90-Day Report Period;C:User specified Report Period"
  1.  S DIR("A",1)=""
  1.  S DIR("A")="Enter selection"
  1.  D ^DIR K DIR
  1.  Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
  1.  S ABMY("90")=$P(Y,U)
  1.  I ABMY("90")="B"!(ABMY("90")="C") D
  1.  .D ^XBFMK
  1.  .S DIR(0)="D^"_(ABMY("QYR")-1700)_"0101:"_(ABMY("QYR")-1700)_"1231:%DT"
  1.  .I ABMY("RTYP")="HOS" S DIR(0)="D^"_(ABMY("QYR")-1701)_"1001:"_(ABMY("QYR")-1700)_"0930:%DT"
  1.  .S DIR("A",1)=""
  1.  .S DIR("A",2)="Select a specific start date in the calendar year"
  1.  .I ABMY("90")="B" S DIR("A",2)=DIR("A",2)_" for the 90-Day Report Period."
  1.  .I ABMY("RTYP")="HOS" S DIR("A",2)="Select a specific start date in the fiscal year for the 90-Day Report Period."
  1.  .S DIR("A",3)="Note:  End Date must not be after December 31."
  1.  .I ABMY("RTYP")="HOS" S DIR("A",3)="Note:  End Date must not be after September 30."
  1.  .S DIR("A",4)=""
  1.  .S DIR("A")="Enter first day of reporting period for "_ABMY("QYR")
  1.  .D ^DIR K DIR
  1.  .S (ABMY("SDT"),ABMP("SDT"))=Y
  1.  .I ABMY("90")="C" D
  1.  ..D ^XBFMK
  1.  ..S DIR(0)="D^"_(ABMY("QYR")-1700)_"0101:"_(ABMY("QYR")-1700)_"1231:%DT"
  1.  ..I ABMY("RTYP")="HOS" S DIR(0)="D^"_(ABMY("QYR")-1701)_"1001:"_(ABMY("QYR")-1700)_"0930:%DT"
  1.  ..S DIR("A",1)=""
  1.  ..S DIR("A",2)="Select a specific end date in the calendar year"
  1.  ..I ABMY("90")="B" S DIR("A",2)=DIR("A",2)_" for the 90-Day Report Period."
  1.  ..I ABMY("RTYP")="HOS" S DIR("A",2)="Select a specific start date in the fiscal year for the 90-Day Report Period."
  1.  ..S DIR("A",3)="Note:  End Date must not be after December 31."
  1.  ..S DIR("A",4)=""
  1.  ..S DIR("A")="Enter last day of reporting period for "_ABMY("QYR")
  1.  ..D ^DIR K DIR
  1.  ..S (ABMY("EDT"),ABMP("EDT"))=Y
  1.  Q
  1. RFORMAT ;
  1.  D ^XBFMK
  1.  S DIR(0)="S^S:Summary Report;A:Abbreviated Summary Report;P:Patient List"
  1.  S DIR("A",1)=""
  1.  S DIR("A")="Enter Report Format Choice"
  1.  D ^DIR K DIR
  1.  Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
  1.  S ABMY("RFMT")=$P(Y,U)
  1.  I ABMY("RFMT")="A" D
  1.  . D ^XBFMK
  1.  .S DIR(0)="N"
  1.  .S DIR("A",1)=""
  1.  .S DIR("A",2)="Specify the number of top volume dates to display if minimum thresholds are not met"
  1.  .S DIR("A")="Enter Number (1-275)"
  1.  .D ^DIR K DIR
  1.  .Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
  1.  .S ABMY("TVDTS")=+Y
  1.  Q
  1. SUMMARY ;
  1.  D EN^ABMVDF("IOF")
  1.  W !
  1.  D CENTER^ABMUCUTL("SUMMARY OF PATIENT VOLUME REPORT TO BE GENERATED")
  1.  W !!!,"Report Name: "
  1.  I ABMY("RTYP")="SEL" W "Patient Volume Report for Eligible Professionals"
  1.  I ABMY("RTYP")="GRP" W "Patient Volume Report for Group Practice"  ;abm*2.6*8
  1.  I ABMY("RTYP")="HOS" W "Patient Volume Report for Eligible Hospitals"
  1.  W !,"The date ranges for this report are:"
  1.  W !?3,"Participation Year: ",ABMY("PYR")
  1.  W !?3,"Qualification Year: ",ABMY("QYR")
  1.  W !,"Reporting Period: "
  1.  I ABMY("90")="A" W "Automated 90-day"
  1.  I ABMY("90")="B" W "90-day beginning ",$$SDT^ABMDUTL(ABMY("SDT"))
  1.  I ABMY("90")="C" W $$SDT^ABMDUTL(ABMY("SDT"))_" thru "_$$SDT^ABMDUTL(ABMY("EDT"))
  1.  W:$G(ABMY("TVDTS")) !!,"Number of top volume dates to display if minimum thresholds are not met: ",ABMY("TVDTS")
  1.  W !!,"Report Method Type: "
  1.  W:ABMY("RTYP")="SEL" "Individual"
  1.  W:ABMY("RTYP")="GRP" "Group"  ;abm*2.6*8
  1.  W:ABMY("RTYP")="HOS" "Hospital/ER"
  1.  I ABMY("RTYP")="SEL" D
  1.  .W !!,"Eligible Professional(s):"
  1.  .S ABMPRV=0
  1.  .F  S ABMPRV=$O(ABMPRVDR(ABMPRV)) Q:'ABMPRV  D
  1.  ..W !?3,$$GET1^DIQ(200,ABMPRV,".01")_" ("_$$GET1^DIQ(7,$$GET1^DIQ(200,ABMPRV,53.5,"I"),.01,"E")_")"
  1.  W !
  1.  W !,"Facility(s):"
  1.  S ABMFC=0
  1.  F  S ABMFC=$O(ABMF(ABMFC)) Q:'ABMFC  D
  1.  .W !?3,$$GET1^DIQ(9999999.06,ABMFC,".01","E")
  1.  .;I $D(^ABMMUPRM(1,1,"B",ABMFC)) W " (FQHC/RHC)"  ;abm*2.6*10 HEAT61752
  1.  .I $D(^ABMMUPRM(1,1,"B",ABMFC)) W " (FQHC/RHC/Tribal)"  ;abm*2.6*10 HEAT61752
  1.  Q