Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ACRFPAYU

ACRFPAYU.m

Go to the documentation of this file. 
  1. ACRFPAYU ;IHS/OIRM/DSD/THL,AEF - PAYMENT MANAGEMENT UTILITIES;  [ 11/01/2001   9:44 AM ]
  1.  ;;2.1;ADMIN RESOURCE MGT SYSTEM;;NOV 05, 2001
  1.  ;;
  1.  I '$D(^ACRAPL("AC",DUZ,38)) D  Q
  1.  .W !!,"You do not have the authority for Utility Functions."
  1.  .D PAUSE^ACRFWARN
  1. EN F  D EN1 Q:$D(ACRQUIT)!$D(ACROUT)
  1. EXIT K ACR,ACRQUIT,ACROUT
  1.  Q
  1. EN1 ;SELECT PAYMENT MANAGEMENT UTILITY
  1.  W @IOF
  1.  W !?10,"Payment Management Utilities"
  1.  S DIR(0)="SO^1:Enter Bank Information;2:Enter/Edit Object Class Codes;3:Add New Traveler;4:Print Bank Information;5:Late Payment Interest Rates;6:Add/Edit Vendor;7:Import Obligations from PCC/HAS"
  1.  S DIR("A")="Which Utility"
  1.  W !
  1.  D DIR^ACRFDIC
  1.  I +Y<1 S ACRQUIT="" Q
  1.  I Y=1 D ACHINFO Q
  1.  I Y=2 D OBJCODE^ACRFDFL1 Q
  1.  I Y=3 D ADDT Q
  1.  I Y=4 D PRINT Q
  1.  I Y=5 D LATEPAY Q
  1.  I Y=6 D VENDOR Q
  1.  I Y=7 D ^AFSLLDO1 Q
  1.  Q
  1. ACHINFO ;EP;TO EDIT ACH INFORMATION
  1.  F  D ACH1 Q:$D(ACRQUIT)!$D(ACROUT)
  1.  K ACRBTYP,ACRQUIT
  1.  Q
  1. ACH1 ;SELECT TYPE OF LOOKUP
  1.  K ACRBTYP
  1.  D WHICH
  1.  I $G(ACRBTYP)="" S ACRQUIT="" Q
  1.  F  D ACH2 Q:$D(ACRQUIT)!$D(ACROUT)
  1.  K ACRQUIT
  1.  Q
  1. ACH2 ;SELECT VENDOR OR TRAVELER
  1.  D ACHHEAD
  1.  S DIC=$S(ACRBTYP="V":"^AUTTVNDR(",1:"^ACRAU(")
  1.  S DIC(0)="AEMQZ"
  1.  S DIC("A")="Which "_$S(ACRBTYP="V":"VENDOR",1:"TRAVELER")_": "
  1.  W !
  1.  D DIC^ACRFDIC
  1.  I +Y<1 S ACRQUIT="" Q
  1.  S DA=+Y
  1.  D BANKINFO^ACRFPAY
  1.  Q
  1. ACHHEAD ;
  1.  W @IOF
  1.  W !?5,"BANK INFORMATION is CONFIDENTIAL, PROTECTED information."
  1.  W !?5,"Illegal use or dissemination of this data is against Federal Law."
  1.  Q
  1. ADDT ;ADD TRAVELERE
  1.  F  D AT1 Q:$D(ACRQUIT)!$D(ACROUT)
  1.  K ACRQUIT
  1.  Q
  1. AT1 S DIC="^ACRAU("
  1.  S DIC(0)="AELMQZ"
  1.  S DIC("A")="Traveler's NAME (LAST,FIRST): "
  1.  W !
  1.  D DIC^ACRFDIC
  1.  I +Y<1 S ACRQUIT="" Q
  1.  S (DA,ACRDUZ)=+Y
  1.  S DIE="^ACRAU("
  1.  S DDSFILE="9002185.3"
  1.  S DR="[ACR ARMS USER]"
  1.  D DDS^ACRFDIC
  1.  S DA=ACRDUZ
  1.  S ACRBTYP="T"
  1.  D BANKINFO^ACRFPAY
  1.  Q
  1. PRINT ;
  1.  D WHICH
  1.  I $G(ACRBTYP)="" K ACRQUIT Q
  1.  D ALL
  1.  I $G(ACRALL)="" K ACRQUIT Q
  1.  Q
  1. PALL ;EP;PRINT BANK INFO FOR ALL TRAVLERES/VENDORS
  1.  S FLDS="[ACR "_$S(ACRBTYP="T":"TRAVELER",1:"VENDOR")_" BANK INFO]"
  1.  S BY=.01 ;$S(ACRBTYP="T":".01;""""",1:".01")
  1.  S FR="A"
  1.  S TO="z"
  1.  S IOP=ION
  1.  S ACRDIC=$S(ACRBTYP="V":"^AUTTVNDR",1:"^ACRAU")
  1.  S DIC=ACRDIC_"("
  1.  S DIS(0)="I $G(@ACRDIC@(D0,19))]"""""
  1.  D EN1^DIP
  1.  D PAUSE^ACRFWARN
  1.  Q
  1. PSELECT ;PRINT BANK INFO FOR SELECTED TRAVLERES/VENDORS
  1.  D PSHEAD
  1.  S ACRNAM=""
  1.  F  S ACRNAM=$O(^TMP("ACRBI",$J,ACRNAM)) Q:ACRNAM=""!$D(ACRQUIT)  D
  1.  .S ACRDA=0
  1.  .F  S ACRDA=$O(^TMP("ACRBI",$J,ACRNAM,ACRDA)) Q:'ACRDA!$D(ACRQUIT)  D
  1.  ..S X=$S(ACRBTYP="T":$G(^ACRAU(ACRDA,19)),1:$G(^AUTTVNDR(ACRDA,19)))
  1.  ..W !,ACRNAM,?32,$S($P(X,U)="C":"CHECKING",$P(X,U)="S":"SAVING",1:"")
  1.  ..W ?42,$S($D(^XUSEC("ACRFZ EDIT EFT",DUZ)):$P(X,U,2),$D(^XUSEC("ACRFZ VIEW EFT",DUZ)):$P(X,U,2),1:"<HIDDEN>")
  1.  ..W ?53,$S($D(^XUSEC("ACRFZ EDIT EFT",DUZ)):$P(X,U,3),$D(^XUSEC("ACRFZ VIEW EFT",DUZ)):$P(X,U,3),1:"<HIDDEN>")
  1.  ..I IOSL-4<$Y D PAUSE^ACRFWARN Q:$D(ACRQUIT)  D PSHEAD
  1.  D PAUSE^ACRFWARN
  1.  K ACRDC
  1.  Q
  1. PSHEAD ;
  1.  W @IOF
  1.  W !,"EFT BANK INFORMATION"
  1.  W !,"REPORT DATE: "
  1.  S Y=DT
  1.  X ^DD("DD")
  1.  W Y
  1.  S ACRDC=$G(ACRDC)+1
  1.  W ?55,"PAGE: ",ACRDC
  1.  W !!,"NAME",?32,"ACCOUNT",?42,"ROUTING #",?53,"ACCOUNT #"
  1.  W !,"--------------------------------------------------------------------------------"
  1.  Q
  1. ALL S DIR(0)="SO^1:Print for ALL "_$S(ACRBTYP="T":"Travelers",1:"Vendors")_";2:Print for SELECTED "_$S(ACRBTYP="T":"Travelers",1:"Vendors")
  1.  S DIR("A")="Which one"
  1.  W !
  1.  D DIR^ACRFDIC
  1.  I Y<1 K ACRQUIT Q
  1.  S ACRALL=$S(Y=1:"ALL",1:"SELECT")
  1.  I Y=1 D ZIS Q
  1.  I Y=2 D SEL Q
  1.  Q
  1. SEL ;SELECT TRAVELER/VENDOR TO PRINT
  1.  K ^TMP("ACRBI",$J)
  1.  F  D S1 Q:$D(ACRQUIT)!$D(ACROUT)
  1.  K ACRQUIT
  1.  Q:'$D(^TMP("ACRBI",$J))
  1.  S (ACRRTN,ZTRTN)="PSELECT^ACRFPAYU"
  1.  S ZTDESC="PRINT EFT BANK INFORMATION"
  1.  D ^ACRFZIS
  1.  Q
  1. S1 S DIC=$S(ACRBTYP="T":"^ACRAU(",1:"^AUTTVNDR(")
  1.  S ACRDIC=$S(ACRBTYP="T":"^ACRAU",1:"^AUTTVNDR")
  1.  S DIC(0)="AEMQZ"
  1.  W !
  1.  D DIC^ACRFDIC
  1.  I +Y<1 S ACRQUIT="" Q
  1.  I $G(@ACRDIC@(+Y,19))="" W !!,"NO BANK INFO ON FILE" H 2 Q
  1.  S ^TMP("ACRBI",$J,$P(Y(0,0),U),+Y)=""
  1.  Q
  1. ZIS ;SELECT DEVICE
  1.  S (ACRRTN,ZTRTN)=$S(ACRALL="ALL":"PALL^ACRFPAYU",1:"PSELECT^ACRFPAYU")
  1.  S ZTDESC="EFT BANK INFORMATION"
  1.  D ^ACRFZIS
  1.  K ACRQUIT
  1.  Q
  1. WHICH ;SELECT VENDOR OR TRAVELER
  1.  K ACRBTYP
  1.  D ACHHEAD
  1.  S DIR(0)="SO^1:Vendor Banking Information;2:Traveler Banking Information"
  1.  S DIR("A")="Which Banking Information"
  1.  W !
  1.  D DIR^ACRFDIC
  1.  I +Y<1 S ACRQUIT="" Q
  1.  S ACRBTYP=$S(Y=1:"V",Y=2:"T",1:"")
  1.  Q
  1. LATEPAY ;EP;TO REVIEW/ADD/EDIT LATE PAY INTEREST RATES
  1.  F  D LP1 Q:$D(ACRQUIT)!$D(ACROUT)
  1. LPEXIT K ACRQUIT,ACRLP,ACRIR,ACRED,ACRXX,ACRYY,ACRJ
  1.  Q
  1. LP1 ;
  1.  D LPHEAD
  1.  S ACRJ=0
  1.  S ACRXX=9999
  1.  F  S ACRXX=$O(^ACRSYS(1,40,ACRXX),-1) Q:'ACRXX!(ACRJ>7)  D
  1.  .S ACRYY=$G(^ACRSYS(1,40,ACRXX,0))
  1.  .S Y=$P(ACRYY,U)
  1.  .X ^DD("DD")
  1.  .S ACRJ=ACRJ+1
  1.  .S ACRLP(ACRJ)=ACRXX
  1.  .W !?10,ACRJ
  1.  .W ?15,Y
  1.  .W ?30,$J($FN($P(ACRYY,U,2),"P",3),5)
  1.  S DIR(0)="SO^1:Edit Rate;2:ADD New Rate;3:REMOVE Rate"
  1.  S DIR("A")="Which one"
  1.  W !
  1.  D DIR^ACRFDIC
  1.  I Y<1 S ACRQUIT="" Q
  1.  I Y=1 D LPE K ACRQUIT Q
  1.  I Y=2 D LPA K ACRQUIT Q
  1.  I Y=3 D LPR K ACRQUIT Q
  1.  Q
  1. LPE ;EDIT LP RATE
  1.  S DIR(0)="NO^1:"_ACRJ
  1.  S DIR("A")="Edit which one"
  1.  W !
  1.  D DIR^ACRFDIC
  1.  I Y<1 K ACRQUIT Q
  1.  I '$D(ACRLP(+Y)) K ACRQUIT Q
  1.  S DA=+ACRLP(Y)
  1.  S DA(1)=1
  1.  S DIE="^ACRSYS(1,40,"
  1.  S DR=".01T;.02T"
  1.  W !
  1.  D DIE^ACRFDIC
  1.  Q
  1. LPA ;ADD LP RATE
  1.  S DIR(0)="DO^::ET"
  1.  S DIR("A")="EFFECTIVE DATE"
  1.  W !
  1.  D DIR^ACRFDIC
  1.  I Y<1 K ACRQUIT Q
  1.  S ACRED=Y
  1.  S DIR(0)="NOA^1:10:3"
  1.  S DIR("A")="INTEREST RATE.:  "
  1.  D DIR^ACRFDIC
  1.  I Y<1 K ACRQUIT Q
  1.  S ACRIR=Y
  1.  S X=ACRED
  1.  S DA(1)=1
  1.  S DIC="^ACRSYS(1,40,"
  1.  S DIC(0)="L"
  1.  S DIC("DR")=".02////"_ACRIR
  1.  D FILE^ACRFDIC
  1.  Q
  1. LPR ;REMOVE LP RATE
  1.  S DIR(0)="NO^1:"_ACRJ
  1.  S DIR("A")="Remove which one"
  1.  W !
  1.  D DIR^ACRFDIC
  1.  I Y<1 K ACRQUIT Q
  1.  I '$D(ACRLP(+Y)) K ACRQUIT Q
  1.  S DA=+ACRLP(Y)
  1.  S DA(1)=1
  1.  S DIK="^ACRSYS(1,40,"
  1.  D DIK^ACRFDIC
  1.  Q
  1. LPHEAD ;LP HEADER
  1.  W @IOF
  1.  W !?10,"Late Payment Interest Rates"
  1.  W !!?15,"Effective",?30,"Interest"
  1.  W !?10,"NO.",?15,"Date",?30,"Rate"
  1.  W !?10,"---",?15,"----------",?30,"--------"
  1.  Q
  1. VENDOR ;ADD/EDIT VENDOR
  1.  D EN^ACRFVEND
  1.  Q