Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: APCDDVL1

APCDDVL1.m

Go to the documentation of this file. 
  1. APCDDVL1 ; IHS/CMI/LAB - report on checked in visits with no pov ;
  1.  ;;2.0;IHS PCC SUITE;;MAY 14, 2009
  1.  ;
  1.  ;
  1. START ;
  1.  D EOJ
  1.  D INFORM
  1. GETDATES ;
  1. BD ;get beginning date
  1.  W ! S DIR(0)="D^:DT:EP",DIR("A")="Enter beginning Visit Date" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  I $D(DIRUT) G EOJ
  1.  S APCDBD=Y
  1. ED ;get ending date
  1.  W ! S DIR(0)="DA^"_APCDBD_":DT:EP",DIR("A")="Enter ending Visit Date:  " S Y=APCDBD D DD^%DT S Y="" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  I $D(DIRUT) G BD
  1.  S APCDED=Y
  1.  ;
  1. WHICH ;
  1.  K APCDHLOC
  1.  K DIR
  1.  S DIR(0)="S^A:ALL Visits;H:Visits to Selected Hospital Locations (Scheduling Clinics)"
  1.  S DIR("A")="Which Visits do you want to display",DIR("B")="A" KILL DA D ^DIR KILL DIR
  1.  I $D(DIRUT) G BD
  1.  I Y="A" K APCDHLOC G SORT
  1. HLOC ;
  1.  S DIC="^SC(",DIC(0)="AEMQ",DIC("A")="Which HOSPITAL LOCATION: " D ^DIC K DIC
  1.  I X="" W:'$D(APCDHLOC) !!,"No Hospital Locations selected, all will be included." G SORT
  1.  I Y=-1 W:'$D(APCDHLOC) !!,"No Hospital Locations selected, all will be included." G SORT
  1.  S APCDHLOC(+Y)=""
  1.  G HLOC
  1. SORT ;
  1.  S APCDCSRT=""
  1.  W !!,"*** NOTE:  If you pick Visit date order the report will be sorted by Visit date",!,"and sub-sorted by clinic code.  All others will be sub-sorted by visit date."
  1.  S DIR(0)="S^T:Terminal Digit Order;H:Health Record Number Order;D:Visit Date Order;C:Clinic Code Order",DIR("A")="Sort the report by",DIR("B")="T" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  I $D(DIRUT) G BD
  1.  S APCDCSRT=Y
  1. DEMO ;
  1.  D DEMOCHK^APCLUTL(.APCDDEMO)
  1.  I APCDDEMO=-1 G BD
  1. ZIS ;call to XBDBQUE
  1.  S XBRP="PRINT^APCDDVL1",XBRC="PROCESS^APCDDVL1",XBRX="EOJ^APCDDVL1",XBNS="APCD"
  1.  D ^XBDBQUE
  1.  D EOJ
  1.  Q
  1.  ;
  1. EOJ ;
  1.  D EN^XBVK("APCD")
  1.  Q
  1. PROCESS ;EP - called from XBDBQUE
  1.  S ^XTMP("APCDDVL1",0)=$$FMADD^XLFDT(DT,14)_"^"_DT_"^"_"APCD - CHECKED IN VISIT REPORT"
  1.  S APCDJ=$J,APCDBT=$H,APCDTOT=0
  1.  ;go through all visits (B index) check for option used to create
  1.  ;and check for no POV 
  1.  ;print name, hrn, date/time, clinic, primary prov, and any other visits on that day
  1.  ;
  1.  S APCDT=APCDBD-.0001,APCDEND=APCDED+.2400
  1.  F  S APCDT=$O(^AUPNVSIT("B",APCDT)) Q:'APCDT!(APCDT>APCDEND)  D
  1.  . S APCDV=0
  1.  . F  S APCDV=$O(^AUPNVSIT("B",APCDT,APCDV)) Q:'APCDV  D
  1.  .. I $$VAL^XBDIQ1(9000010,APCDV,.24)'="SD IHS PCC LINK" Q  ;not created by check in
  1.  .. Q:$$DEMO^APCLUTL($P(^AUPNVSIT(APCDV,0),U,5),APCDDEMO)
  1.  .. I $P(^AUPNVSIT(APCDV,0),U,6)'=DUZ(2) Q  ;another facilities visit
  1.  .. Q:$D(^AUPNVPOV("AD",APCDV))  ;already been coded
  1.  .. Q:$P(^AUPNVSIT(APCDV,0),U,11)  ;deleted
  1.  .. I $D(APCDHLOC) S X=$P(^AUPNVSIT(APCDV,0),U,22) Q:X=""  Q:'$D(APCDHLOC(X))
  1.  .. S APCDSORT="" D GETSORT I APCDSORT="" S APCDSORT="??"
  1.  .. S ^XTMP("APCDDVL1",APCDJ,APCDBT,"VISITS",APCDSORT,APCDSSRT,APCDV)="",APCDTOT=APCDTOT+1
  1.  .. Q
  1.  . Q
  1.  Q
  1. GETSORT ;get sort value
  1.  I APCDCSRT="D" S APCDSORT=$P($P(^AUPNVSIT(APCDV,0),U),"."),APCDSSRT=$$CLINIC^APCLV(APCDV,"C") S:APCDSSRT="" APCDSSRT="??" Q
  1.  I APCDCSRT="C" S APCDSORT=$$CLINIC^APCLV(APCDV,"C"),APCDSSRT=$P($P(^AUPNVSIT(APCDV,0),U),".") Q  ;clinic code
  1.  ;hrn sort values
  1.  S APCDSORT=$$HRN^AUPNPAT($P(^AUPNVSIT(APCDV,0),U,5),DUZ(2)),APCDSSRT=$P($P(^AUPNVSIT(APCDV,0),U),".") S:APCDSORT="" APCDSORT="?????"
  1.  Q:APCDSORT="?????"
  1.  Q:APCDCSRT'="T"
  1.  S APCDSORT=APCDSORT+10000000,APCDSORT=$E(APCDSORT,7,8)_"-"_+$E(APCDSORT,2,8)
  1.  Q
  1. PRINT ;EP - called from XBDBQUE
  1.  S APCDQUIT="",APCDPG=0 D HDR
  1.  I '$D(^XTMP("APCDDVL1",APCDJ,APCDBT)) W !!,"NO DATA TO REPORT",! G DONE
  1.  S APCDSORT="" F  S APCDSORT=$O(^XTMP("APCDDVL1",APCDJ,APCDBT,"VISITS",APCDSORT)) Q:APCDSORT=""!(APCDQUIT)  D
  1.  .S APCDSSRT="" F  S APCDSSRT=$O(^XTMP("APCDDVL1",APCDJ,APCDBT,"VISITS",APCDSORT,APCDSSRT)) Q:APCDSSRT=""!(APCDQUIT)  D
  1.  .. S APCDV=0 F  S APCDV=$O(^XTMP("APCDDVL1",APCDJ,APCDBT,"VISITS",APCDSORT,APCDSSRT,APCDV)) Q:APCDV'=+APCDV!(APCDQUIT)  D
  1.  ... I $Y>(IOSL-4) D HDR Q:APCDQUIT
  1.  ... S APCDVR=^AUPNVSIT(APCDV,0)
  1.  ... W !,$E($P(^DPT($P(APCDVR,U,5),0),U),1,15),?16,$$HRN^AUPNPAT($P(APCDVR,U,5),DUZ(2)),?23,$$FMTE^XLFDT($P(APCDVR,U)),?42,$P(APCDVR,U,7),?45,$$CLINIC^APCLV(APCDV,"C")
  1.  ... W ?48,$E($$VAL^XBDIQ1(9000010,APCDV,.22),1,15),?64,$$PRIMPROV^APCLV(APCDV,"P")
  1.  ... S C=$$VCNT(APCDV) W ?72,$P(C,U),"  ",$P(C,U,2)
  1.  ... Q
  1.  .. Q
  1.  . Q
  1.  G:APCDQUIT DONE
  1.  I $Y>(IOSL-3) D HDR G:APCDQUIT DONE
  1.  W !!,"Total Number of Visits:  ",APCDTOT
  1. DONE ;
  1.  K ^XTMP("APCDDVL1",APCDJ,APCDBT),APCDJ,APCDBT
  1.  I $E(IOST)="C",IO=IO(0) S DIR(0)="EO",DIR("A")="End of report.  HIT RETURN" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  W:$D(IOF) @IOF
  1.  Q
  1. VCNT(V) ;return number of other visits on this date
  1.  I '$G(V) Q 0
  1.  I '$D(^AUPNVSIT(V)) Q 0
  1.  NEW D,X,Y,C,DATE,END,P
  1.  S P=$P(^AUPNVSIT(V,0),U,5)
  1.  S D=$P($P(^AUPNVSIT(V,0),U),".")
  1.  S (C,C1)=0,DATE=(9999999-D)-.0001,END=(9999999-D)+.9999999
  1.  F  S DATE=$O(^AUPNVSIT("AA",P,DATE)) Q:'DATE!(DATE>END)  D
  1.  . S X=0 F  S X=$O(^AUPNVSIT("AA",P,DATE,X)) Q:X'=+X  I X'=V,'$P(^AUPNVSIT(X,0),U,11) S C=C+1 I $D(^AUPNVPOV("AD",X)),$D(^AUPNVPRV("AD",X)) S C1=C1+1
  1.  Q C_U_C1
  1.  ;
  1. HDR ;header for report
  1.  I 'APCDPG G HDR1
  1.  I $E(IOST)="C",IO=IO(0) W ! S DIR(0)="EO" D ^DIR K DIR I Y=0!(Y="^")!($D(DTOUT)) S APCDQUIT=1 Q
  1. HDR1 ;
  1.  W:$D(IOF) @IOF S APCDPG=APCDPG+1
  1.  W $P(^VA(200,DUZ,0),U,2),$$CTR($$FMTE^XLFDT(DT)),?71,"Page ",APCDPG,!
  1.  W $$CTR($$LOC),!
  1.  W $$CTR("CHECKED IN VISITS WITH NO POV (NOT YET CODED)"),!
  1.  NEW % S %="Visit dates: "_$$FMTE^XLFDT(APCDBD)_" to "_$$FMTE^XLFDT(APCDED) W $$CTR(%),! ;CMI/TUCSON added 11/3/98
  1.  W "** Last column is the number of other visits on the same day and the",!," # of those visits that are complete",!!
  1.  W ?3,"PATIENT NAME",?17," HRN",?23,"VISIT DATE&TIME",?42,"SC",?45,"CL",?48,"HOSPITAL LOC",?64,"PROV",?72,"# visits",!
  1.  W $TR($J(" ",80)," ","-"),!
  1.  Q
  1. CTR(X,Y) ;EP - Center X in a field Y wide.
  1.  Q $J("",$S($D(Y):Y,1:IOM)-$L(X)\2)_X
  1.  ;----------
  1. USR() ;EP - Return name of current user from ^VA(200.
  1.  Q $S($G(DUZ):$S($D(^VA(200,DUZ,0)):$P(^(0),U),1:"UNKNOWN"),1:"DUZ UNDEFINED OR 0")
  1.  ;----------
  1. LOC() ;EP - Return location name from file 4 based on DUZ(2).
  1.  Q $S($G(DUZ(2)):$S($D(^DIC(4,DUZ(2),0)):$P(^(0),U),1:"UNKNOWN"),1:"DUZ(2) UNDEFINED OR 0")
  1.  ;----------
  1. INFORM ;let user know what is gong on
  1.  W:$D(IOF) @IOF
  1.  W !!,$$CTR($$LOC,80)
  1.  W !,$$CTR($$USR,80),!!
  1.  F I=1:1 S X=$P($T(INTRO+I),";;",2) Q:X="END"  W !,X
  1.  K I,X
  1.  Q
  1. INTRO ;;
  1.  ;;This report will list all PCC Visits that were created by the
  1.  ;;Scheduling Check-In process that do not yet have a Purpose of Visit.
  1.  ;;This report will be used to determine if PCC forms have been submitted
  1.  ;;for these visits or if an additional visit has been created for this scheduled 
  1.  ;;visit.
  1.  ;;END