Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BIUTL1

BIUTL1.m

Go to the documentation of this file. 
  1. BIUTL1 ;IHS/CMI/MWR - UTIL: PATIENT DEMOGRAPHICS; MAY 10, 2010
  1.  ;;8.5;IMMUNIZATION;**2**;MAY 15,2012
  1.  ;;* MICHAEL REMILLARD, DDS * CIMARRON MEDICAL INFORMATICS, FOR IHS *
  1.  ;;  RETRIEVE PATIENTS FOR DUE LISTS & LETTERS.
  1.  ;;  PATCH 2: Add YY option to DOBF.  DOBF
  1.  ;
  1.  ;----------
  1. NAME(DFN,ORDER) ;EP
  1.  ;---> Return text of Patient Name.
  1.  ;---> Parameters:
  1.  ;     1 - DFN   (req) Patient's IEN (DFN).
  1.  ;     2 - ORDER (opt) ""/0=Last,First   2=First Only
  1.  ;                        1=First Last   3=Last Only
  1.  ;
  1.  Q:'$G(DFN) "NO PATIENT"
  1.  Q:'$D(^DPT(DFN,0)) "Unknown"
  1.  N X S X=$P(^DPT(DFN,0),U)
  1.  Q:'$G(ORDER) X
  1.  S X=$$FL(X)
  1.  Q:ORDER=1 X
  1.  Q:ORDER=2 $P(X," ")
  1.  Q:ORDER=3 $P(X," ",2)
  1.  Q "UNKNOWN ORDER"
  1.  ;
  1.  ;
  1.  ;----------
  1. FL(X) ;EP
  1.  ;---> Switch First and Last Names.
  1.  Q $P($P(X,",",2)," ")_" "_$P(X,",")
  1.  ;
  1.  ;
  1.  ;----------
  1. DOB(DFN) ;EP
  1.  ;---> Return Patient's Date of Birth in Fileman format.
  1.  ;---> Parameters:
  1.  ;     1 - DFN   (req) Patient's IEN (DFN).
  1.  ;
  1.  Q:'$G(DFN) "NO PATIENT"
  1.  Q:'$P($G(^DPT(DFN,0)),U,3) "NOT ENTERED"
  1.  Q $P(^DPT(DFN,0),U,3)
  1.  ;
  1.  ;
  1.  ;********** PATCH 2, v8.5, MAY 15,2012, IHS/CMI/MWR
  1.  ;---> Add BIYY option/parameter to DOBF
  1.  ;----------
  1. DOBF(DFN,BIDT,BINOA,BISL,BIADT,BIYY) ;EP
  1.  ;---> Date of Birth formatted "09-Sep-1994 (35 Months)"
  1.  ;---> Parameters:
  1.  ;     1 - DFN   (req) Patient's IEN (DFN).
  1.  ;     2 - BIDT  (opt) Date on which Age should be calculated.
  1.  ;     3 - BINOA (opt) 1=No age (don't append age).
  1.  ;     4 - BISL  (opt) 1=Slash Date Format: MM/DD/YYYY
  1.  ;     5 - BIADT (opt) 1=Append "on BIDT" to age.
  1.  ;     6 - BIYY  (opt) 1=2-digit year.
  1.  ;
  1.  N X,Y
  1.  S X=$$DOB($G(DFN))
  1.  Q:'X X
  1.  S X=$S($G(BISL):$$SLDT2^BIUTL5(X,+$G(BIYY)),1:$$TXDT1^BIUTL5(X))
  1.  Q:$G(BINOA) X
  1.  S Y=$$AGEF(DFN,$G(BIDT))
  1.  S:Y["DECEASED" Y="DECEASED"
  1.  S X=X_" ("_Y
  1.  I $G(BIADT),$G(BIDT) S X=X_" on "_$$SLDT2^BIUTL5(BIDT,+$G(BIYY))
  1.  S X=X_")"
  1.  Q X
  1.  ;**********
  1.  ;
  1.  ;
  1.  ;----------
  1. AGE(DFN,BIZ,BIDT) ;EP
  1.  ;---> Return Patient's Age.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) IEN in PATIENT File.
  1.  ;     2 - BIZ  (opt) BIZ=1,2,3  1=years, 2=months, 3=days.
  1.  ;                               2 will be assumed if not passed.
  1.  ;     3 - BIDT (opt) Date on which Age should be calculated.
  1.  ;
  1.  N BIDOB,X,X1,X2  S:$G(BIZ)="" BIZ=2
  1.  Q:'$G(DFN) "NO PATIENT"
  1.  S BIDOB=$$DOB(DFN)
  1.  Q:'BIDOB "Unknown"
  1.  I '$G(BIDT)&($$DECEASED(DFN)) D  Q X
  1.  .S X="DECEASED: "_$$TXDT1^BIUTL5(+^DPT(DFN,.35))
  1.  S:'$G(DT) DT=$$DT^XLFDT
  1.  S:'$G(BIDT) BIDT=DT
  1.  Q:BIDT<BIDOB "NOT BORN"
  1.  ;
  1.  ;---> Age in Years.
  1.  N BIAGEY,BIAGEM,BID1,BID2,BIM1,BIM2,BIY1,BIY2
  1.  S BIM1=$E(BIDOB,4,7),BIM2=$E(BIDT,4,7)
  1.  S BIY1=$E(BIDOB,1,3),BIY2=$E(BIDT,1,3)
  1.  S BIAGEY=BIY2-BIY1 S:BIM2<BIM1 BIAGEY=BIAGEY-1
  1.  S:BIAGEY<1 BIAGEY="<1"
  1.  Q:BIZ=1 BIAGEY
  1.  ;
  1.  ;---> Age in Months.
  1.  S BID1=$E(BIM1,3,4),BIM1=$E(BIM1,1,2)
  1.  S BID2=$E(BIM2,3,4),BIM2=$E(BIM2,1,2)
  1.  S BIAGEM=12*BIAGEY
  1.  I BIM2=BIM1&(BID2<BID1) S BIAGEM=BIAGEM+12
  1.  I BIM2>BIM1 S BIAGEM=BIAGEM+BIM2-BIM1
  1.  I BIM2<BIM1 S BIAGEM=BIAGEM+BIM2+(12-BIM1)
  1.  S:BID2<BID1 BIAGEM=BIAGEM-1
  1.  Q:BIZ=2 BIAGEM
  1.  ;
  1.  ;---> Age in Days.
  1.  S X1=BIDT,X2=BIDOB
  1.  D ^%DTC
  1.  Q X
  1.  ;
  1.  ;
  1.  ;----------
  1. AGEF(DFN,BIDT) ;EP
  1.  ;---> Age formatted "35 Months" or "23 Years"
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;     2 - BIDT (opt) Date on which Age should be calculated.
  1.  ;
  1.  N Y
  1.  S Y=$$AGE(DFN,2,$G(BIDT))
  1.  Q:Y["DECEASED" Y
  1.  Q:Y["NOT BORN" Y
  1.  ;
  1.  ;---> If over 60 months, return years.
  1.  I Y>60 S Y=$$AGE(DFN,1,$G(BIDT)) Q Y_$S(Y=1:"year",1:" yrs")
  1.  ;
  1.  ;---> If under 1 month return days.
  1.  I Y<1 S Y=$$AGE(DFN,3,$G(BIDT)) Q Y_$S(Y=1:" day",1:" days")
  1.  ;
  1.  ;---> Return months
  1.  Q Y_$S(Y=1:" mth",1:" mths")
  1.  ;
  1.  ;
  1.  ;----------
  1. DECEASED(DFN,BIDT) ;EP
  1.  ;---> Return 1 if patient is deceased, 0 if not deceased.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;     2 - BIDT (opt) If BIDT=1 return Date of Death (Fileman format).
  1.  ;
  1.  Q:'$G(DFN) 0
  1.  N X S X=+$G(^DPT(DFN,.35))
  1.  Q:'X 0
  1.  Q:'$G(BIDT) 1
  1.  Q X
  1.  ;
  1.  ;
  1.  ;----------
  1. SEX(DFN,PRON) ;EP
  1.  ;---> Return "F" is patient is female, "M" if male.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;     2 - PRON (opt) Pronoun: 1=he/she, 2=him/her,3=his,her
  1.  ;
  1.  Q:'$G(DFN) ""
  1.  Q:'$D(^DPT(DFN,0)) ""
  1.  N X S X=$P(^DPT(DFN,0),U,2)
  1.  Q:'$G(PRON) X
  1.  I PRON=1 Q $S(X="F":"she",1:"he")
  1.  I PRON=2 Q $S(X="F":"her",1:"him")
  1.  I PRON=3 Q $S(X="F":"her",1:"his")
  1.  Q X
  1.  ;
  1.  ;
  1.  ;----------
  1. SEXW(DFN) ;EP
  1.  ;---> Return Patient sex: "Female"/"Male".
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;
  1.  Q:$$SEX(DFN)="M" "Male"
  1.  Q:$$SEX(DFN)="F" "Female"
  1.  Q "Unknown"
  1.  ;
  1.  ;
  1.  ;----------
  1. ACTIVE(DFN) ;PEP - Return Patient's Active Status in Immunization Package.
  1.  ;---> Return text of Patient's Active Status.
  1.  ;---> $$ACTIVE^BIUTL1(DFN) will return values of either:
  1.  ;---> "Deceased","Inactive", or "Active".
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;
  1.  N X
  1.  S X=$$DECEASED(DFN)
  1.  Q:X>0 "Deceased"
  1.  S X=$$INACT(DFN)
  1.  Q:X "Inactive"
  1.  Q:X]"" X
  1.  Q "Active"
  1.  ;
  1.  ;
  1.  ;----------
  1. INACT(DFN,TEXT) ;PEP - Return date this patient became Inactive in Immunization.
  1.  ;---> Return date this patient became Inactive.
  1.  ;---> $$INACT^BIUTL1(DFN) will return values of either:
  1.  ;---> "NO PATIENT","UNKNOWN", "NOT IN REGISTER", DATE INACTIVE, or null.
  1.  ;
  1.  ;---> NOTE: If $$INACT^BIUTL1(DFN)="" then the Patient is Active.
  1.  ;
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;     2 - TEXT (opt) If TEXT=1, return text of date.
  1.  ;
  1.  Q:'$G(DFN) "NO PATIENT"
  1.  Q:'$D(^DPT(DFN,0)) "UNKNOWN"
  1.  Q:'$D(^BIP(DFN,0)) "NOT IN REGISTER"
  1.  N X S X=$P(^BIP(DFN,0),U,8)
  1.  Q:'X ""
  1.  Q:'$G(TEXT) X
  1.  Q $$TXDT1^BIUTL5(X)
  1.  ;
  1.  ;
  1.  ;----------
  1. INACTRE(DFN,BICODE) ;EP
  1.  ;---> Return Reason for Inactive.
  1.  ;---> Parameters:
  1.  ;     1 - DFN    (req) Patient's IEN (DFN).
  1.  ;     2 - BICODE (opt) If BICODE=1 return Code rather than text.
  1.  ;
  1.  Q:'$G(DFN) ""
  1.  N X,Y,Z S X=$P($G(^BIP(DFN,0)),U,16)
  1.  Q:(X="") ""
  1.  S Y=$P($G(^DD(9002084,.16,0)),U,3)
  1.  S Z=$P($P(Y,X_":",2),";")
  1.  S:Z="" Z="Not Recorded"
  1.  Q Z
  1.  ;
  1.  ;
  1.  ;----------
  1. INACTUSR(DFN,Z) ;EP
  1.  ;---> Return User who made this Patient Inactive.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;     2 - Z    (opt) If Z=1 return IEN of user.
  1.  ;
  1.  Q:'$G(DFN) ""
  1.  N X S X=$P($G(^BIP(DFN,0)),U,23)
  1.  Q:$G(Z) X
  1.  Q $$PERSON(X)
  1.  ;
  1.  ;
  1.  ;----------
  1. INACTREG(DFN,DUZ2) ;EP
  1.  ;---> Return 1 if patient does not have an Active Chart in
  1.  ;---> RPMS Patient Registration at this site DUZ(2).
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;     2 - DUZ2 (req) IEN of site DUZ(2) to check for Active Chart.
  1.  ;
  1.  Q:'$G(DFN) 1
  1.  Q:'$G(DUZ2) 1
  1.  Q:'$D(^AUPNPAT(DFN,41,DUZ2,0)) 1
  1.  ;
  1.  ;********** PATCH 1, SEP 21,2006, IHS/CMI/MWR
  1.  ;---> Correct test for Active Chart at site DUZ2.
  1.  ;Q:$P($D(^AUPNPAT(DFN,41,DUZ2,0)),"^",3) 1
  1.  Q:$P(^AUPNPAT(DFN,41,DUZ2,0),"^",3) 1
  1.  ;**********
  1.  ;
  1.  Q 0
  1.  ;
  1.  ;
  1.  ;----------
  1. ENTERED(DFN,BIA,BIT) ;EP
  1.  ;---> Return date this patient was entered.
  1.  ;---> Parameters:
  1.  ;     1 - DFN (req) Patient's IEN (DFN).
  1.  ;     2 - BIA (opt) If BIA="", return Date Entered.
  1.  ;                   If BIA=1, return 1 if Automatically entered during Scan.
  1.  ;     3 - BIT (opt) If BIT=1, return text of Date or Auto field.
  1.  ;
  1.  Q:'$G(DFN) ""
  1.  Q:'$D(^BIP(DFN,0)) ""
  1.  N X,Y
  1.  S Y=$S($G(BIA):22,1:21)
  1.  S X=$P(^BIP(DFN,0),U,Y)
  1.  Q:$G(BIA) $S($G(BIT):$S(X:"Automatically",1:"Manually"),1:X)
  1.  Q:'$G(BIT) X
  1.  Q $$TXDT1^BIUTL5(X)
  1.  ;
  1.  ;
  1.  ;----------
  1. MOVEDLOC(DFN) ;EP
  1.  ;---> Return Location where patient moved is receiving treatment elsewhere.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;
  1.  Q:'$G(DFN) ""
  1.  Q $P($G(^BIP(DFN,0)),U,12)
  1.  ;
  1.  ;
  1.  ;----------
  1. LASTLET(DFN,TEXT) ;EP
  1.  ;---> Return Fileman date of the last letter sent to this patient.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;     2 - TEXT (opt) If TEXT=1, return text of date.
  1.  ;
  1.  Q:'$G(DFN) 0
  1.  Q:'$D(^DPT(DFN,0)) "None"
  1.  Q:'$D(^BIP(DFN,0)) "Not in Register"
  1.  N X S X=$P(^BIP(DFN,0),U,14)
  1.  Q:'X "None"
  1.  Q:'$G(TEXT) X
  1.  Q $$TXDT1^BIUTL5(X)
  1.  ;
  1.  ;
  1.  ;----------
  1. NAMAGE(DFN) ;EP
  1.  ;---> Return Patient Name concatenated with age.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;
  1.  Q:'$G(DFN) "NO PATIENT"
  1.  Q $$NAME(DFN)_" ("_$$AGE(DFN)_"y/o)"
  1.  ;
  1.  ;
  1.  ;----------
  1. SSN(DFN) ;EP
  1.  ;---> Return Social Security Number (SSN).
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  N X
  1.  Q:'$G(DFN) "NO PATIENT"
  1.  Q:'$D(^DPT(DFN,0)) "Unknown"
  1.  S X=$P(^DPT(DFN,0),U,9)
  1.  Q:X']"" "Unknown"
  1.  Q X
  1.  ;
  1.  ;
  1.  ;----------
  1. HRCN(DFN,DUZ2,BIX) ;EP
  1.  ;---> Return IHS Health Record Number.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;     2 - DUZ2 (opt) User's Site/Location IEN.  If no DUZ2
  1.  ;                    provided, function will look for DUZ(2).
  1.  ;     3 - BIX  (opt) If BIX=1 return HRCN with no dashes.
  1.  ;
  1.  ;  vvv83
  1.  S:'$G(DUZ2) DUZ2=$G(DUZ(2))
  1.  Q:'$G(DFN)!('$G(DUZ2)) "No Value"
  1.  Q:'$D(^AUPNPAT(DFN,41,DUZ2,0)) "Not Here"
  1.  Q:'+$P(^AUPNPAT(DFN,41,DUZ2,0),"^",2) "No Rec#"
  1.  N Y S Y=$P(^AUPNPAT(DFN,41,DUZ2,0),"^",2)
  1.  Q:$G(BIX) Y
  1.  Q:'+Y Y
  1.  Q:'$$DASH(DUZ2) Y
  1.  I $L(Y)=7 D  Q Y
  1.  .S Y=$TR("123-45-67",1234567,Y)
  1.  S Y=$E("00000",0,6-$L(Y))_Y
  1.  S Y=$TR("12-34-56",123456,Y)
  1.  Q Y
  1.  ;
  1.  ;
  1.  ;----------
  1. DASH(BIDUZ2) ;EP
  1.  ;---> Return 1 if Site Parameter says return Chart#s with dashes.
  1.  ;---> Parameters:
  1.  ;     1 - BIDUZ2 (req) User's DUZ(2)
  1.  ;
  1.  Q +$P($G(^BISITE(+$G(BIDUZ2),0)),U,12)
  1.  ;
  1.  ;
  1.  ;----------
  1. HPHONE(DFN) ;EP
  1.  ;---> Return patient's home phone number.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;
  1.  Q:'$G(DFN) "No Patient"
  1.  Q:'$D(^DPT(DFN,.13)) "Unknown"
  1.  Q:$P(^DPT(DFN,.13),U)="" "Unknown"
  1.  Q $P(^DPT(DFN,.13),U)
  1.  ;
  1.  ;
  1.  ;********** PATCH 1, SEP 21,2006, IHS/CMI/MWR
  1.  ;---> Add ability to retrieve 2nd and 3rd Street Address lines.
  1.  ;----------
  1. STREET(DFN,Z) ;EP
  1.  ;---> Return patient's street address.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;     2 - Z    (opt) If Z=2 return Line 2 of patient's address.
  1.  ;                    If Z=3 return Line 3 of patient's address.
  1.  ;
  1.  N X S X=$S($G(Z)=2:2,$G(Z)=3:3,1:1)
  1.  Q:'$G(DFN) "No Patient"
  1.  Q:'$D(^DPT(DFN,.11)) "Unknown"
  1.  ;---> Only return "Unknown" for the first line.
  1.  Q:$P(^DPT(DFN,.11),U,X)="" $S(X=1:"Unknown",1:"")
  1.  Q $P(^DPT(DFN,.11),U,X)
  1.  ;
  1.  ;
  1.  ;----------
  1. CITY(DFN) ;EP
  1.  ;---> Return patient's city.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;
  1.  Q:'$G(DFN) "No Patient"
  1.  Q:'$D(^DPT(DFN,.11)) "Unknown"
  1.  Q:$P(^DPT(DFN,.11),U,4)="" "Unknown"
  1.  Q $P(^DPT(DFN,.11),U,4)
  1.  ;
  1.  ;
  1.  ;----------
  1. STATE(DFN) ;EP
  1.  ;---> Return patient's state.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;
  1.  Q:'$G(DFN) "No Patient"
  1.  Q:'$D(^DPT(DFN,.11)) "No State"
  1.  Q:$P(^DPT(DFN,.11),U,5)="" "No State"
  1.  Q $P(^DIC(5,$P(^DPT(DFN,.11),U,5),0),U,2)
  1.  ;
  1.  ;
  1.  ;----------
  1. ZIP(DFN) ;EP
  1.  ;---> Return patient's zipcode.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;
  1.  Q:'$G(DFN) "No Patient"
  1.  Q:'$D(^DPT(DFN,.11)) "No Zip"
  1.  Q:$P(^DPT(DFN,.11),U,6)="" "No Zip"
  1.  Q $P(^DPT(DFN,.11),U,6)
  1.  ;
  1.  ;
  1.  ;----------
  1. CTYSTZ(DFN) ;EP
  1.  ;---> Return patient's city, state zip.
  1.  ;---> Parameters:
  1.  ;     1 - DFN  (req) Patient's IEN (DFN).
  1.  ;
  1.  Q:'$G(DFN) "No Patient"
  1.  Q $$CITY(DFN)_", "_$$STATE(DFN)_"  "_$$ZIP(DFN)
  1.  ;
  1.  ;
  1.  ;----------
  1. CMGR(DFN,TEXT,ORDER) ;EP
  1.  ;---> Return patient's Case Manager.
  1.  ;---> Parameters:
  1.  ;     1 - DFN   (req) Patient's IEN (DFN).
  1.  ;     2 - TEXT  (opt) If TEXT=1, return text of Case Manager.
  1.  ;     3 - ORDER (opt) ""/0=Last,First  1=First Last
  1.  ;
  1.  N Y
  1.  Q:'$G(DFN) "No Patient"
  1.  Q:'$D(^BIP(DFN,0)) "Unknown"
  1.  S Y=$P(^BIP(DFN,0),U,10)
  1.  Q:'$G(TEXT) Y
  1.  Q $$PERSON(Y,$G(ORDER))
  1.  ;
  1.  ;
  1.  ;----------
  1. DPRV(DFN,TEXT,ORDER) ;EP
  1.  ;---> Return patient's Designated Provider.
  1.  ;---> Parameters:
  1.  ;     1 - DFN   (req) Patient's IEN (DFN).
  1.  ;     2 - TEXT  (opt) If TEXT=1, return text of Case Manager.
  1.  ;     3 - ORDER (opt) ""/0=Last,First  1=First Last
  1.  ;
  1.  N Y,Z
  1.  Q:'$G(DFN) "No Patient"
  1.  Q:'$D(^BIP(DFN,0)) "Unknown"
  1.  Q:'$L($T(^BDPAPI)) "No BDP Pkg"
  1.  D ALLDP^BDPAPI(DFN,"DESIGNATED PRIMARY PROVIDER",.Y)
  1.  S Z=$P($G(Y("DESIGNATED PRIMARY PROVIDER")),U,2)
  1.  Q:'$G(TEXT) Z
  1.  Q $$PERSON(Z,$G(ORDER))
  1.  ;
  1.  ;
  1.  ;----------
  1. PERSON(X,ORDER) ;EP
  1.  ;---> Return person's name from File #200.
  1.  ;---> Parameters:
  1.  ;     1 - X     (req) Person's IEN in New Person File #200.
  1.  ;     2 - ORDER (opt) ""/0=Last,First   1=First Last
  1.  ;
  1.  Q:'X "Unknown"
  1.  Q:'$D(^VA(200,X,0)) "Unknown"
  1.  N Y S Y=$P(^VA(200,X,0),U)
  1.  Q:'$G(ORDER) Y
  1.  Q $$FL(Y)
  1.  ;
  1.  ;
  1.  ;----------
  1. PARENT(DFN,BIX) ;EP
  1.  ;---> Return Patient's Parent/Guardian name as stored in the
  1.  ;---> Immunization database.
  1.  ;---> Parameters:
  1.  ;     1 - DFN (req) Patient's IEN (DFN).
  1.  ;     2 - BIX (opt) If BIX=1, return text for letter address
  1.  ;                   (return text "Parent/Guardian of" if no data).
  1.  N Y
  1.  D
  1.  .I '$G(DFN) S Y="" Q
  1.  .S Y=$P($G(^BIP(DFN,0)),U,9)
  1.  ;---> If no Parent/Guardian in Immunization, check Patient Reg.
  1.  ;S:Y="" Y=?
  1.  Q:'$G(BIX) Y
  1.  Q:Y="" "Parent/Guardian of"
  1.  Q Y_", for"
  1.  ;
  1.  ;
  1.  ;----------
  1. INELIG(BIDFN) ;EP
  1.  ;---> Return 1 if patient is Ineligible in RPMS Patient Registration.
  1.  ;---> Parameters:
  1.  ;     1 - BIDFN  (req) Patient's IEN (DFN).
  1.  ;
  1.  Q:'$G(BIDFN) 0
  1.  Q:$P($G(^AUPNPAT(BIDFN,11)),"^",12)="I" 1
  1.  Q 0
  1.  ;
  1.  ;
  1.  ;----------
  1.  ;---> Return 1 if patient or guardian consented to participation in the state
  1.  ;---> registry.
  1.  ;---> Parameters:
  1.  ;     1 - BIDFN  (req) Patient's IEN (DFN).
  1.  ;
  1.  Q:'$G(BIDFN) ""
  1.  Q $P($G(^BIP(BIDFN,0)),"^",24)