Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BGPMUAD4

BGPMUAD4.m

Go to the documentation of this file. 
  1. BGPMUAD4 ; IHS/MSC/MGH - Print MI measure NQF0061 ;07-Jul-2011 14:06;DU
  1.  ;;14.1;IHS CLINICAL REPORTING;**1**;MAY 29, 2014;Build 2
  1.  ;Delimeted output
  1.  ;Diabetes BP control
  1. LASTBP(CNT) ;EP
  1.  D P1
  1.  K ^TMP("BGPMU0061",$J)
  1.  Q
  1. P1 ;Write individual measure
  1.  N X,Y,Z,LIST1,LIST2,LIST3
  1.  N DEN1,NUM1,DEN2,NUM2,PC1,PC2,EXC1,EXC2,STRING1,STRING2,STRING3
  1.  N PRD1,PRD2,PRD3,PRD4,PRD5,PRD6,PRD7,PRD8,PRN1,PRN2,PRN3,PRN4,PRN5,PRN6,PRN7,PRN8
  1.  S STRING1=$$NUM61("C")
  1.  S STRING2=$$NUM61("P")
  1.  S STRING3=$$NUM61("B")
  1.  D SUMMARY1^BGPMUAP4(STRING1,STRING2,STRING3)
  1.  ;First population 
  1.  S PRD1=$P(STRING1,U,5)-$P(STRING2,U,5) S PRD1=$FN(PRD1,",+",1)
  1.  S PRD2=$P(STRING1,U,6)-$P(STRING2,U,6) S PRD2=$FN(PRD2,",+",1)
  1.  S PRD3=$P(STRING1,U,7)-$P(STRING2,U,7) S PRD3=$FN(PRD3,",+",1)
  1.  S PRD7=$P(STRING1,U,9)-$P(STRING2,U,9) S PRD7=$FN(PRD7,",+",1)
  1.  S PRN1=$P(STRING1,U,5)-$P(STRING3,U,5) S PRN1=$FN(PRN1,",+",1)
  1.  S PRN2=$P(STRING1,U,6)-$P(STRING3,U,6) S PRN2=$FN(PRN2,",+",1)
  1.  S PRN3=$P(STRING1,U,7)-$P(STRING3,U,7) S PRN3=$FN(PRN3,",+",1)
  1.  S PRN7=$P(STRING1,U,9)-$P(STRING3,U,9) S PRN7=$FN(PRN7,",+",1)
  1.  S X=U_"REPORT PERIOD"_U_"%"_U_"PREV YR PERIOD"_U_"%"_U_"CHG FROM PREV YR"_U_"BASE YEAR"_U_"%"_U_"CHG FROM BASE"
  1.  D S^BGPMUDEL(X,2,1)
  1.  S X="Pts 18-75 w/diabetes"_U_$P(STRING1,U,1)_U_U_$P(STRING2,U,1)_U_U_U_$P(STRING3,U,1) D S^BGPMUDEL(X,1,1)
  1.  S X="# Excluded (Exc)"_U_$P(STRING1,U,4)_U_U_$P(STRING2,U,4)_U_U_U_$P(STRING3,U,4)
  1.  D S^BGPMUDEL(X,1,1)
  1.  S X="Pts 18-75 w/diabetes - Exc"_U_$P(STRING1,U,3)_U_U_$P(STRING2,U,3)_U_U_U_$P(STRING3,U,3)
  1.  D S^BGPMUDEL(X,1,1)
  1.  S X="# w/lowest BP < 140/90"_U_$P(STRING1,U,2)_U_$J($P(STRING1,U,5),5,1)_U_$P(STRING2,U,2)_U_$J($P(STRING2,U,5),5,1)_U_$FN(PRD1,",+",1)_U_$P(STRING3,U,2)_U_$J($P(STRING3,U,5),5,1)_U_$FN(PRN1,",+",1)
  1.  D S^BGPMUDEL(X,2,1)
  1.  S X="# w/o BP or lowest BP >=140/90"_U_$P(STRING1,U,8)_U_$J($P(STRING1,U,9),5,1)_U_$P(STRING2,U,8)_U_$J($P(STRING2,U,9),5,1)_U_$FN(PRD7,",+",1)_U_$P(STRING3,U,8)_U_$J($P(STRING3,U,9),5,1)_U_$FN(PRN7,",+",1)
  1.  D S^BGPMUDEL(X,1,1)
  1.  S X="" D S^BGPMUDEL(X,1,1)
  1.  I $D(BGPLIST(BGPIC)) D P2
  1.  Q
  1. NUM61(TF) ;Get the numbers for this measure
  1.  N ARRAY,DEN,NUM,EXC,NOT,PC1,PC11,PC2,PC14,PC21,PC13,NNUM
  1.  S DEN=+$G(^TMP("BGPMU0061",$J,TF,"DEN"))
  1.  S NUM=+$G(^TMP("BGPMU0061",$J,TF,"NUM"))
  1.  S NOT=+$G(^TMP("BGPMU0061",$J,TF,"NOT"))
  1.  S EXC=+$G(^TMP("BGPMU0061",$J,TF,"EXC"))
  1.  S NNUM=DEN-EXC
  1.  I DEN=0 S (PC1,PC11,PC13,PC14)=0
  1.  I DEN>0&(NNUM=0) D
  1.  .S (PC1,PC11,PC14)=0
  1.  .S PC13=$$ROUND^BGPMUA01((EXC/DEN),3)*100
  1.  I DEN>0&(NNUM>0) D
  1.  .S PC1=$$ROUND^BGPMUA01((NUM/NNUM),3)*100
  1.  .S PC11=$$ROUND^BGPMUA01((NNUM/DEN),3)*100
  1.  .S PC13=$$ROUND^BGPMUA01((EXC/DEN),3)*100
  1.  .S PC14=$$ROUND^BGPMUA01((NOT/NNUM),3)*100
  1.  S ARRAY=DEN_U_NUM_U_NNUM_U_EXC_U_PC1_U_PC11_U_PC13_U_NOT_U_PC14
  1.  Q ARRAY
  1. P2 ;Do the Details
  1.  N PT,NODE,NAME,VST,BMI,FOL,X,PTCT
  1.  S PTCT=0
  1.  S X="**** CONFIDENTIAL PATIENT INFORMATION COVERED BY PRIVACY ACT ****" D S^BGPMUDEL(X,2,1)
  1.  S X="Diabetic patients 18-75 years of age with at least 1 or 2 encounters with the EP" D S^BGPMUDEL(X,1,1)
  1.  S X="during the reporting period, whose blood pressure reading during their most" D S^BGPMUDEL(X,1,1)
  1.  S X="recent encounter was < 140/90 mmHg, if any." D S^BGPMUDEL(X,1,1)
  1.  S X="" D S^BGPMUDEL(X,1,1)
  1.  S X="Patients who did not meet the numerator criteria are listed first (NM:)," D S^BGPMUDEL(X,1,1)
  1.  S X="followed by patients who do meet the numerator criteria (M:).  Excluded patients" D S^BGPMUDEL(X,1,1)
  1.  S X="are listed last." D S^BGPMUDEL(X,1,1)
  1.  S X="" D S^BGPMUDEL(X,1,1)
  1.  S X="The following are the abbreviations used in the denominator and numerator" D S^BGPMUDEL(X,1,1)
  1.  S X="columns: " D S^BGPMUDEL(X,1,1)
  1.  S X="ICD-9 Code=Diabetes Diagnosis" D S^BGPMUDEL(X,1,1)
  1.  S X="MED=Medication Indicative of Diabetes" D S^BGPMUDEL(X,1,1)
  1.  S X="EN=Encounter" D S^BGPMUDEL(X,1,1)
  1.  S X="PATIENT NAME"_U_"HRN"_U_"COMMUNITY"_U_"SEX"_U_"AGE"_U_"DENOMINATOR"_U_"NUMERATOR" D S^BGPMUDEL(X,2,1)
  1.  I BGPLIST="D"!(BGPLIST="A") D
  1.  .K BGPARR
  1.  .D PTLSORT^BGPMUUTL(.BGPARR,"^TMP(""BGPMU0061"","_$J_",""PAT"",""C"",""NOT"")")
  1.  .S PT=0 F  S PT=$O(BGPARR(PT)) Q:PT=""  D
  1.  ..S PTCT=PTCT+1
  1.  ..S NODE=$G(BGPARR(PT))
  1.  ..D DATA(NODE)
  1.  I BGPLIST="N"!(BGPLIST="A") D
  1.  .K BGPARR
  1.  .D PTLSORT^BGPMUUTL(.BGPARR,"^TMP(""BGPMU0061"","_$J_",""PAT"",""C"",""NUM"")")
  1.  .S PT=0 F  S PT=$O(BGPARR(PT)) Q:PT=""  D
  1.  ..S PTCT=PTCT+1
  1.  ..S NODE=$G(BGPARR(PT))
  1.  ..D DATA(NODE)
  1.  I BGPLIST="A" D
  1.  .K BGPARR
  1.  .D PTLSORT^BGPMUUTL(.BGPARR,"^TMP(""BGPMU0061"","_$J_",""PAT"",""C"",""EXC"")")
  1.  .S PT=0 F  S PT=$O(BGPARR(PT)) Q:PT=""  D
  1.  ..S PTCT=PTCT+1
  1.  ..S NODE=$G(BGPARR(PT))
  1.  ..D DATA(NODE)
  1.  S X="Total # of patients on list: "_PTCT D S^BGPMUDEL(X,2,1)
  1.  Q
  1. DATA(NODE) ;GET DATA
  1.  N NAME,HRN,DEN,NUM,AGE,DFN,SEX,COMM,NUM1,NUM2
  1.  S DFN=$P(NODE,U,1)
  1.  S NAME=$E($$GET1^DIQ(2,$P(NODE,U,1),.01),1,30)
  1.  S HRN=$$HRN^AUPNPAT(DFN,DUZ(2))
  1.  S AGE=$$AGE^AUPNPAT(DFN,BGPED)
  1.  S COMM=$$GET1^DIQ(9000001,DFN,1118)
  1.  S SEX=$P(^DPT(DFN,0),U,2)
  1.  S DEN=$P(NODE,U,2)
  1.  S NUM=$P(NODE,U,3)
  1.  S NUM1=$P(NUM,";",1),NUM2=($P(NUM,";",2)),NUM3=$P(NUM,";",3),NUM4=$P(NUM,";",4)
  1.  S X=NAME_U_HRN_U_COMM_U_SEX_U_AGE_U_DEN_U_NUM1_" "_NUM2
  1.  I NUM3'="" S X=X_";"_NUM3_"  "_NUM4
  1.  D S^BGPMUDEL(X,1,1)
  1.  Q
  1. XML0061 ;XML output for diabetes BP control
  1.  ; BGPXML(i)=Population Number^Numerator Number^Denominator Count^exclusion number
  1.  N STRING,TOTN,TOTD,TOTE
  1.  S STRING=$$NUM61("C")
  1.  S TOTD=$P(STRING,U,1)
  1.  S TOTN=$P(STRING,U,2)
  1.  S TOTE=$P(STRING,U,4)
  1.  S BGPXML(1)="3"_U_U_+TOTD_U_TOTN_U_TOTE
  1.  K ^TMP("BGPMU0061",$J)
  1.  Q