ABMRSUBN ; IHS/SD/SDR - Resubmission Number Entry ;
;;2.6;IHS 3P BILLING SYSTEM;;NOV 12, 2009
;
; For data entry of resubmission number for claims. Claim doesn't
; need to be cancelled but number will be entered and then claim
; reprinted in order for it to show up.
;
; IHS/SD/SDR - v2.5 p13 - IM25920
; Changed field to free-text with length of 29
;
;pick bill/patient; display info and confirm selection
K DIR,DIE,DIC
K ABMP
D BILL^ABMDBDIC ;returns ABMP("BDFN") and ABMP("PDFN")
Q:$G(ABMP("BDFN"))=""
S DIR(0)="YO"
S DIR("A")="Bill "_$P(^ABMDBILL(DUZ(2),ABMP("BDFN"),0),U)
S DIR("B")="Y"
D ^DIR
Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
;
;prompt for changes
K DIR,DIE,DIC,X,Y
S DIR(0)="NOA^111:999"
S DIR("A")="Bill type: "
S DIR("B")=$P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),0)),U,2)
D ^DIR
Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
S ABMP(".02")=Y
;
K DIR,DIE,DIC,X,Y
S DIR(0)="FAO^1:29"
S DIR("A")="Resubmission (Control) Number: "
S DIR("B")=$P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),4)),U,9)
D ^DIR
Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
S ABMP(".49")=Y
;
K DIR,DIE,DIC,X,Y
S DIR(0)="FAO^3:80"
S DIR("A")="Resubmission (Control) note: "
S DIR("B")=$P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),4)),U,11)
D ^DIR
Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
S ABMP("411")=Y
;
;display bill info
W !!
S ABM("STATUS")=$P(^DD(9002274.4,.04,0),"^",3)
S ABM("CNT")=0
S ABMP("PDFN")=$P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),0)),U)
S ABM("ZERO")=^ABMDBILL(DUZ(2),ABMP("BDFN"),0)
N J F J=1:1:12 S ABM(J)=$P(ABM("ZERO"),U,J)
S ABM(7,1)=$P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),7)),U)
S ABM(2,1)=$P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),2)),U)
S ABM(4)=$P(ABM("STATUS"),ABM(4)_":",2),ABM(4)=$P(ABM(4),";",1)
W ?5,"Bill# ",ABM(1)
W ?20,$$SDT^ABMDUTL(ABM(7,1))
W ?30,$P($G(^ABMDVTYP(+ABM(7),0)),U)
W ?51,$P($G(^DIC(40.7,+ABM(10),0)),U)
W ?67,$P($G(^AUTTLOC(+ABM(3),0)),U,2)
W !,?6,$P($G(^ABMDEXP(+ABM(6),0)),U)
W ?18,$E(ABM(4),1,15)
W ?37,$P($G(^AUTNINS(+ABM(8),0)),U)
W ?70,$J($FN(ABM(2,1),",",2),10)
;
;display would be changes before filing on bill
W !!
W ?5,"Bill Type: ",ABMP(".02")
W ?40,"User: ",$P($G(^VA(200,DUZ,0)),U)
W !?5,"Resubmission Number: ",ABMP(".49")
W ?40,"Date: ",$$SDT^ABMDUTL(DT)
W !?5,"Notes: ",ABMP("411")
;
;confirm changes before filing on bill
W !!
K DIR,DIE,DIC,X,Y
S DIR(0)="YA"
S DIR("A")="Correct? "
S DIR("B")="Y"
D ^DIR
Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
Q:Y'=1
;
;
;file changes if YES
K DIC,DIE,X,Y,DA
S DIE="^ABMDBILL(DUZ(2),"
S DA=ABMP("BDFN")
S DR=".02////"_ABMP(".02")
S DR=DR_";.49////"_ABMP(".49")
S DR=DR_";411////"_ABMP("411")
D ^DIE
;
;reprint bill?
W !
K DIR,DIE,DIC,X,Y
S DIR(0)="YA"
S DIR("A")="Reprint bill? "
S DIR("B")="Y"
D ^DIR
Q:$D(DTOUT)!$D(DUOUT)!$D(DIRUT)!$D(DIROUT)
Q:Y'=1
;
S ABMY("FORM")=$P($G(^ABMDBILL(DUZ(2),ABMP("BDFN"),0)),U,6)
S ABMY("FORM")=ABMY("FORM")_"^"_$P($G(^ABMDEXP(ABMY("FORM"),0)),U)
S ABMY(ABMP("BDFN"))=""
S ABMY("TOT")="0^0^0"
S ABMP("XMIT")=0
D ZIS^ABMDFRDO
Q
ABMRSUBN ; IHS/SD/SDR - Resubmission Number Entry ;
+1 ;;2.6;IHS 3P BILLING SYSTEM;;NOV 12, 2009
+2 ;
+3 ; For data entry of resubmission number for claims. Claim doesn't
+4 ; need to be cancelled but number will be entered and then claim
+5 ; reprinted in order for it to show up.
+6 ;
+7 ; IHS/SD/SDR - v2.5 p13 - IM25920
+8 ; Changed field to free-text with length of 29
+9 ;
+10 ;pick bill/patient; display info and confirm selection
+11 KILL DIR,DIE,DIC
+12 KILL ABMP
+13 ;returns ABMP("BDFN") and ABMP("PDFN")
DO BILL^ABMDBDIC
+14 IF $GET(ABMP("BDFN"))=""
QUIT
+15 SET DIR(0)="YO"
+16 SET DIR("A")="Bill "_$PIECE(^ABMDBILL(DUZ(2),ABMP("BDFN"),0),U)
+17 SET DIR("B")="Y"
+18 DO ^DIR
+19 IF $DATA(DTOUT)!$DATA(DUOUT)!$DATA(DIRUT)!$DATA(DIROUT)
QUIT
+20 ;
+21 ;prompt for changes
+22 KILL DIR,DIE,DIC,X,Y
+23 SET DIR(0)="NOA^111:999"
+24 SET DIR("A")="Bill type: "
+25 SET DIR("B")=$PIECE($GET(^ABMDBILL(DUZ(2),ABMP("BDFN"),0)),U,2)
+26 DO ^DIR
+27 IF $DATA(DTOUT)!$DATA(DUOUT)!$DATA(DIRUT)!$DATA(DIROUT)
QUIT
+28 SET ABMP(".02")=Y
+29 ;
+30 KILL DIR,DIE,DIC,X,Y
+31 SET DIR(0)="FAO^1:29"
+32 SET DIR("A")="Resubmission (Control) Number: "
+33 SET DIR("B")=$PIECE($GET(^ABMDBILL(DUZ(2),ABMP("BDFN"),4)),U,9)
+34 DO ^DIR
+35 IF $DATA(DTOUT)!$DATA(DUOUT)!$DATA(DIRUT)!$DATA(DIROUT)
QUIT
+36 SET ABMP(".49")=Y
+37 ;
+38 KILL DIR,DIE,DIC,X,Y
+39 SET DIR(0)="FAO^3:80"
+40 SET DIR("A")="Resubmission (Control) note: "
+41 SET DIR("B")=$PIECE($GET(^ABMDBILL(DUZ(2),ABMP("BDFN"),4)),U,11)
+42 DO ^DIR
+43 IF $DATA(DTOUT)!$DATA(DUOUT)!$DATA(DIRUT)!$DATA(DIROUT)
QUIT
+44 SET ABMP("411")=Y
+45 ;
+46 ;display bill info
+47 WRITE !!
+48 SET ABM("STATUS")=$PIECE(^DD(9002274.4,.04,0),"^",3)
+49 SET ABM("CNT")=0
+50 SET ABMP("PDFN")=$PIECE($GET(^ABMDBILL(DUZ(2),ABMP("BDFN"),0)),U)
+51 SET ABM("ZERO")=^ABMDBILL(DUZ(2),ABMP("BDFN"),0)
+52 NEW J
FOR J=1:1:12
SET ABM(J)=$PIECE(ABM("ZERO"),U,J)
+53 SET ABM(7,1)=$PIECE($GET(^ABMDBILL(DUZ(2),ABMP("BDFN"),7)),U)
+54 SET ABM(2,1)=$PIECE($GET(^ABMDBILL(DUZ(2),ABMP("BDFN"),2)),U)
+55 SET ABM(4)=$PIECE(ABM("STATUS"),ABM(4)_":",2)
SET ABM(4)=$PIECE(ABM(4),";",1)
+56 WRITE ?5,"Bill# ",ABM(1)
+57 WRITE ?20,$$SDT^ABMDUTL(ABM(7,1))
+58 WRITE ?30,$PIECE($GET(^ABMDVTYP(+ABM(7),0)),U)
+59 WRITE ?51,$PIECE($GET(^DIC(40.7,+ABM(10),0)),U)
+60 WRITE ?67,$PIECE($GET(^AUTTLOC(+ABM(3),0)),U,2)
+61 WRITE !,?6,$PIECE($GET(^ABMDEXP(+ABM(6),0)),U)
+62 WRITE ?18,$EXTRACT(ABM(4),1,15)
+63 WRITE ?37,$PIECE($GET(^AUTNINS(+ABM(8),0)),U)
+64 WRITE ?70,$JUSTIFY($FNUMBER(ABM(2,1),",",2),10)
+65 ;
+66 ;display would be changes before filing on bill
+67 WRITE !!
+68 WRITE ?5,"Bill Type: ",ABMP(".02")
+69 WRITE ?40,"User: ",$PIECE($GET(^VA(200,DUZ,0)),U)
+70 WRITE !?5,"Resubmission Number: ",ABMP(".49")
+71 WRITE ?40,"Date: ",$$SDT^ABMDUTL(DT)
+72 WRITE !?5,"Notes: ",ABMP("411")
+73 ;
+74 ;confirm changes before filing on bill
+75 WRITE !!
+76 KILL DIR,DIE,DIC,X,Y
+77 SET DIR(0)="YA"
+78 SET DIR("A")="Correct? "
+79 SET DIR("B")="Y"
+80 DO ^DIR
+81 IF $DATA(DTOUT)!$DATA(DUOUT)!$DATA(DIRUT)!$DATA(DIROUT)
QUIT
+82 IF Y'=1
QUIT
+83 ;
+84 ;
+85 ;file changes if YES
+86 KILL DIC,DIE,X,Y,DA
+87 SET DIE="^ABMDBILL(DUZ(2),"
+88 SET DA=ABMP("BDFN")
+89 SET DR=".02////"_ABMP(".02")
+90 SET DR=DR_";.49////"_ABMP(".49")
+91 SET DR=DR_";411////"_ABMP("411")
+92 DO ^DIE
+93 ;
+94 ;reprint bill?
+95 WRITE !
+96 KILL DIR,DIE,DIC,X,Y
+97 SET DIR(0)="YA"
+98 SET DIR("A")="Reprint bill? "
+99 SET DIR("B")="Y"
+100 DO ^DIR
+101 IF $DATA(DTOUT)!$DATA(DUOUT)!$DATA(DIRUT)!$DATA(DIROUT)
QUIT
+102 IF Y'=1
QUIT
+103 ;
+104 SET ABMY("FORM")=$PIECE($GET(^ABMDBILL(DUZ(2),ABMP("BDFN"),0)),U,6)
+105 SET ABMY("FORM")=ABMY("FORM")_"^"_$PIECE($GET(^ABMDEXP(ABMY("FORM"),0)),U)
+106 SET ABMY(ABMP("BDFN"))=""
+107 SET ABMY("TOT")="0^0^0"
+108 SET ABMP("XMIT")=0
+109 DO ZIS^ABMDFRDO
+110 QUIT
