Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: AZAX3PBF

AZAX3PBF.m

Go to the documentation of this file. 
  1. AZAX3PBF ;IHS/PHXAO/AEF - FIX COVERED DAYS FIELD IN 3P BILL BATCHES
  1.  ;;1.0;ANNE'S SPECIAL ROUTINES;;JULY 14, 2004
  1.  ;;
  1.  ;;DELETE THIS ROUTINE... THIS CODE HAS BEEN MOVED TO ^AZAXFCD
  1.  ;
  1. EN ;EP -- MAIN ENTRY POINT
  1.  ;
  1.  N EXPDT,OUT,QUIT
  1.  ;
  1.  D ^XBKVAR
  1.  D HOME^%ZIS
  1.  ;
  1.  F  D  Q:QUIT
  1.  . D EXP(.EXPDT,.OUT,.QUIT)
  1.  . Q:QUIT
  1.  . Q:OUT
  1.  . ;
  1.  . D PROC(EXPDT)
  1.  ;
  1.  Q
  1. PROC(EXPDT) ;
  1.  ;----- PROCESS ENTRIES
  1.  ;
  1.  N BILL,CD,CNT,D1,NOW
  1.  ;
  1.  Q:'EXPDT
  1.  ;
  1.  S CNT=0
  1.  S NOW=$$NOW
  1.  ;
  1.  W !!,"PROCESSING BATCH #",EXPDT,"  ",$$EXTDT($P($G(^ABMDTXST(DUZ(2),EXPDT,0)),U)),"..."
  1.  ;
  1.  S D1=0
  1.  F  S D1=$O(^ABMDTXST(DUZ(2),EXPDT,2,D1)) Q:'D1  D
  1.  . S CNT=$G(CNT)+1
  1.  . I '(CNT#10) W "."
  1.  . S BILL=$P($G(^ABMDTXST(DUZ(2),EXPDT,2,D1,0)),U)
  1.  . Q:'BILL
  1.  . S CD=$P($G(^ABMDBILL(DUZ(2),BILL,7)),U,3)
  1.  . D ARCH(NOW,EXPDT,BILL,CD)
  1.  . D ONE(BILL)
  1.  ;
  1.  W !,CNT," BILLS PROCESSED"
  1.  Q
  1. ONE(DA) ;
  1.  ;----- EDIT ONE BILL
  1.  ;
  1.  N DIE,DR,X,Y
  1.  ;
  1.  S DIE="^ABMDBILL("_DUZ(2)_","
  1.  S DR=".73///^S X=""@"""
  1.  D ^DIE
  1.  Q
  1. EXP(EXPDT,OUT,QUIT) ;
  1.  ;----- SELECT EXPORT DATE FROM 3P TX STATUS FILE
  1.  ;
  1.  N DA,DIC,DIQ,DIR,DIROUT,DIRUT,DR,DTOUT,DUOUT,X,Y
  1.  ;
  1.  S OUT=0
  1.  S QUIT=0
  1.  ;
  1.  W !
  1.  S DIC="^ABMDTXST("_DUZ(2)_","
  1.  S DIC(0)="AEQM"
  1.  D ^DIC
  1.  I $D(DTOUT)!($D(DUOUT))!(+Y'>0) S QUIT=1
  1.  Q:QUIT
  1.  ;
  1.  W !
  1.  S DA=+Y
  1.  S DR="0:1"
  1.  S DIQ(0)="R"
  1.  D EN^DIQ
  1.  ;
  1.  W !
  1.  S DIR("A",1)="WARNING!  This option will delete the COVERED DAYS from all bills"
  1.  S DIR("A",2)="contained in this batch."
  1.  S DIR("A",3)=""
  1.  S DIR("A")="Do you REALLY want to delete the COVERED DAYS from this batch"
  1.  S DIR("B")="NO"
  1.  S DIR(0)="Y"
  1.  D ^DIR
  1.  I $D(DTOUT)!($D(DUOUT))!($D(DIRUT))!($D(DIROUT))!(+Y'>0) S OUT=1
  1.  Q:OUT
  1.  ;
  1.  S EXPDT=DA
  1.  Q
  1. ARCH(NOW,EXPDT,BILL,CD) ;
  1.  ;----- PUT AN ENTRY INTO THE ^AZAX3PBF GLOBAL FOR EACH 'COVERED DAYS'
  1.  ;      FIELD THAT IS CHANGED BY THIS ROUTINE.  USED AS AN AUDIT TRAIL.
  1.  ;      THIS GLOBAL CAN BE DELETED AFTER A WHILE.
  1.  ;      
  1.  ;      GLOBAL STRUCTURE IS:
  1.  ;      ^AZAX3PBF(DUZ(2),NOW,EXPORT_IEN,BILL_IEN)=COVERED_DAYS_OLD_VALUE^DUZ
  1.  ;      
  1.  ;      INPUT:
  1.  ;      NOW    =  DATE/TIME THE CHANGE WAS MADE
  1.  ;      EXPDT  =  EXPORT DATE IEN FROM 3P TX STATUS FILE
  1.  ;      BILL   =  BILL IEN FROM 3P TX STATUS FILE
  1.  ;      CD     =  COVERED DAYS FROM 3P BILL FILE
  1.  ;      
  1.  I '$D(^AZAX3PBF(0)) D
  1.  . S ^AZAX3PBF(0)="RECORD OF 3P BILL FILE ENTRIES WHOSE COVERED DAYS FIELD HAS BEEN CHANGED BY AZAX3PBF ROUTINE. "
  1.  . S ^AZAX3PBF(0)=^AZAX3PBF(0)_" THIS GLOBAL CAN BE DELETED AFTER A WHILE."
  1.  ;
  1.  S ^AZAX3PBF(DUZ(2),NOW,EXPDT,BILL)=CD_U_DUZ
  1.  Q
  1. EXTDT(Y) ;
  1.  ;----- RETURNS EXTERNAL DATE
  1.  ;
  1.  X ^DD("DD")
  1.  Q Y
  1. NOW() ;
  1.  ;----- RETURNS CURRENT DATE/TIME IN INTERNAL FM FORMAT CYYMMDD.HHMMSS
  1.  ;
  1.  N %,%I,X
  1.  D NOW^%DTC
  1.  Q %
  1.  
  1.