Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: APCLPIF1

APCLPIF1.m

Go to the documentation of this file. 
  1. APCLPIF1 ; IHS/CMI/LAB - INFANT FEEDING REPORT #1 ;
  1.  ;;2.0;IHS PCC SUITE;;MAY 14, 2009
  1.  ;
  1.  ;
  1.  ;
  1. EP ;EP - called from option interactive
  1.  D EOJ
  1.  W:$D(IOF) @IOF
  1.  S APCLTEXT="INTROT" F APCLJ=1:1 S APCLX=$T(@APCLTEXT+APCLJ) Q:$P(APCLX,";;",2)="END"  D
  1.  .S APCLT=$P(APCLX,";;",2)
  1.  .I $Y>(IOSL-2) K DIR S DIR(0)="E",DIR("A")="Press enter to continue" D ^DIR K DIR W:$D(IOF) @IOF
  1.  .W !,APCLT
  1. ENDDATE ;
  1.  S APCLED=""
  1.  W !!
  1.  S DIR(0)="D^::EPX",DIR("A")="Enter the As of Date to calculate the patient's age" KILL DA D ^DIR KILL DIR
  1.  I $D(DIRUT) D EOJ Q
  1.  S APCLED=Y
  1.  S APCLBDOB=$$FMADD^XLFDT(APCLED,-1)
  1.  S APCLBDOB=($E(APCLBDOB,1,3)-2)_$E(APCLBDOB,4,7)
  1.  S APCLEDOB=($E(APCLBDOB,1,3)+1)_$E(APCLED,4,7)
  1. CMMNTS ;
  1.  K APCLCOMM S APCLCOMT=""
  1.  S DIR(0)="S^O:One particular Community;A:All Communities;S:Selected Set of Communities (Taxonomy)",DIR("A")="List patients who live in",DIR("B")="A" K DA D ^DIR K DIR
  1.  I $D(DIRUT) G ENDDATE
  1.  S APCLCOMT=Y
  1.  I APCLCOMT="A" G ZIS
  1.  I APCLCOMT="O" D  G:'$D(APCLCOMM) CMMNTS  G ZIS
  1.  .S DIC="^AUTTCOM(",DIC(0)="AEMQ",DIC("A")="Which COMMUNITY: " D ^DIC K DIC
  1.  .Q:Y=-1
  1.  .S APCLCOMM($P(^AUTTCOM(+Y,0),U))=""
  1.  S X="COMMUNITY",DIC="^AMQQ(5,",DIC(0)="FM",DIC("S")="I $P(^(0),U,14)" D ^DIC K DIC,DA I Y=-1 W "OOPS - QMAN NOT CURRENT - QUITTING" S APCLERR=1 Q
  1.  D PEP^AMQQGTX0(+Y,"APCLCOMM(")
  1.  I '$D(APCLCOMM) G CMMNTS
  1.  I $D(APCLCOMM("*")) K APCLCOMM G CMMNTS
  1. ZIS ;
  1. DEMO ;
  1.  D DEMOCHK^APCLUTL(.APCLDEMO)
  1.  I APCLDEMO=-1 G CMMNTS
  1.  W !!,"Patients with the following birthdates with be reviewed in this"
  1.  W !,"report:  ",$$FMTE^XLFDT(APCLBDOB)," - ",$$FMTE^XLFDT(APCLEDOB),!
  1.  W !,"Patients from the following communities will be included:"
  1.  I APCLCOMT="A" W !?5,"All communities"
  1.  I APCLCOMT'="A" W !?3 S X=0 F  S X=$O(APCLCOMM(X)) Q:X=""  W " ",X
  1.  W !! S XBRP="PRINT^APCLPIF1",XBRC="PROC^APCLPIF1",XBRX="EOJ^APCLPIF1",XBNS="APCL"
  1.  D ^XBDBQUE
  1.  Q
  1. EOJ ;
  1.  D ^XBFMK
  1.  K DIC,DIR
  1.  D EN^XBVK("APCL")
  1.  Q
  1.  ;
  1. PROC ;
  1.  S APCLJ=$J,APCLH=$H
  1.  S ^XTMP("APCLPIF1",0)=$$FMADD^XLFDT(DT,14)_"^"_DT_"^"_"INFANT FEEDING REPORT"
  1.  S APCLD0=""
  1.  S APCLD6=""
  1.  S APCLDOB=$$FMADD^XLFDT(APCLBDOB,-1),DFN=0
  1.  F  S APCLDOB=$O(^DPT("ADOB",APCLDOB)) Q:APCLDOB=""!(APCLDOB>APCLEDOB)  D
  1.  .S DFN=0 F  S DFN=$O(^DPT("ADOB",APCLDOB,DFN)) Q:DFN'=+DFN  D
  1.  ..;birth stats
  1.  ..Q:$$DEMO^APCLUTL(DFN,$G(APCLDEMO))
  1.  ..S APCLPCV0=""
  1.  ..S APCLBVD=APCLDOB
  1.  ..;S APCLBS=$P($G(^AUPNBMSR(DFN,0)),U,15)
  1.  ..S APCLEVD=$$FMADD^XLFDT(APCLDOB,179)
  1.  ..S APCL06=0
  1.  ..D PCV
  1.  ..I APCLPCV0 S $P(APCLD0,U,1)=$P(APCLD0,U,1)+1 D
  1.  ...;I $D(APCLINF)!(APCLBS]"") S $P(APCLD0,U,2)=$P(APCLD0,U,2)+1
  1.  ...I $D(APCLINF) S $P(APCLD0,U,2)=$P(APCLD0,U,2)+1
  1.  ...S (G,Y)=0 F  S Y=$O(APCLINF(Y)) Q:Y'=+Y!(G)  I APCLINF(Y)'=5 S G=1
  1.  ...;I 'G,APCLBS]"",APCLBS>1 S G=1
  1.  ...I G S $P(APCLD0,U,3)=$P(APCLD0,U,3)+1
  1.  ..;SIX MONTHS
  1.  ..S APCLPCV6=0
  1.  ..S APCLBVD=$$FMADD^XLFDT(APCLDOB,180)
  1.  ..S APCLEVD=$$FMADD^XLFDT(APCLDOB,365)
  1.  ..S APCL06=6
  1.  ..D PCV
  1.  ..I APCLPCV6 S $P(APCLD6,U,1)=$P(APCLD6,U,1)+1 D
  1.  ...;I $D(APCLINF)!(APCLBS]"") S $P(APCLD6,U,2)=$P(APCLD6,U,2)+1
  1.  ...I $D(APCLINF) S $P(APCLD6,U,2)=$P(APCLD6,U,2)+1
  1.  ...S (G,Y)=0 F  S Y=$O(APCLINF(Y)) Q:Y'=+Y!(G)  I APCLINF(Y)'=5 S G=1
  1.  ...;I 'G,APCLBS]"",APCLBS>180 S G=1
  1.  ...I G S $P(APCLD6,U,3)=$P(APCLD6,U,3)+1
  1.  ..Q
  1.  .Q
  1.  Q
  1. DONE ;
  1.  I $E(IOST)="C",IO=IO(0) S DIR(0)="EO",DIR("A")="End of report.  PRESS ENTER" D ^DIR K DIR S:$D(DUOUT) DIRUT=1
  1.  W:$D(IOF) @IOF
  1.  K APCLTS,APCLS,APCLM,APCLET
  1.  K ^XTMP("APCLPIF1",APCLJ,APCLH),APCLJ,APCLH
  1.  Q
  1.  ;
  1. PCV ;
  1.  ;get all visits in date range
  1.  ;table all infant feeding in time range
  1.  K ^TMP($J,"A"),APCLINF
  1.  S A="^TMP($J,""A"",",B=DFN_"^ALL VISITS;DURING "_$$FMTE^XLFDT(APCLBVD)_"-"_$$FMTE^XLFDT(APCLEVD),E=$$START1^APCLDF(B,A)
  1.  S (X,G,F,S)=0 F  S X=$O(^TMP($J,"A",X)) Q:X'=+X  S V=$P(^TMP($J,"A",X),U,5) D
  1.  .Q:'$D(^AUPNVSIT(V,0))
  1.  .Q:'$P(^AUPNVSIT(V,0),U,9)
  1.  .Q:$P(^AUPNVSIT(V,0),U,11)
  1.  .Q:'$D(^AUPNVPRV("AD",V))
  1.  .Q:"SAHO"'[$P(^AUPNVSIT(V,0),U,7)
  1.  .Q:"V"[$P(^AUPNVSIT(V,0),U,3)
  1.  .S B=$$CLINIC^APCLV(V,"C")
  1.  .Q:B=""
  1.  .I $D(^BGPCTRL(3,11,"B",B)) S G=1  ;must be a primary clinic S G=V
  1.  .;table infant feeding choice
  1.  .Q:'$D(^AUPNVIF("AD",V))
  1.  .S Y=0 F  S Y=$O(^AUPNVIF("AD",V,Y)) Q:Y'=+Y  S APCLINF($P($P(^AUPNVSIT(V,0),U),"."))=$$VALI^XBDIQ1(9000010.44,Y,.01)
  1.  .Q
  1.  I G D
  1.  .I APCL06=0 S APCLPCV0=1
  1.  .I APCL06=6 S APCLPCV6=1
  1.  .Q
  1.  Q
  1.  ;
  1. PRINT ;EP - called from xbdbque
  1.  S APCLQ=0
  1.  D COVER
  1.  Q:APCLQ
  1.  D HEADER
  1.  W !,"BREASTFEEDING AT BIRTH",!
  1.  W !?2,"w/visit",?30,$$C($P(APCLD0,U,1),0,6)
  1.  W !?2,"w/data recorded",?30,$$C($P(APCLD0,U,2),0,6)
  1.  I $P(APCLD0,U,1) S X=($P(APCLD0,U,2)/$P(APCLD0,U,1))*100 W ?39,$J(X,6,1)
  1.  I '$P(APCLD0,U,1) W ?39,$J("0.0",6,1)
  1.  W !?2,"Breastfeeding",?30,$$C($P(APCLD0,U,3),0,6)
  1.  I $P(APCLD0,U,2) S X=($P(APCLD0,U,3)/$P(APCLD0,U,2))*100 W ?39,$J(X,6,1)
  1.  I '$P(APCLD0,U,2) W ?39,$J("0.0",6,1)
  1.  W ?55,"75%",?65,"71%",?75,"69%"
  1.  W !!,"BREASTFEEDING AT 6 MONTHS",!
  1.  W !?2,"w/visit",?30,$$C($P(APCLD6,U,1),0,6)
  1.  W !?2,"w/data recorded",?30,$$C($P(APCLD6,U,2),0,6)
  1.  I $P(APCLD6,U,1) S X=($P(APCLD6,U,2)/$P(APCLD6,U,1))*100 W ?39,$J(X,6,1)
  1.  I '$P(APCLD6,U,1) W ?39,$J("0.0",6,1)
  1.  W !?2,"Breastfeeding",?30,$$C($P(APCLD6,U,3),0,6)
  1.  I $P(APCLD6,U,2) S X=($P(APCLD6,U,3)/$P(APCLD6,U,2))*100 W ?39,$J(X,6,1)
  1.  I '$P(APCLD6,U,2) W ?39,$J("0.0",6,1)
  1.  W ?55,"50%",?65,"36%",?75,"32%"
  1.  W !
  1.  D DONE
  1.  Q
  1.  G:'APCLPG HEADER1
  1.  K DIR I $E(IOST)="C",IO=IO(0) W ! S DIR(0)="EO" D ^DIR K DIR I Y=0!(Y="^")!($D(DTOUT)) S APCLQ=1 Q
  1. HEADER1 ;
  1.  W:$D(IOF) @IOF S APCLPG=APCLPG+1
  1.  W !?3,$P(^VA(200,DUZ,0),U,2),?35,$$FMTE^XLFDT(DT),?70,"Page ",APCLPG,!
  1.  W $$CTR($P(^DIC(4,DUZ(2),0),U),80),!
  1.  W !,$$CTR("INFANT BREASTFEEDING STATISTICS, as of "_$$FMTE^XLFDT(APCLEDOB),80),!
  1.  S X="Patients born "_$$FMTE^XLFDT(APCLBDOB)_" - "_$$FMTE^XLFDT(APCLEDOB) W $$CTR(X,80),!
  1.  W $TR($J("",80)," ","-"),!
  1.  W !?30,$E($P(^DIC(4,DUZ(2),0),U),1,15),?53,"HP 2010",?63,"NATIONAL",?73,"2003",!?63,"USA RATE",?73,"AI/AN",!
  1.  W ?32,"#",?42,"%",?55,"%",?65,"%",?75,"%",!
  1.  W $TR($J("",80)," ","-"),!
  1.  Q
  1. C(X,X2,X3) ;
  1.  D COMMA^%DTC
  1.  Q X
  1. CTR(X,Y) ;EP - Center X in a field Y wide.
  1.  Q $J("",$S($D(Y):Y,1:IOM)-$L(X)\2)_X
  1.  ;----------
  1. EOP ;EP - End of page.
  1.  K DIR I $E(IOST)="C",IO=IO(0) W ! S DIR(0)="EO" D ^DIR K DIR I Y=0!(Y="^")!($D(DTOUT)) S APCLQ=1 Q
  1.  W:$D(IOF) @IOF
  1.  W !,$$CTR("COVER PAGE",80)
  1.  W !!,$$CTR($P(^DIC(4,DUZ(2),0),U),80)
  1.  W !,$$CTR("INFANT BREASTFEEDING STATISTICS, as of "_$$FMTE^XLFDT(APCLEDOB),80),!
  1.  S X="Report Run By: "_$P(^VA(200,DUZ,0),U) W !,$$CTR(X,80)
  1.  S X="Date Report Run: "_$$FMTE^XLFDT(DT) W !,$$CTR(X,80),!
  1.  Q
  1.  ;----------
  1. USR() ;EP - Return name of current user from ^VA(200.
  1.  Q $S($G(DUZ):$S($D(^VA(200,DUZ,0)):$P(^(0),U),1:"UNKNOWN"),1:"DUZ UNDEFINED OR 0")
  1.  ;----------
  1. LOC() ;EP - Return location name from file 4 based on DUZ(2).
  1.  Q $S($G(DUZ(2)):$S($D(^DIC(4,DUZ(2),0)):$P(^(0),U),1:"UNKNOWN"),1:"DUZ(2) UNDEFINED OR 0")
  1.  ;----------
  1. INTROT ;
  1.  ;;This option will produce a report of how many infants were documented as
  1.  ;;being breast fed at birth and at age 6 months.
  1.  ;;
  1.  ;;You will select the "as of" date (report end date) and the communities you
  1.  ;;want to report on.  The report first identifies all patients who are ages
  1.  ;;12-23 months on the "as of" date you defined.
  1.  ;;
  1.  ;;The report calculates the infants to report on from this initial population.
  1.  ;;
  1.  ;;  BIRTH breastfeeding statistics:
  1.  ;;
  1.  ;;   Denominator:  Number of Infants with a visit - patients who had at least
  1.  ;;   one visit to a primary care clinic between birth and 6 months
  1.  ;;   (ages 1-179 days old).
  1.  ;;  
  1.  ;;   Numerators:
  1.  ;;   1.  infants with feeding data - any patient with a visit with any infant
  1.  ;;   feeding choice documented between birth and 6 months (0-179 days old)
  1.  ;;   2.  infants breastfeeding - of the patients with feeding data (numerator
  1.  ;;   #1), those with ANY infant feeding choice that includes breastfeeding
  1.  ;;   (e.g., NOT formula only).  The report looks chronologically at all visits
  1.  ;;   in the timeframe with feeding documentation and counts the patient as
  1.  ;;   meeting the numerator as soon as the first feeding choice that includes
  1.  ;;   breastfeeding is found.
  1.  ;;  
  1.  ;;   6 MONTH statistics:
  1.  ;;     same as BIRTH except the visits reviewed are those that
  1.  ;;     occured between 180-365 days old
  1.  ;;END
  1. COVER ;;
  1.  S APCLPG=0
  1.  W !,$$CTR("COVER PAGE",80)
  1.  W !!,$$CTR($P(^DIC(4,DUZ(2),0),U),80)
  1.  W !,$$CTR("INFANT BREASTFEEDING STATISTICS, as of "_$$FMTE^XLFDT(APCLEDOB),80)
  1.  S X="Report Run By: "_$P(^VA(200,DUZ,0),U) W !,$$CTR(X,80)
  1.  S X="Date Report Run: "_$$FMTE^XLFDT(DT) W !,$$CTR(X,80)
  1.  W !!,"Population Reviewed:  All patients with birthdates ",$$FMTE^XLFDT(APCLBDOB)," to ",$$FMTE^XLFDT(APCLEDOB)
  1.  W !,"Community of Residence: "
  1.  I APCLCOMT="O" W " ",$O(APCLCOMM(""))
  1.  I APCLCOMT="A" W "  ","All Communities"
  1.  I APCLCOMT="S" S C=0,X="" F  S X=$O(APCLCOMM(X)) Q:X=""  W:C "; " W X S C=C+1
  1.  ;now text
  1.  S APCLTEXT="COVERT" F APCLJ=1:1 S APCLX=$T(@APCLTEXT+APCLJ) Q:$P(APCLX,";;",2)="END"!(APCLQ)  D
  1.  .S APCLT=$P(APCLX,";;",2)
  1.  .I $Y>(IOSL-3) D EOP Q:APCLQ
  1.  .W !,APCLT
  1.  .Q
  1.  Q
  1. COVERT ;;
  1.  ;;
  1.  ;;BIRTH breastfeeding statistics:
  1.  ;;
  1.  ;;  Denominator:  Number of Infants with a visit - patients who had at least
  1.  ;;  one visit to a primary care clinic between birth and 6 months
  1.  ;;  (ages 1-179 days old).
  1.  ;;  
  1.  ;;  Numerators:
  1.  ;;  1.  with feeding data - any patient with a visit with any infant
  1.  ;;  feeding choice documented between birth and 6 months (0-179 days old)
  1.  ;;  2.  breastfeeding - of the patients with feeding data (numerator
  1.  ;;  #1), those with ANY infant feeding choice that includes breastfeeding
  1.  ;;  (e.g., NOT formula only).  The report looks chronologically at all visits
  1.  ;;  in the timeframe with feeding documentation and counts the patient as
  1.  ;;  meeting the numerator as soon as the first feeding choice that includes
  1.  ;;  breastfeeding is found.
  1.  ;;  
  1.  ;;  6 MONTH statistics:
  1.  ;;    same as BIRTH except the visits reviewed are those that
  1.  ;;    occured between 180-365 days old
  1.  ;;
  1.  ;;The report documents the site performance against three national performance
  1.  ;;measures for breastfeeding; Healthy People 2010 goal; National USA rate for
  1.  ;;[YY] from (what report); and 2003 data for American Indian and Alaska
  1.  ;;Natives from (what report).
  1.  ;;
  1.  ;;END