Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BLRLABIR

BLRLABIR.m

Go to the documentation of this file. 
  1. BLRLABIR ; IHS/MSC/MKK - Lab Install Reports ; 22-Oct-2013 09:22 ; MKK
  1.  ;;5.2;IHS LABORATORY;**1033**;NOV 01, 1997
  1.  ;
  1. EEP ; Ersatz EP
  1.  D EEP^BLRGMENU
  1.  Q
  1.  ;
  1. EP ; EP
  1. PEP ; EP
  1.  ; New everything but Default variables
  1.  NEW (DILOCKTM,DISYS,DT,DTIME,DUZ,IO,IOBS,IOF,IOM,ION,IOS,IOSL,IOST,IOT,IOXY,U,XPARSYS,XQXFLG)
  1.  ;
  1.  D MAKEMENU
  1.  ;
  1.  ; Main Menu driver
  1.  D MENUDRVR^BLRGMENU("IHS Laboratory User Support","Lab Patch Install Reports")
  1.  Q
  1.  ;
  1. MAKEMENU ; EP -- Lab Install Reports Menu
  1.  S BLRVERN=$P($P($T(+1),";")," ")
  1.  ;
  1.  D ADDTMENU^BLRGMENU("IHSONLY^BLRLABIR","IHS Lab Patches Only")
  1.  D ADDTMENU^BLRGMENU("VAONLY^BLRLABIR","VA Lab Patches Only")
  1.  D ADDTMENU^BLRGMENU("BOTH^BLRLABIR","IHS & VA Lab Patches")
  1.  Q
  1.  ;
  1. IHSONLY ; EP - IHS Lab Patches Only Report
  1.  NEW (DILOCKTM,DISYS,DT,DTIME,DUZ,IO,IOBS,IOF,IOM,ION,IOS,IOSL,IOST,IOT,IOXY,U,XPARSYS,XQXFLG)
  1.  ;
  1.  Q:$$INITVARS("IHS Lab Package Patch Installs")="Q"
  1.  ;
  1.  F SEED="BLR*5.2*1099","LR*5.2*1099"  D
  1.  . S SEEDBEG=$P(SEED,"*")
  1.  . S SEEDBEGL=$L(SEEDBEG)
  1.  . S PATCH=SEED
  1.  . F  S PATCH=$O(^XPD(9.7,"B",PATCH),-1)  Q:PATCH=""!($E(PATCH,1,SEEDBEGL)'=SEEDBEG)!(QFLG="Q")  D
  1.  .. S IEN="A"
  1.  .. F  S IEN=$O(^XPD(9.7,"B",PATCH,IEN),-1)  Q:IEN<1!(QFLG="Q")  D
  1.  ... D LINEDATA
  1.  ;
  1.  D ^%ZISC
  1.  ;
  1.  D PRESSKEY^BLRGMENU(9)
  1.  Q
  1.  ;
  1. VAONLY ; EP - VA Lab Patches Only Report
  1.  NEW (DILOCKTM,DISYS,DT,DTIME,DUZ,IO,IOBS,IOF,IOM,ION,IOS,IOSL,IOST,IOT,IOXY,U,XPARSYS,XQXFLG)
  1.  ;
  1.  Q:$$INITVARS("VA Lab Package Patch Installs")="Q"
  1.  ;
  1.  F  S PATCH=$O(^XPD(9.7,"B",PATCH),-1)  Q:PATCH=""!($E(PATCH,1,2)'="LR")!($L($P(PATCH,"*",3))>3)!(QFLG="Q")  D
  1.  . S IEN="A"
  1.  . F  S IEN=$O(^XPD(9.7,"B",PATCH,IEN),-1)  Q:IEN<1!(QFLG="Q")  D
  1.  .. D LINEDATA
  1.  ;
  1.  D ^%ZISC
  1.  ;
  1.  D PRESSKEY^BLRGMENU(9)
  1.  Q
  1.  ;
  1. BOTH ; EP - Both VA and RPMS Lab Patches Report
  1.  NEW (DILOCKTM,DISYS,DT,DTIME,DUZ,IO,IOBS,IOF,IOM,ION,IOS,IOSL,IOST,IOT,IOXY,U,XPARSYS,XQXFLG)
  1.  ;
  1.  D BOTHCOMP
  1.  ;
  1.  Q:$$INITVARS("RPMS Lab Package Patch Installs")="Q"
  1.  ;
  1.  S WHNSTART=.9999999
  1.  F  S WHNSTART=$O(^TMP("BLRLABIR",$J,WHNSTART))  Q:WHNSTART<1!(QFLG="Q")  D
  1.  . S PATCH=""
  1.  . F  S PATCH=$O(^TMP("BLRLABIR",$J,WHNSTART,PATCH))  Q:PATCH=""!(QFLG="Q")  D
  1.  .. S IEN=.9999999
  1.  .. F  S IEN=$O(^TMP("BLRLABIR",$J,WHNSTART,PATCH,IEN))  Q:IEN<1!(QFLG="Q")  D
  1.  ... D LINEDATA
  1.  ;
  1.  D ^%ZISC
  1.  ;
  1.  D PRESSKEY^BLRGMENU(9)
  1.  ;
  1.  Q
  1.  ;
  1. BOTHCOMP ; EP - Compile Data for Combined Report
  1.  NEW (DILOCKTM,DISYS,DT,DTIME,DUZ,IO,IOBS,IOF,IOM,ION,IOS,IOSL,IOST,IOT,IOXY,U,XPARSYS,XQXFLG)
  1.  ;
  1.  S BLRVERN=$P($P($T(+1),";")," ")
  1.  S HEADER(1)="RPMS Lab Package Patch Installs"
  1.  S HEADER(2)="Compilation of Data"
  1.  ;
  1.  D HEADERDT^BLRGMENU
  1.  ;
  1.  K ^TMP("BLRLABIR")
  1.  ;
  1.  W ?5,"Compiling"
  1.  S PATCH="LR*5.2*A"
  1.  ;
  1.  F SEED="BLR*5.2*1099","LR*5.2*A"  D
  1.  . S SEEDBEG=$P(SEED,"*")
  1.  . S SEEDBEGL=$L(SEEDBEG)
  1.  . S PATCH=SEED
  1.  . F  S PATCH=$O(^XPD(9.7,"B",PATCH),-1)  Q:PATCH=""!($E(PATCH,1,SEEDBEGL)'=SEEDBEG)  D
  1.  .. S IEN="A"
  1.  .. F  S IEN=$O(^XPD(9.7,"B",PATCH,IEN),-1)  Q:IEN<1  D
  1.  ... W "."  W:$X>74 !,?5
  1.  ... ;
  1.  ... S STARTDTT=$P($G(^XPD(9.7,IEN,1)),"^")
  1.  ... S ^TMP("BLRLABIR",$J,STARTDTT,PATCH,IEN)=""
  1.  ;
  1.  W !!,?5,"Compilation Complete."
  1.  D PRESSKEY^BLRGMENU(10)
  1.  Q
  1.  ;
  1. INITVARS(HEADL1) ; EP - Initialization of variables
  1.  S BLRVERN=$P($P($T(+1),";")," ")
  1.  ;
  1.  S HEADER(1)=HEADL1
  1.  S HEADER(2)="Reverse Patch Sort"
  1.  S HEADER(3)=" "
  1.  S HEADER(4)="Patch #"
  1.  S $E(HEADER(4),14)="Package Name"
  1.  S $E(HEADER(4),29)="Started Date/Time"
  1.  S $E(HEADER(4),51)="Completed Date/Time"
  1.  S $E(HEADER(4),73)="File 200"
  1.  ;
  1.  S:HEADL1["IHS" PATCH="LR*5.2*1099"
  1.  S:HEADL1["VA" PATCH="LR*5.2*A"
  1.  S:HEADL1["RPMS" HEADER(2)="Start Date/Time Sort"
  1.  ;
  1.  D ^%ZIS
  1.  I POP D  Q "Q"
  1.  . W !,?4,"Could not open output Device.  Routine Ends.",!
  1.  . D PRESSKEY^BLRGMENU(9)
  1.  ;
  1.  S QFLG="NO"
  1.  S MAXLINES=$S(IOT["VT":(IOSL-4),1:IOSL)
  1.  S LINES=MAXLINES+10,PG=0
  1.  ;
  1.  U IO
  1.  ;
  1.  Q "OK"
  1.  ;
  1. LINEDATA ; EP - Write a line of Data
  1.  I LINES>MAXLINES D HEADERPG^BLRGMENU(.PG,.QFLG,"NO")  I QFLG="Q" Q
  1.  ;
  1.  D INSTLLFB
  1.  ;
  1.  W $E(PATCH,1,12)
  1.  W ?13,$E(NAME,1,13)
  1.  W ?28,STARTDTT
  1.  W ?50,COMPDTT
  1.  W ?72,WHOINSTALL
  1.  W !
  1.  S LINES=LINES+1
  1.  Q
  1.  ;
  1. INSTLLFB ; EP - INSTALL File Breakout of Variables
  1.  S STR=$G(^XPD(9.7,IEN,0))
  1.  S WHOINSTALL=$P(STR,"^",11)
  1.  ;
  1.  S PKGFLINK=$P(STR,"^",2)
  1.  S NAME=$P($G(^DIC(9.4,+PKGFLINK,0)),"^")
  1.  ;
  1.  S STR=$G(^XPD(9.7,IEN,1))
  1.  ;
  1.  S STARTDTT=$P(STR,"^")
  1.  S:$L(STARTDTT) STARTDTT=$$FMTE^XLFDT(STARTDTT,"5Z")
  1.  ;
  1.  S COMPDTT=$P(STR,"^",3)
  1.  S:$L(COMPDTT) COMPDTT=$$FMTE^XLFDT(COMPDTT,"5Z")
  1.  Q