Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: APCDDVL4

APCDDVL4.m

Go to the documentation of this file. 
  1. APCDDVL4 ; IHS/CMI/LAB - report on T/C VISITS WITH ANCILLARY ;
  1.  ;;2.0;IHS PCC SUITE;;MAY 14, 2009
  1.  ;IHS/CMI/LAB - patch 1 Y2K
  1.  ;
  1.  ;
  1. START ;
  1.  D EOJ
  1.  D INFORM
  1. GETDATES ;
  1. BD ;get beginning date
  1.  W ! S DIR(0)="D^:DT:EP",DIR("A")="Enter beginning Visit Date" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  I $D(DIRUT) G EOJ
  1.  S APCDBD=Y
  1. ED ;get ending date
  1.  W ! S DIR(0)="DA^"_APCDBD_":DT:EP",DIR("A")="Enter ending Visit Date:  " S Y=APCDBD D DD^%DT S Y="" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  I $D(DIRUT) G BD
  1.  S APCDED=Y
  1.  ;
  1. SORT ;
  1.  S APCDCSRT=""
  1.  S DIR(0)="S^T:Terminal Digit Order;H:Health Record Number Order;D:Visit Date Order",DIR("A")="Sort the report by",DIR("B")="T" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  I $D(DIRUT) G ED
  1.  S APCDCSRT=Y
  1. DEMO ;
  1.  D DEMOCHK^APCLUTL(.APCDDEMO)
  1.  I APCDDEMO=-1 G BD
  1. ZIS ;call to XBDBQUE
  1.  S XBRP="PRINT^APCDDVL4",XBRC="PROCESS^APCDDVL4",XBRX="EOJ^APCDDVL4",XBNS="APCD"
  1.  D ^XBDBQUE
  1.  D EOJ
  1.  Q
  1.  ;
  1. EOJ ;
  1.  D EN^XBVK("APCD")
  1.  Q
  1. PROCESS ;EP - called from XBDBQUE
  1.  S ^XTMP("APCDDVL4",0)=$$FMADD^XLFDT(DT,14)_"^"_DT_"^"_"APCD - C OR T WITH ANCILLARY"
  1.  S APCDJ=$J,APCDBT=$H
  1.  S APCDT=APCDBD-.0001,APCDEND=APCDED+.2400
  1.  F  S APCDT=$O(^AUPNVSIT("B",APCDT)) Q:'APCDT!(APCDT>APCDEND)  D
  1.  . S APCDV=0
  1.  . F  S APCDV=$O(^AUPNVSIT("B",APCDT,APCDV)) Q:'APCDV  D
  1.  .. S G=0 D
  1.  ... Q:$$DEMO^APCLUTL($P(^AUPNVSIT(APCDV,0),U,5),APCDDEMO)
  1.  ... I $P(^AUPNVSIT(APCDV,0),U,7)="T" S G=1  ;telephone serv cat
  1.  ... I $P(^AUPNVSIT(APCDV,0),U,7)="C" S G=1  ;chart review serv cat
  1.  ... S C=$$CLINIC^APCLV(APCDV,"C")
  1.  ... I C=52 S G=1  ;CHART REVIEW
  1.  ... I C=51 S G=1  ;TELEPHONE CLINIC
  1.  .. Q:'G
  1.  .. Q:'$$ANCIL(APCDV)  ;no ancillary item
  1.  .. S APCDSORT="" D GETSORT I APCDSORT="" S APCDSORT="??"
  1.  .. S ^XTMP("APCDDVL4",APCDJ,APCDBT,"VISITS",APCDSORT,APCDV)=""
  1.  .. Q
  1.  . Q
  1.  Q
  1. ANCIL(V) ;
  1.  I $D(^AUPNVMED("AD",V)),'$$RTS(V) Q 1
  1.  I $D(^AUPNVLAB("AD",V)) Q 1
  1.  I $D(^AUPNVMIC("AD",V)) Q 1
  1.  I $D(^AUPNVBB("AD",V)) Q 1
  1.  I $D(^AUPNVRAD("AD",V)) Q 1
  1.  Q 0
  1. RTS(V) ;
  1.  NEW G,X,C
  1.  ;if all have returned to stock
  1.  S G=0,X=0,C=0
  1.  F  S X=$O(^AUPNVMED("AD",V,X)) Q:X'=+X  D
  1.  .S C=C+1  ;# OF VMEDS
  1.  .I $P($G(^AUPNVMED(X,11)),U)["RETURNED TO STOCK" S G=G+1
  1.  .Q
  1.  I G=C Q 1
  1.  Q 0
  1. GETSORT ;get sort value
  1.  I APCDCSRT="D" S APCDSORT=$P(^AUPNVSIT(APCDV,0),U) Q
  1.  ;I APCDCSRT="C" S APCDSORT=$$CLINIC^APCLV(APCDV,"C") Q  ;clinic code
  1.  ;hrn sort values
  1.  S APCDSORT=$$HRN^AUPNPAT($P(^AUPNVSIT(APCDV,0),U,5),DUZ(2))
  1.  Q:APCDCSRT'="T"
  1.  S APCDSORT=APCDSORT+10000000,APCDSORT=$E(APCDSORT,7,8)_"-"_+$E(APCDSORT,2,8)
  1.  Q
  1. PRINT ;EP - called from XBDBQUE
  1.  S APCDQUIT="",APCDPG=0 D HDR
  1.  I '$D(^XTMP("APCDDVL4",APCDJ,APCDBT)) D HDR W !!,"NO DATA TO REPORT",! G DONE
  1.  S APCDSORT="" F  S APCDSORT=$O(^XTMP("APCDDVL4",APCDJ,APCDBT,"VISITS",APCDSORT)) Q:APCDSORT=""!(APCDQUIT)  D
  1.  . S APCDV=0 F  S APCDV=$O(^XTMP("APCDDVL4",APCDJ,APCDBT,"VISITS",APCDSORT,APCDV)) Q:APCDV'=+APCDV!(APCDQUIT)  D
  1.  .. I $Y>(IOSL-4) D HDR Q:APCDQUIT
  1.  .. S APCDVR=^AUPNVSIT(APCDV,0)
  1.  .. W !,$E($P(^DPT($P(APCDVR,U,5),0),U),1,15),?16,$$HRN^AUPNPAT($P(APCDVR,U,5),DUZ(2)),?24,$$DATE($P($P(APCDVR,U),".")),?36,$P(APCDVR,U,7),?39,$$CLINIC^APCLV(APCDV,"C") ;Y2000
  1.  .. K APCDX,APCDD D DE
  1.  .. S APCDY=0 F  S APCDY=$O(APCDX(APCDY)) Q:APCDY'=+APCDY!(APCDQUIT)  D
  1.  ... I $Y>(IOSL-3) D HDR Q:APCDQUIT
  1.  ... W:APCDY>1 !
  1.  ... ;beginning Y2K
  1.  ... W ?45,$P(APCDX(APCDY),U),?54,$E($P(APCDX(APCDY),U,2),1,15),?70,$$DATE($P($P(APCDX(APCDY),U,3),".")) ;Y2000
  1.  .Q
  1. DONE ;
  1.  K ^XTMP("APCDDVL4",APCDJ,APCDBT),APCDJ,APCDBT
  1.  I $E(IOST)="C",IO=IO(0) S DIR(0)="EO",DIR("A")="End of report.  PRESS ENTER" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  W:$D(IOF) @IOF
  1.  Q
  1. DE ;EP;FIND DEP ENTRIES
  1.  K APCDX,APCDD S APCDC=0
  1.  S APCDVFLE=9000010 F  S APCDVFLE=$O(^DIC(APCDVFLE)) Q:APCDVFLE>9000010.99!(APCDVFLE'=+APCDVFLE)  D DE2
  1.  Q
  1.  ;
  1. DE2 ;
  1.  I '$$DF(APCDVFLE) Q
  1.  S APCDVDG=^DIC(APCDVFLE,0,"GL"),APCDVIGR=APCDVDG_"""AD"",APCDV,APCDVDFN)"
  1.  S APCDVDFN="" I $O(@APCDVIGR)]"" S APCDC=APCDC+1,APCDX(APCDC)=$E($P($P(^DIC(APCDVFLE,0),U),"V ",2),1,3)_"'s" S Y=$O(@APCDVIGR) S $P(APCDX(APCDC),U,3)=$$VALI^XBDIQ1(APCDVFLE,Y,1211),$P(APCDX(APCDC),U,2)=$$VAL^XBDIQ1(APCDVFLE,Y,1202)
  1.  Q
  1.  ;
  1. DATE(D) ;
  1.  I D="" Q ""
  1.  Q $E(D,4,5)_"/"_$E(D,6,7)_"/"_(1700+$E(D,1,3))
  1. DF(F) ;
  1.  I F=9000010.09 Q 1
  1.  I F=9000010.14 Q 1
  1.  I F=9000010.22 Q 1
  1.  I F=9000010.25 Q 1
  1.  I F=9000010.31 Q 1
  1.  Q 0
  1. HDR ;header for report
  1.  I 'APCDPG G HDR1
  1.  I $E(IOST)="C",IO=IO(0) W ! S DIR(0)="EO" D ^DIR K DIR I Y=0!(Y="^")!($D(DTOUT)) S APCDQUIT=1 Q
  1. HDR1 ;
  1.  W:$D(IOF) @IOF S APCDPG=APCDPG+1
  1.  W $P(^VA(200,DUZ,0),U,2),$$CTR($$FMTE^XLFDT(DT)),?71,"Page ",APCDPG,!
  1.  W $$CTR($$LOC),!
  1.  W $$CTR("Chart Review and Telephone Call visits with ancillary data"),!
  1.  W !?3,"PATIENT NAME",?17,"HRN",?24,"VISIT DATE",?36,"SC",?39,"CL",?45,"DATA",?54,"ORDER PROV",?70,"ORDER DATE"
  1.  W $TR($J(" ",80)," ","-"),!
  1.  Q
  1. CTR(X,Y) ;EP - Center X in a field Y wide.
  1.  Q $J("",$S($D(Y):Y,1:IOM)-$L(X)\2)_X
  1.  ;----------
  1. USR() ;EP - Return name of current user from ^VA(200.
  1.  Q $S($G(DUZ):$S($D(^VA(200,DUZ,0)):$P(^(0),U),1:"UNKNOWN"),1:"DUZ UNDEFINED OR 0")
  1.  ;----------
  1. LOC() ;EP - Return location name from file 4 based on DUZ(2).
  1.  Q $S($G(DUZ(2)):$S($D(^DIC(4,DUZ(2),0)):$P(^(0),U),1:"UNKNOWN"),1:"DUZ(2) UNDEFINED OR 0")
  1.  ;----------
  1. INFORM ;let user know what is gong on
  1.  W:$D(IOF) @IOF
  1.  W !!,$$CTR($$LOC,80)
  1.  W !,$$CTR($$USR,80),!!
  1.  F I=1:1 S X=$P($T(INTRO+I),";;",2) Q:X="END"  W !,X
  1.  K I,X
  1.  Q
  1. INTRO ;;
  1.  ;;This report will list all visits with a service category of
  1.  ;;T (telecommunications) or C (Chart Review) or clinic code 51 (TELEPHONE),
  1.  ;;or clinic code 52 (CHART REVIEW) that have an ancillary
  1.  ;;data item attached to them.  The ancillary data items are defined as:
  1.  ;;   MEDICATION
  1.  ;;   RADIOLOGY
  1.  ;;   MICROBIOLOGY
  1.  ;;   LAB
  1.  ;;   BLOOD BANK
  1.  ;; 
  1.  ;;
  1.  ;;END
  1. ADDMENU ;EP
  1.  S X=$$ADD^XPDMENU("APCDDVR","APCD C T VISITS W ANCILLARY","CTA")
  1.  I 'X W "Attempt to add update option failed." H 3
  1.  Q