Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BHSMBN

BHSMBN.m

Go to the documentation of this file. 
  1. BHSMBN ;IHS/CIA/MGH - Health Summary for V MED file ;01-May-2014 11:09;DU
  1.  ;;1.0;HEALTH SUMMARY COMPONENTS;**1,2,6,9**;March 17, 2006;Build 16
  1.  ;===================================================================
  1.  ;Taken from APCHS77
  1.  ; IHS/TUCSON/LAB - PART 7 OF BHS -- SUMMARY PRODUCTION COMPONENTS ;  [ 04/14/04  3:14 PM ]
  1.  ;;2.0;IHS RPMS/PCC HEALTH SUMMARY;**11**;SEP 23, 1997
  1.  ;
  1.  ;This routine makes health summaries for those medications sorted by name
  1.  ;Patch 1 changes prescribed at to dispensed at as in IHS patch 15
  1.  ;Patch 6 for non-VA meds and medication review
  1.  ;======================================================================
  1. MEDSCURR ; ************** CURRENT MEDICATIONS * 9000010.14 ********
  1.  S BHSMTY="CURR" G CONT
  1. MEDSCHRN ; ************* CHRONIC MEDCICATIONS ************
  1.  S BHSMTY="CHRONIC" G CONT
  1. MEDSNDUP ; ************* ALL, NON DUPLICATED *************
  1.  S BHSMTY="NODUP" G CONT
  1. CONT ; <SETUP>
  1.  N BHSPAT,BHSQ,APCHZ
  1.  S BHSPAT=DFN
  1.  Q:'$D(^AUPNVMED("AC",BHSPAT))
  1.  D CKP^GMTSUP Q:$D(GMTSQIT)
  1.  ; <BUILD>
  1.  K ^TMP($J,"BHSMTB"),^TMP($J,"BHSMTP")
  1.  S BHSIVD=0 F BHSQ=0:0 S BHSIVD=$O(^AUPNVMED("AA",BHSPAT,BHSIVD)) Q:BHSIVD=""!(BHSIVD>GMTSDLM)  S BHSMX=0 F BHSQ=0:0 S BHSMX=$O(^AUPNVMED("AA",BHSPAT,BHSIVD,BHSMX)) Q:BHSMX=""  D MEDBLD
  1.  ; <DISPLAY>
  1.  D NONVA^BHSMED  ;Patch 6 get all NON-VA meds that didn't pass to PCC
  1.  S BHSNAM="" F BHSQ=0:0 S BHSNAM=$O(^TMP($J,"BHSMTP",BHSNAM)) Q:BHSNAM=""!($D(GMTSQIT))  S BHSMX=0 F  S BHSMX=$O(^TMP($J,"BHSMTP",BHSNAM,BHSMX)) Q:BHSMX'=+BHSMX!($D(GMTSQIT))  D MEDDSP
  1.  D HOLDDSP^BHSMED
  1.  ;Patch 2 med refusals
  1.  S BHST="MEDICATION",BHSFN=50 D DISPREF^BHSRAD
  1.  ;Patch 6
  1.  D MEDRU^BHSMED  ;display last date reviewed/updated/nam
  1.  K BHST,BHSFN
  1.  ; <CLEANUP>
  1. MEDX K BHSIVD,BHSMX,BHSMFX,BHSQTY,BHSIG,BHSSGY,BHSEXP,BHSMTS,BHSMED,BHSDTM,BHSDAT,BHSDYS,BHSN,BHSDC,BHSVDF,BHSP,APCHORTS,BHSDCP,BHSNAM,BHSMED
  1.  K BHSNFL,BHSNSH,BHSNAB,BHSVSC,BHSITE,BHSRX,BHSDRG,BHSCRN,BHSREF,BHSRFL,BHSALL,BHSTXT,BHSMTY,BHSORD
  1.  K ^TMP($J,"BHSMTB"),^TMP($J,"BHSMTP")
  1.  K X1,X2,X,Y
  1.  Q
  1. MEDBLD ;BUILD ARRAY OF MEDICATIONS
  1.  ;BHSDC=DATE DISCONTINUED,DYS=DAYS PRESCRIBED,SIG=DIRECTIONS
  1.  ;VDF=VISIT FILE DATE
  1.  Q:'$D(^AUPNVMED(BHSMX,0))
  1.  S BHSN=^AUPNVMED(BHSMX,0)
  1.  Q:'$D(^PSDRUG($P(BHSN,U,1)))
  1.  S BHSDTM=-BHSIVD\1+9999999
  1.  S BHSDC=$P(BHSN,U,8),BHSDYS=$P(BHSN,U,7),BHSMFX=$S($P(BHSN,U,4)="":+BHSN,1:$P(BHSN,U,4))
  1.  S:BHSDYS="" BHSDYS=30
  1.  D @BHSMTY
  1.  Q
  1.  ;
  1. CURR ; current meds only
  1.  I $D(^TMP($J,"BHSMTB",BHSMFX)),^TMP($J,"BHSMTB",BHSMFX)="" Q
  1.  S X1=DT,X2=BHSDTM D ^%DTC Q:X>60&(X>(2*BHSDYS))
  1.  S BHSN=^AUPNVMED(BHSMX,0)
  1.  S BHSMED=$S($P(BHSN,U,4)="":$P(^PSDRUG(BHSMFX,0),U,1),1:$P(BHSN,U,4))
  1.  S ^TMP($J,"BHSMTB",BHSMFX)=BHSDC,^TMP($J,"BHSMTP",BHSMED,BHSMX)=BHSMX
  1.  Q
  1. CHRONIC ;chronic meds only
  1.  I $D(^TMP($J,"BHSMTB",BHSMFX)) Q
  1.  S X=$S($D(^PSRX("APCC",BHSMX)):$O(^(BHSMX,0)),1:0)
  1.  S Y=$S(+X:$D(^PS(55,BHSPAT,"P","CP",X)),1:0)
  1.  Q:'Y
  1.  I $G(BHSDCP),BHSDC]"" Q  ;IHS/CMI/LAB - new component patch 9
  1.  S BHSN=^AUPNVMED(BHSMX,0)
  1.  S BHSMED=$S($P(BHSN,U,4)="":$P(^PSDRUG(BHSMFX,0),U,1),1:$P(BHSN,U,4))
  1.  S ^TMP($J,"BHSMTB",BHSMFX)=BHSDC,^TMP($J,"BHSMTP",BHSMED,BHSMX)=BHSMX
  1.  Q
  1. MEDDSP ;DISPLAY MEDICATION
  1.  ;BHSRX=RX# in FILE 52,CHRN=CHRONIC FLAG,REF=#REFILLS
  1.  I $P(^TMP($J,"BHSMTP",BHSNAM,BHSMX),U,1)="" D NVADSP Q
  1.  S BHSN=^AUPNVMED(BHSMX,0)
  1.  S APCHZ=$P(^AUPNVMED(BHSMX,0),U,3)
  1.  S BHSIVD=$P($P(^AUPNVSIT(APCHZ,0),U),".")
  1.  S BHSRX=$S($D(^PSRX("APCC",BHSMX)):$O(^(BHSMX,0)),1:0)
  1.  S BHSCRN=$S(+BHSRX:$D(^PS(55,BHSPAT,"P","CP",BHSRX)),1:0)
  1.  S (X,BHSDTM)=BHSIVD D REGDT4^GMTSU S BHSDAT=X
  1.  S BHSDC=$P(BHSN,U,8),BHSDYS=$P(BHSN,U,7),BHSQTY=$P(BHSN,U,6),BHSIG=$P(BHSN,U,5),BHSVDF=$P(BHSN,U,3),BHSMFX=+BHSN
  1.  S:BHSDYS="" BHSDYS=30
  1.  S X1=DT,X2=BHSDTM D ^%DTC ;Q:X>60&(X>(2*BHSDYS))
  1.  S BHSEXP=""
  1.  I X>BHSDYS S X1=BHSDTM,X2=BHSDYS D C^%DTC D REGDT4^GMTSU S BHSEXP="-- Ran out "_X
  1.  S BHSMED=$S($P(BHSN,U,4)="":$P(^PSDRUG(BHSMFX,0),U,1),1:$P(BHSN,U,4))
  1.  I BHSDC S X=BHSDC D REGDT4^GMTSU S BHSEXP="-- D/C "_X
  1.  ;CHANGE IT AROUND A BIT LOOK FOR RETURNED TO STOCK IHS/OKCAO/POC 2/14/2000
  1.  S APCHORTS=$G(^AUPNVMED(BHSMX,11))
  1.  I APCHORTS["RETURNED TO STOCK",BHSDC S BHSEXP="--RTS "_Y
  1.  ;END OF LOCAL CHANGES IHS/OKCAO/POC 2/14/2000
  1.  D SIG S BHSIG=BHSSGY
  1.  D REF I BHSREF S BHSIG=BHSIG_" "_BHSREF_$S(BHSREF=1:" refill",1:" refills")_" left."
  1.  D SITE ;I BHSITE]"" S BHSIG=BHSIG_"  ["_BHSITE_"]"
  1.  D CKP^GMTSUP Q:$D(GMTSQIT)
  1.  W BHSDAT,?10,$S(BHSCRN:"(C)",1:""),?14,BHSMED," #",BHSQTY," (",BHSDYS," days) ",BHSEXP,!
  1.  ;Patch 8 Add Rxnorm code here
  1.  S RXNORM=$$GET1^DIQ(50,BHSMFX,9999999.27)
  1.  I RXNORM'="" W ?14,"RxNorm: ",RXNORM,!
  1.  I BHSITE]"" W ?14,"Dispensed at: ",BHSITE,!
  1.  D CKP^GMTSUP Q:$D(GMTSQIT)
  1.  S BHSICL=14,BHSNRQ="",BHSTXT=BHSIG D PRTTXT^BHSUTL K BHSICL,BHSNRQ,BHSP
  1.  S BHSORD=$$GET1^DIQ(52,BHSRX,39.3,"I")
  1.  I +BHSORD D RECON^BHSMED(BHSORD,"M")
  1.  E  D
  1.  .N NVA
  1.  .S NVA=+$P(APCHORTS,U,8)
  1.  .I NVA'="" D
  1.  ..S BHSORD=$P($G(^PS(55,DFN,"NVA",NVA,0)),U,8)
  1.  ..D RECON^BHSMED(BHSORD,"M")
  1.  Q
  1.  ;
  1. NVADSP ;
  1.  S BHSEXP=""
  1.  S (X,BHSDTM)=-BHSIVD\1+9999999 D REGDT4^GMTSU S BHSDAT=X
  1.  S BHSDC=$P(^TMP($J,"BHSMTP",BHSIVD),U,5)
  1.  S BHSMED=$P(^TMP($J,"BHSMTP",BHSIVD),U,3)
  1.  I BHSDC S Y=BHSDC D REGDT4^GMTSU S BHSEXP="-- D/C "_Y
  1.  S BHSIG=$P(^TMP($J,"BHSMTP",BHSIVD),U,4)
  1.  D CKP^GMTSUP Q:$D(GMTSQIT)
  1.  W BHSDAT,?14,BHSMED,"  ",BHSEXP,!
  1.  D CKP^GMTSUP Q:$D(GMTSQIT)
  1.  S BHSICL=14,BHSNRQ="",BHSTXT=BHSIG_"  (EHR OUTSIDE MEDICATION)" D PRTTXT^BHSUTL K BHSICL,BHSNRQ,BHSP
  1.  Q
  1. SIG ;CONSTRUCT THE FULL TEXT FROM THE ENCODED SIG
  1.  ;I $$VALI^XBDIQ1(9001015,BHSTYP,3.5)="S" S BHSSGY=BHSIG Q
  1.  S BHSSGY="" F BHSP=1:1:$L(BHSIG," ") S X=$P(BHSIG," ",BHSP) I X]"" D
  1.  . S Y=$O(^PS(51,"B",X,0)) I Y>0 S X=$P(^PS(51,Y,0),"^",2) I $D(^(9)) S Y=$P(BHSIG," ",BHSP-1),Y=$E(Y,$L(Y)) S:Y>1 X=$P(^(9),"^",1)
  1.  . S BHSSGY=BHSSGY_X_" "
  1.  Q
  1.  ;
  1. REF ;DETERMINE THE NUMBER OF REFILLS REMAINING
  1.  I 'BHSRX S BHSREF=0 Q
  1.  S BHSRFL=$P($G(^PSRX(BHSRX,0)),U,9) S BHSREF=0 F  S BHSREF=$O(^PSRX(BHSRX,1,BHSREF)) Q:'BHSREF  S BHSRFL=BHSRFL-1
  1.  S BHSREF=BHSRFL
  1.  Q
  1.  ;
  1. SITE ;DETERMINE IF OUTSIDE LOCATION INFO PRESENT
  1.  S BHSITE=""
  1.  I $D(^AUPNVSIT(BHSVDF,21))#2 S BHSITE=$P(^(21),U) Q
  1.  Q:$P(^AUPNVSIT(BHSVDF,0),U,6)=""
  1.  I $P(^AUPNVSIT(BHSVDF,0),U,6)'=DUZ(2) S BHSITE=$E($P(^DIC(4,$P(^AUPNVSIT(BHSVDF,0),U,6),0),U),1,30)
  1.  Q