Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: APCDDVL3

APCDDVL3.m

Go to the documentation of this file. 
  1. APCDDVL3 ; IHS/CMI/LAB - report on checked in visits with no pov ;
  1.  ;;2.0;IHS PCC SUITE;;MAY 14, 2009
  1.  ;IHS/CMI/LAB - patch 1 Y2K
  1.  ;
  1.  ;
  1. START ;
  1.  D EOJ
  1.  D INFORM
  1. GETDATES ;
  1. BD ;get beginning date
  1.  W ! S DIR(0)="D^:DT:EP",DIR("A")="Enter beginning Visit Date" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  I $D(DIRUT) G EOJ
  1.  S APCDBD=Y
  1. ED ;get ending date
  1.  W ! S DIR(0)="DA^"_APCDBD_":DT:EP",DIR("A")="Enter ending Visit Date:  " S Y=APCDBD D DD^%DT S Y="" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  I $D(DIRUT) G BD
  1.  S APCDED=Y
  1.  ;
  1. SORT ;
  1.  S APCDCSRT=""
  1.  S DIR(0)="S^T:Terminal Digit Order;H:Health Record Number Order;D:Visit Date Order;C:Clinic Code Order",DIR("A")="Sort the report by",DIR("B")="T" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  I $D(DIRUT) G ED
  1.  S APCDCSRT=Y
  1. DEMO ;
  1.  D DEMOCHK^APCLUTL(.APCDDEMO)
  1.  I APCDDEMO=-1 G BD
  1. ZIS ;call to XBDBQUE
  1.  S XBRP="PRINT^APCDDVL3",XBRC="PROCESS^APCDDVL3",XBRX="EOJ^APCDDVL3",XBNS="APCD"
  1.  D ^XBDBQUE
  1.  D EOJ
  1.  Q
  1.  ;
  1. EOJ ;
  1.  D EN^XBVK("APCD")
  1.  Q
  1. PROCESS ;EP - called from XBDBQUE
  1.  S ^XTMP("APCDDVL3",0)=$$FMADD^XLFDT(DT,14)_"^"_DT_"^"_"APCD - 12:00 VISITS W NO BILL LINK"
  1.  S APCDJ=$J,APCDBT=$H
  1.  S APCDT=APCDBD-.0001,APCDEND=APCDED+.2400
  1.  F  S APCDT=$O(^AUPNVSIT("B",APCDT)) Q:'APCDT!(APCDT>APCDEND)  D
  1.  . S APCDV=0
  1.  . F  S APCDV=$O(^AUPNVSIT("B",APCDT,APCDV)) Q:'APCDV  D
  1.  .. I $P($P(^AUPNVSIT(APCDV,0),U),".",2)'=12 Q  ;no a 12:00 visit
  1.  .. Q:$$DEMO^APCLUTL($P(^AUPNVSIT(APCDV,0),U,5),APCDDEMO)
  1.  .. I $P(^AUPNVSIT(APCDV,0),U,28)]"" Q  ;has billing link
  1.  .. I $P(^AUPNVSIT(APCDV,0),U,6)'=DUZ(2) Q  ;another facilities visit
  1.  .. ;I $$PRIMPROV^APCLV(APCDV)]"",$D(^AUPNVPOV("AD",APCDV)) Q  ;COMPLETE VISIT
  1.  .. Q:"AORS"'[$P(^AUPNVSIT(APCDV,0),U,7)
  1.  .. S APCDSORT="" D GETSORT I APCDSORT="" S APCDSORT="??"
  1.  .. S ^XTMP("APCDDVL3",APCDJ,APCDBT,"VISITS",APCDSORT,APCDV)=""
  1.  .. Q
  1.  . Q
  1.  Q
  1. GETSORT ;get sort value
  1.  I APCDCSRT="D" S APCDSORT=$P(^AUPNVSIT(APCDV,0),U) Q
  1.  I APCDCSRT="C" S APCDSORT=$$CLINIC^APCLV(APCDV,"C") Q  ;clinic code
  1.  ;hrn sort values
  1.  S APCDSORT=$$HRN^AUPNPAT($P(^AUPNVSIT(APCDV,0),U,5),DUZ(2))
  1.  Q:APCDCSRT'="T"
  1.  S APCDSORT=APCDSORT+10000000,APCDSORT=$E(APCDSORT,7,8)_"-"_+$E(APCDSORT,2,8)
  1.  Q
  1. PRINT ;EP - called from XBDBQUE
  1.  S APCDQUIT="",APCDPG=0 D HDR
  1.  I '$D(^XTMP("APCDDVL3",APCDJ,APCDBT)) D HDR W !!,"NO DATA TO REPORT",! G DONE
  1.  S APCDSORT="" F  S APCDSORT=$O(^XTMP("APCDDVL3",APCDJ,APCDBT,"VISITS",APCDSORT)) Q:APCDSORT=""!(APCDQUIT)  D
  1.  . S APCDV=0 F  S APCDV=$O(^XTMP("APCDDVL3",APCDJ,APCDBT,"VISITS",APCDSORT,APCDV)) Q:APCDV'=+APCDV!(APCDQUIT)  D
  1.  .. I $Y>(IOSL-4) D HDR Q:APCDQUIT
  1.  .. S APCDVR=^AUPNVSIT(APCDV,0)
  1.  .. ;beginning Y2K - change 2 parameter to 5
  1.  .. ;W !!,$E($P(^DPT($P(APCDVR,U,5),0),U),1,15),?16,$$HRN^AUPNPAT($P(APCDVR,U,5),DUZ(2)),?23,$$FMTE^XLFDT($P(APCDVR,U),"2"),?38,$P(APCDVR,U,7),?40,$$CLINIC^APCLV(APCDV,"C") ;Y2000
  1.  .. W !!,$E($P(^DPT($P(APCDVR,U,5),0),U),1,15),?16,$$HRN^AUPNPAT($P(APCDVR,U,5),DUZ(2)),?23,$$FMTE^XLFDT($P(APCDVR,U),"5"),?38,$P(APCDVR,U,7),?40,$$CLINIC^APCLV(APCDV,"C") ;Y2000
  1.  .. ;end Y2K
  1.  .. K APCDX,APCDD D DE
  1.  .. S APCDY=0 F  S APCDY=$O(APCDX(APCDY)) Q:APCDY'=+APCDY!(APCDQUIT)  D
  1.  ... I $Y>(IOSL-3) D HDR Q:APCDQUIT
  1.  ... W:APCDY>1 !
  1.  ... ;beginning Y2K
  1.  ... ;W ?43,$P(APCDX(APCDY),U),?54,$E($P(APCDX(APCDY),U,2),1,15),?70,$$FMTE^XLFDT($P(APCDX(APCDY),U,3),"2") ;Y2000
  1.  ... W ?43,$P(APCDX(APCDY),U),?54,$E($P(APCDX(APCDY),U,2),1,15),?70,$$FMTE^XLFDT($P(APCDX(APCDY),U,3),"5") ;Y2000
  1.  ... ;end Y2K
  1.  .. S APCDP=$P(^AUPNVSIT(APCDV,0),U,5)
  1.  .. S APCDY=0,APCDORDT="" F  S APCDY=$O(APCDX(APCDY)) Q:APCDY'=+APCDY!(APCDORDT)  S APCDORDT=$P(APCDX(APCDY),U,3)
  1.  .. Q:APCDORDT=""
  1.  .. S C=0,APCDDATE=(9999999-APCDORDT)-.0001,END=(9999999-APCDORDT)+.9999999
  1.  .. F  S APCDDATE=$O(^AUPNVSIT("AA",APCDP,APCDDATE)) Q:'APCDDATE!(APCDDATE>END)!(APCDQUIT)  D
  1.  ... S APCDX=0 F  S APCDX=$O(^AUPNVSIT("AA",APCDP,APCDDATE,APCDX)) Q:APCDX'=+APCDX!(APCDQUIT)  I APCDX'=APCDV,'$P(^AUPNVSIT(APCDX,0),U,11) S C=C+1 D
  1.  .... I $Y>(IOSL-3) D HDR Q:(APCDQUIT)
  1.  .... W ! W:C=1 ?3,"Order date vsts: "
  1.  .... ;beginning Y2K
  1.  .... ;W ?21,$$FMTE^XLFDT($P(^AUPNVSIT(APCDX,0),U),"2"),?38,$P(^AUPNVSIT(APCDX,0),U,7),?39,$$CLINIC^APCLV(APCDX,"C"),?42,$E($$VAL^XBDIQ1(9000010,APCDX,.22),1,15),?58,$E($$PRIMPROV^APCLV(APCDX,"N"),1,15),?74,$$PRIMPOV^APCLV(APCDX,"C") ;Y2000
  1.  .... W ?21,$$FMTE^XLFDT($P(^AUPNVSIT(APCDX,0),U),"5"),?38,$P(^AUPNVSIT(APCDX,0),U,7),?39,$$CLINIC^APCLV(APCDX,"C"),?42,$E($$VAL^XBDIQ1(9000010,APCDX,.22),1,15),?58,$E($$PRIMPROV^APCLV(APCDX,"N"),1,15),?74,$$PRIMPOV^APCLV(APCDX,"C") ;Y2000
  1.  .... ;end Y2K
  1.  .... Q
  1.  ... Q
  1.  .. Q
  1.  .Q
  1. DONE ;
  1.  K ^XTMP("APCDDVL3",APCDJ,APCDBT),APCDJ,APCDBT
  1.  I $E(IOST)="C",IO=IO(0) S DIR(0)="EO",DIR("A")="End of report.  PRESS ENTER" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  W:$D(IOF) @IOF
  1.  Q
  1. DTC(V) ;any v tran code with an ordering provider? 1 or 0
  1.  I '$G(V) Q 0
  1.  I '$D(^AUPNVSIT(V,0)) Q 0
  1.  I '$D(^AUPNVTC("AD",V)) Q 0
  1.  NEW C
  1.  S (X,C)=0 F  S X=$O(^AUPNVTC("AD",V,X)) Q:X'=+X  I $P($G(^AUPNVTC(X,12)),U,11) S C=C+1
  1.  Q C
  1.  ;
  1. DE ;EP;FIND DEP ENTRIES
  1.  K APCDX,APCDD S APCDC=0
  1.  S APCDVFLE=9000010 F  S APCDVFLE=$O(^DIC(APCDVFLE)) Q:APCDVFLE>9000010.99!(APCDVFLE'=+APCDVFLE)  D DE2
  1.  Q
  1.  ;
  1. DE2 ;
  1.  S APCDVDG=^DIC(APCDVFLE,0,"GL"),APCDVIGR=APCDVDG_"""AD"",APCDV,APCDVDFN)"
  1.  S APCDVDFN="" I $O(@APCDVIGR)]"" S APCDC=APCDC+1,APCDX(APCDC)=$E($P($P(^DIC(APCDVFLE,0),U),"V ",2),1,3)_"'s" S Y=$O(@APCDVIGR) S $P(APCDX(APCDC),U,3)=$$VALI^XBDIQ1(APCDVFLE,Y,1211),$P(APCDX(APCDC),U,2)=$$VAL^XBDIQ1(APCDVFLE,Y,1202)
  1.  Q
  1.  ;
  1. HDR ;header for report
  1.  I 'APCDPG G HDR1
  1.  I $E(IOST)="C",IO=IO(0) W ! S DIR(0)="EO" D ^DIR K DIR I Y=0!(Y="^")!($D(DTOUT)) S APCDQUIT=1 Q
  1. HDR1 ;
  1.  W:$D(IOF) @IOF S APCDPG=APCDPG+1
  1.  W $P(^VA(200,DUZ,0),U,2),$$CTR($$FMTE^XLFDT(DT)),?71,"Page ",APCDPG,!
  1.  W $$CTR($$LOC),!
  1.  W $$CTR("12:00 Visits with No Billing Link"),!
  1.  W !?3,"PATIENT NAME",?17,"HRN",?22,"VISIT DATE",?37,"SC",?40,"CL",?43,"V FILE'S",?54,"ORDER PROV",?70,"ORDER DATE"
  1.  W $TR($J(" ",80)," ","-"),!
  1.  Q
  1. CTR(X,Y) ;EP - Center X in a field Y wide.
  1.  Q $J("",$S($D(Y):Y,1:IOM)-$L(X)\2)_X
  1.  ;----------
  1. USR() ;EP - Return name of current user from ^VA(200.
  1.  Q $S($G(DUZ):$S($D(^VA(200,DUZ,0)):$P(^(0),U),1:"UNKNOWN"),1:"DUZ UNDEFINED OR 0")
  1.  ;----------
  1. LOC() ;EP - Return location name from file 4 based on DUZ(2).
  1.  Q $S($G(DUZ(2)):$S($D(^DIC(4,DUZ(2),0)):$P(^(0),U),1:"UNKNOWN"),1:"DUZ(2) UNDEFINED OR 0")
  1.  ;----------
  1. INFORM ;let user know what is gong on
  1.  W:$D(IOF) @IOF
  1.  W !!,$$CTR($$LOC,80)
  1.  W !,$$CTR($$USR,80),!!
  1.  F I=1:1 S X=$P($T(INTRO+I),";;",2) Q:X="END"  W !,X
  1.  K I,X
  1.  Q
  1. INTRO ;;
  1.  ;;This report will list all visits with a time of 12:00 that have no billing
  1.  ;;link.  Only visits with a service category of A,O,R and s are reviewed.
  1.  ;;Only visits to the location list above are reviewed.
  1.  ;;
  1.  ;;END