Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: AG7P2

AG7P2.m

Go to the documentation of this file. 
  1. AG7P2 ;IHS/SD/EFG - Patient Registration 7.0 Patch 2 ENVIRONMENT CHECKER ;   [ 05/08/2003  1:14 PM ]
  1.  ;;7.0;IHS PATIENT REGISTRATION;**1,2,3**;MAR 28, 2003
  1.  ;
  1.  ;
  1.  I '$G(DUZ) W !,"DUZ UNDEFINED OR 0." D SORRY(2) Q
  1.  ;
  1.  I '$L($G(DUZ(0))) W !,"DUZ(0) UNDEFINED OR NULL." D SORRY(2) Q
  1.  ;
  1.  S X=$P(^VA(200,DUZ,0),U)
  1.  W !!,$$CJ^XLFSTR("Hello, "_$P(X,",",2)_" "_$P(X,","),IOM)
  1.  W !!,$$CJ^XLFSTR("Checking Environment for "_$P($T(+2),";",4)_" V "_$P($T(+2),";",3)_" Patch "_$P($T(+2),";",5)_".",IOM),!
  1.  ;
  1.  NEW AGQUIT
  1.  S AGQUIT=0
  1.  I '$$VCHK("AG","7.0",2) S AGQUIT=2
  1.  ;
  1.  I '$$VCHK("AUPN","99.1",2) S AGQUIT=2
  1.  ;
  1.  ;S X=$$LAST^XPDUTL("IHS DICTIONARIES (PATIENT)","99.1")
  1.  S X=$$LAST^AG7P2("IHS DICTIONARIES (PATIENT)","99.1")
  1.  I $P(X,U,1)'=12&($P(X,U,1)'>12) W !,$$CJ^XLFSTR("AUPN v99.1 Patch 12 NOT INSTALLED",IOM) S AGQUIT=2
  1.  ;
  1.  I '$$VCHK("AUT","98.1",2) S AGQUIT=2
  1.  ;
  1.  ;S X=$$LAST^XPDUTL("IHS DICTIONARIES (POINTERS)","98.1")
  1.  S X=$$LAST^AG7P2("IHS DICTIONARIES (POINTERS)","98.1")
  1.  I $P(X,U,1)'=13&($P(X,U,1)'>13) W !,$$CJ^XLFSTR("AUT v98.1 Patch 13 NOT INSTALLED",IOM) S AGQUIT=2
  1.  ;
  1.  NEW DA,DIC
  1.  S X="AG",DIC="^DIC(9.4,",DIC(0)="",D="C"
  1.  D IX^DIC
  1.  I Y<0,$D(^DIC(9.4,"C","AG")) D  S AGQUIT=2
  1.  . W !!,*7,*7,$$CJ^XLFSTR("You Have More Than One Entry In The",IOM),!,$$CJ^XLFSTR("PACKAGE File with an ""AG"" prefix.",IOM)
  1.  . W !,$$CJ^XLFSTR("One entry needs to be deleted.",IOM)
  1.  . W !,$$CJ^XLFSTR("FIX IT! Before Proceeding.",IOM),!!,*7,*7,*7
  1.  .Q
  1.  ;
  1.  I $G(XPDENV)=1 D
  1.  . ; The following line prevents the "Disable Options..." and "Move
  1.  . ; Routines..." questions from being asked during the install.
  1.  . S (XPDDIQ("XPZ1"),XPDDIQ("XPZ2"))=0
  1.  . D OPTSAV("AGMENU")
  1.  .Q
  1.  ;
  1.  I AGQUIT D SORRY(AGQUIT) Q
  1.  ;
  1.  W !!,$$CJ^XLFSTR("ENVIRONMENT OK.",IOM)
  1.  ;
  1.  I '$$DIR^XBDIR("E","","","","","",1) D SORRY(2) Q
  1.  Q
  1.  ;
  1. SORRY(X) ;
  1.  KILL DIFQ
  1.  S XPDQUIT=X
  1.  W:'$D(ZTQUEUED) *7,!,$$CJ^XLFSTR("Sorry....",IOM),$$DIR^XBDIR("E","Press RETURN")
  1.  Q
  1.  ;
  1. VCHK(AGPRE,AGVER,AGQUIT) ; Check versions needed.
  1.  ;  
  1.  NEW AGV
  1.  S AGV=$$VERSION^XPDUTL(AGPRE)
  1.  W !,$$CJ^XLFSTR("Need at least "_AGPRE_" v "_AGVER_"....."_AGPRE_" v "_AGV_" Present",IOM)
  1.  I AGV<AGVER W *7,!,$$CJ^XLFSTR("^^^^**NEEDS FIXED**^^^^",IOM) Q 0
  1.  Q 1
  1.  ;
  1. OPTSAV(AGM) ;
  1.  D BMES^XPDUTL("Saving the configuration of option '"_AGM_"'...")
  1.  I $D(^XTMP("AG7P2",7.2,"OPTSAV",AGM)) D BMES^XPDUTL("NOT SAVED.  Option '"_AGM_"' has previously been saved.") Q
  1.  I '$D(^XTMP("AG7P2")) S ^XTMP("AG7P2",0)=$$FMADD^XLFDT(DT,30)_U_DT_U_"AG7P2 - SAVE OPTION CONFIGURATIONS."
  1.  NEW I,A
  1.  S I=$O(^DIC(19,"B",AGM,0))
  1.  I 'I D BMES^XPDUTL("NOT SAVED.  Option '"_AGM_"' not found in OPTION file.") Q
  1.  S A=0
  1.  F  S A=$O(^DIC(19,I,10,A)) Q:'A  S ^XTMP("AG7P2",7.2,"OPTSAV",AGM,A)=$P(^DIC(19,+^DIC(19,I,10,A,0),0),U,1)_U_$P(^DIC(19,I,10,A,0),U,2,3)
  1.  Q
  1.  ;
  1. INSTALLD(AGINSTAL) ;EP - Determine if patch AGINSTAL was installed, where AGINSTAL is
  1.  ; the name of the INSTALL.  E.g "AG*6.0*10".
  1.  ;;^DIC(9.4,D0,22,D1,PAH,D2,0)=
  1.  ;;(#.01) PATCH APPLICATION HISTORY [1F] ^ (#.02)DATE APPLIED [2D] ^ (#.03) APPLIED BY [3P] ^ 
  1.  NEW DIC,X,Y
  1.  S X=$P(AGINSTAL,"*",1)
  1.  S DIC="^DIC(9.4,",DIC(0)="FM",D="C"
  1.  D IX^DIC
  1.  I Y<1 Q 0
  1.  S DIC=DIC_+Y_",22,",X=$P(AGINSTAL,"*",2)
  1.  D ^DIC
  1.  I Y<1 Q 0
  1.  S DIC=DIC_+Y_",""PAH"",",X=$P(AGINSTAL,"*",3)
  1.  D ^DIC
  1.  Q $S(Y<1:0,1:1)
  1.  ;
  1. LAST(PKG,VER) ;returns last patch applied for a Package, PATCH^DATE
  1.  ;        Patch includes Seq # if Released
  1.  N PKGIEN,VERIEN,LATEST,PATCH,SUBIEN
  1.  I $G(VER)="" S VER=$$VERSION^XPDUTL(PKG) Q:'VER -1
  1.  S PKGIEN=$O(^DIC(9.4,"B",PKG,"")) Q:'PKGIEN -1
  1.  S VERIEN=$O(^DIC(9.4,PKGIEN,22,"B",VER,"")) Q:'VERIEN -1
  1.  S LATEST=-1,PATCH=-1,SUBIEN=0
  1.  F  S SUBIEN=$O(^DIC(9.4,PKGIEN,22,VERIEN,"PAH",SUBIEN)) Q:SUBIEN'>0  D
  1.  . I $P(^DIC(9.4,PKGIEN,22,VERIEN,"PAH",SUBIEN,0),U,2)>LATEST S LATEST=$P(^(0),U,2),PATCH=$P(^(0),U)
  1.  Q PATCH_U_LATEST