Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BMC4P11

BMC4P11.m

Go to the documentation of this file. 
  1. BMC4P11 ;IHS/OIT/FCJ - BMC 4.0 PATCH 11 ; 16 Feb 2011  2:54 PM
  1.  ;;4.0;REFERRED CARE INFO SYSTEM;**11**;JAN 09, 2006;Build 51
  1.  ;ORIGINAL ROUTINE FR BMC4P9
  1.  ;
  1.  I '$G(IOM) D HOME^%ZIS
  1.  ;
  1.  I '$G(DUZ) W !,"DUZ UNDEFINED OR 0." D SORRY(2) Q
  1.  ;
  1.  I '$L($G(DUZ(0))) W !,"DUZ(0) UNDEFINED OR NULL." D SORRY(2) Q
  1.  ;
  1.  I '(DUZ(0)["@") W:'$D(ZTQUEUED) !,"DUZ(0) DOES NOT CONTAIN AN '@'." D SORRY(2) Q
  1.  ;
  1.  S X=$$GET1^DIQ(200,DUZ,.01)
  1.  W !!,$$CJ^XLFSTR("Hello, "_$P(X,",",2)_" "_$P(X,","),IOM)
  1.  W !!,$$CJ^XLFSTR("Checking Environment for "_$P($T(+2),";",4)_" V "_$P($T(+2),";",3)_".",IOM),!
  1.  ;
  1.  NEW IORVON,IORVOFF
  1.  S X="IORVON;IORVOFF"
  1.  D ENDR^%ZISS
  1.  ;
  1.  I $$VCHK("BMC","4.0",2,"'=")
  1.  I $$VCHK("DI","22.0",2,"<")
  1.  I $$VCHK("XU","8.0",2,"<")
  1.  I $$VCHK^BMC4P11("AICD","4.0",2,"<")
  1.  I '$$INSTALLD("AG*7.1*11") S BMCQUIT=2 D SORRY(BMCQUIT)
  1.  I '$$INSTALLD("AUPN*99.1*16") S BMCQUIT=2 D SORRY(BMCQUIT)
  1.  I '$$INSTALLD("ATX*5.1*5") S BMCQUIT=2 D SORRY(BMCQUIT)
  1.  I '$$INSTALLD("AUT*98.1*26") S BMCQUIT=2 D SORRY(BMCQUIT)
  1.  I '$$INSTALLD("LEX*2.0*1003") S BMCQUIT=2 D SORRY(BMCQUIT)
  1.  I '$$INSTALLD("OR*3.0*190") S BMCQUIT=2 D SORRY(BMCQUIT)
  1.  I $$VCHK("BSTS","1.0",2,"'=")
  1.  W !!
  1.  S DIR(0)="Y0",DIR("A")="Is the Facility using PCC" D ^DIR
  1.  I +Y>0,'$$INSTALLD("BJPC*2.0*10") S BMCQUIT=2 D SORRY(BMCQUIT)
  1.  W !
  1.  S DIR(0)="Y0",DIR("A")="Is the Facility using EHR" D ^DIR
  1.  I +Y>0,'$$INSTALLD("BGO*1.1*13") S BMCQUIT=2 D SORRY(BMCQUIT) W !
  1.  ;
  1.  NEW DA,DIC
  1.  S X="BMC",DIC="^DIC(9.4,",DIC(0)="",D="C"
  1.  D IX^DIC
  1.  I Y<0,$D(^DIC(9.4,"C","BMC")) D
  1.  . W !!,*7,*7,$$CJ^XLFSTR("You Have More Than One Entry In The",IOM),!,$$CJ^XLFSTR("PACKAGE File with an ""BMC"" prefix.",IOM)
  1.  . W !,$$CJ^XLFSTR(IORVON_"One entry needs to be deleted."_IORVOFF,IOM)
  1.  . D SORRY(2)
  1.  ;
  1.  I $G(XPDQUIT) W !,$$CJ^XLFSTR(IORVON_"You will need to update package(s) before proceeding."_IORVOFF,IOM),!!,*7,*7,*7 Q
  1.  W !!,$$CJ^XLFSTR("ENVIRONMENT OK.",IOM)
  1.  D HELP^XBHELP("INTROE","BMC4P11")
  1.  I '$$DIR^XBDIR("E","","","","","",1) D SORRY(2) Q
  1.  I $G(XPDENV)=1 S (XPDDIQ("XPZ1"),XPDDIQ("XPZ2"))=0 D HELP^XBHELP("INTROI","BMC4P11") I '$$DIR^XBDIR("E","","","","","",1) D SORRY(2)
  1.  Q
  1.  ;
  1. SORRY(X) ;
  1.  KILL DIFQ
  1.  S XPDQUIT=X
  1.  W *7,!,$$CJ^XLFSTR("Sorry....Need to update package!",IOM)
  1.  Q
  1.  ;
  1. VCHK(BMCPRE,BMCVER,BMCQUIT,BMCCOMP) ; Check versions needed.
  1.  ;  
  1.  NEW BMCV
  1.  S BMCV=$$VERSION^XPDUTL(BMCPRE)
  1.  I BMCV="" D  Q 0
  1.  .W !,$$CJ^XLFSTR("Need "_$S(BMCCOMP="<":"at least ",1:"")_BMCPRE_" v "_BMCVER_"....."_BMCPRE_" v "_BMCV_" Not Present",IOM)
  1.  .D SORRY(BMCQUIT)
  1.  W !,$$CJ^XLFSTR("Need "_$S(BMCCOMP="<":"at least ",1:"")_BMCPRE_" v "_BMCVER_"....."_BMCPRE_" v "_BMCV_" Present",IOM)
  1.  I @(BMCV_BMCCOMP_BMCVER) D SORRY(BMCQUIT) Q 0
  1.  Q 1
  1.  ;
  1. INSTALLD(BMC) ; Determine if patch BMC was installed, where BMC is
  1.  ; the name of the INSTALL.  E.g "AVA*93.2*12".
  1.  ;
  1.  NEW DIC,X,Y,P
  1.  ;  lookup package.
  1.  S X=$P(BMC,"*",1)
  1.  S DIC="^DIC(9.4,",DIC(0)="FM",D="C"
  1.  D IX^DIC
  1.  I Y<1 Q 0
  1.  ;  lookup version.
  1.  S DIC=DIC_+Y_",22,",X=$P(BMC,"*",2)
  1.  D ^DIC
  1.  I Y<1 Q 0
  1.  ;  lookup patch.
  1.  S DIC=DIC_+Y_",""PAH"",",X=$P(BMC,"*",3)
  1.  D ^DIC
  1.  I Y<1 S P=DIC_"""B"","_X_")" I $O(@P)'="" S Y=1
  1.  I Y>0 W !,$$CJ^XLFSTR("Need at least "_BMC_"....."_BMC_" Present",IOM)
  1.  I Y<0 W !,$$CJ^XLFSTR("Need at least "_BMC_".....",IOM)
  1.  Q $S(Y<1:0,1:1)
  1.  ;
  1.  ; -----------------------------------------------------
  1. PRE ;EP - From KIDS.
  1.  I $$NEWCP^XPDUTL("PRE1","AUDS^BMC4P11")
  1.  ; The following line prevents the "Disable Options..." and "Move
  1.  ; Routines..." questions from being asked during the install.
  1.  I $G(XPDENV)=1 S (XPDDIQ("XPZ1"),XPDDIQ("XPZ2"))=0
  1.  Q
  1.  ;
  1. POST ;EP - From KIDS.
  1.  ; --- Restore dd audit settings.
  1.  S %="AUDR^BMC4P11"
  1.  I $$NEWCP^XPDUTL("POS1-"_%,%)
  1.  ;
  1.  ; --- Set new Index "BA" and "BB"
  1.  S %="INDX^BMC4P11"
  1.  I $$NEWCP^XPDUTL("POS2-"_%,%)
  1.  ;
  1.  ; --- Add Provider/Vendor Option
  1.  S %="P5^BMC4P11"
  1.  I $$NEWCP^XPDUTL("POS3-"_%,%)
  1.  ;
  1.  ; --- Add MED HX Option and fx CHS 2010 PO #'s
  1.  S %="P6^BMC4P11"
  1.  I $$NEWCP^XPDUTL("POS4-"_%,%)
  1.  ;
  1.  ; --- Add Report Option for printing C32s for Active referrals
  1.  S %="P7^BMC4P11"
  1.  I $$NEWCP^XPDUTL("POS5-"_%,%)
  1.  ;
  1.  ; --- Add Report Option for TOC and Edit option for TOC
  1.  S %="P8^BMC4P11"
  1.  I $$NEWCP^XPDUTL("POS6-"_%,%)
  1.  ;
  1.  ; ---Re-Add Report Options, removed because a parent opt sent
  1.  S %="P9^BMC4P11"
  1.  I $$NEWCP^XPDUTL("POS8-"_%,%)
  1.  ;
  1.  ; ---Remove CHS PAID option from GEN Ref selection list
  1.  S %="P10^BMC4P11"
  1.  I $$NEWCP^XPDUTL("POS9-"_%,%)
  1.  ;
  1.  ; ---Remove clinic field from V ref file
  1.  S %="P10VR^BMC4P11"
  1.  I $$NEWCP^XPDUTL("POS10-"_%,%)
  1.  ;
  1.  ; ---Reformat comments to 80 char lenght in RCIS Comments file
  1.  S %="P10COM^BMC4P11"
  1.  I $$NEWCP^XPDUTL("POS11-"_%,%)
  1.  ;
  1.  ; --- Send mail message of install.
  1.  S %="MAIL^BMC4P11"
  1.  I $$NEWCP^XPDUTL("POS12-"_%,%)
  1.  ;
  1.  Q
  1.  ;
  1. MAIL ;
  1.  D BMES^XPDUTL("BEGIN Delivering MailMan message to select users.")
  1.  NEW DIFROM,XMSUB,XMDUZ,XMTEXT,XMY
  1.  KILL ^TMP("BMC4P11",$J)
  1.  D RSLT(" --- BMC v 4.0 Patch 8, has been installed into this namespace ---")
  1.  F %=1:1 D RSLT($P($T(GREET+%),";",3)) Q:$P($T(GREET+%+1),";",3)="###"
  1.  S %=0
  1.  F  S %=$O(^XTMP("XPDI",XPDA,"BLD",XPDBLD,1,%)) Q:'%   D RSLT(^(%,0))
  1.  S XMSUB=$P($P($T(+1),";",2)," ",3,99),XMDUZ=$S($G(DUZ):DUZ,1:.5),XMTEXT="^TMP(""BMC4P11"",$J,",XMY(1)="",XMY(DUZ)=""
  1.  F %="BMCZMENU","XUMGR","XUPROG","XUPROGMODE" D SINGLE(%)
  1.  D ^XMD
  1.  KILL ^TMP("BMC4P11",$J)
  1.  D MES^XPDUTL("END Delivering MailMan message to select users.")
  1.  Q
  1.  ;
  1. RSLT(%) S ^(0)=$G(^TMP("BMC4P11",$J,0))+1,^(^(0))=%
  1.  Q
  1.  ;
  1. SINGLE(K) ; Get holders of a single key K.
  1.  NEW Y
  1.  S Y=0
  1.  Q:'$D(^XUSEC(K))
  1.  F  S Y=$O(^XUSEC(K,Y)) Q:'Y  S XMY(Y)=""
  1.  Q
  1.  ;
  1. INTROE ; Intro text during KIDS Environment check.
  1.  ;;In this distribution:
  1.  ;;
  1.  ;;    Changes include
  1.  ;;      1. Modify RCIS CPT CATEGORY file to include HCPCS
  1.  ;;      2. Modify screens for adding/editing for HCPCS update
  1.  ;;      3. Rebuild special reports menu option
  1.  ;;      4. Fix for allowing date/time entry on add referral
  1.  ;;      5. Fix for truncation of Med Hx Comment from GUI
  1.  ;;      6. Change label on GUI for CPT Category to include HCPCS
  1.  ;;
  1.  ;;###
  1.  ;
  1. INTROI ; Intro text during KIDS Install.
  1.  ;;A standard message will be produced by this update.
  1.  ;;  
  1.  ;;If you run interactively, results will be displayed on your screen,
  1.  ;;as well as in the mail message and the entry in the INSTALL file.
  1.  ;;If you queue to TaskMan, please read the mail message for results of
  1.  ;;this update, and remember not to Q to the HOME device.
  1.  ;;###
  1.  ;
  1. GREET ;;To add to mail message.
  1.  ;;  
  1.  ;;Greetings.
  1.  ;;  
  1.  ;;The RCIS package on your RPMS system has been updated.
  1.  ;;  
  1.  ;;You are receiving this message because of the particular RPMS
  1.  ;;security keys that you hold.  This is for your information, only.
  1.  ;;You need do nothing in response to this message.
  1.  ;;  
  1.  ;;Questions about this patch, which is a product of the RPMS applications
  1.  ;;can be directed to the OIT Support Center, at 505-248-4371,
  1.  ;;or via e-mail to support@ihs.gov.
  1.  ;;Please refer to patch "bmc*4.0*11".
  1.  ;;  
  1.  ;;###;NOTE: This line indicates the end of text in this message.
  1.  ;
  1.  ; -----------------------------------------------------
  1.  ; The global location for dictionary audit is:
  1.  ;           ^DD(FILE,0,"DDA")
  1.  ; If the valuey is "Y", dd audit is on.  Any other value, or the
  1.  ; absence of the node, means dd audit is off.
  1.  ; -----------------------------------------------------
  1. AUDS ;EP - From KIDS.
  1.  D BMES^XPDUTL("Saving current DD AUDIT settings for files in this patch")
  1.  D MES^XPDUTL("and turning DD AUDIT to 'Y'.")
  1.  S ^XTMP("BMC4P11",0)=$$FMADD^XLFDT(DT,10)_"^"_DT_"^"_$P($P($T(+1),";",2)," ",3,99)
  1.  NEW BMC
  1.  S BMC=0
  1.  F  S BMC=$O(^XTMP("XPDI",XPDA,"FIA",BMC)) Q:'BMC  D
  1.  . I '$D(^XTMP("BMC4P11",BMC,"DDA")) S ^XTMP("BMC4P11",BMC,"DDA")=$G(^DD(BMC,0,"DDA"))
  1.  . D MES^XPDUTL(" File "_$$RJ^XLFSTR(BMC,12)_" - "_$$LJ^XLFSTR(^XTMP("XPDI",XPDA,"FIA",BMC),30)_"- DD audit was '"_$G(^XTMP("BMC4P11",BMC,"DDA"))_"'"),MES^XPDUTL($$RJ^XLFSTR("Set to 'Y'",69))
  1.  . S ^DD(BMC,0,"DDA")="Y"
  1.  .Q
  1.  D MES^XPDUTL("DD AUDIT settings saved in ^XTMP(.")
  1.  Q
  1.  ; -----------------------------------------------------
  1. AUDR ; Restore the file data audit values to their original values.
  1.  D BMES^XPDUTL("Restoring DD AUDIT settings for files in this patch.")
  1.  NEW BMC
  1.  S BMC=0
  1.  F  S BMC=$O(^XTMP("BMC4P11",BMC)) Q:'BMC  D
  1.  . S ^DD(BMC,0,"DDA")=^XTMP("BMC4P11",BMC,"DDA")
  1.  . D MES^XPDUTL(" File "_$$RJ^XLFSTR(BMC,12)_" - "_$$LJ^XLFSTR($$GET1^DID(BMC,"","","NAME"),30)_"- DD AUDIT Set to '"_^DD(BMC,0,"DDA")_"'")
  1.  .Q
  1.  KILL ^XTMP("BMC4P11")
  1.  D MES^XPDUTL("DD AUDIT settings restored.")
  1.  Q
  1.  ; -----------------------------------------------------
  1. INDX ;INDEX NEW INDECIES "BA", "BB" AND "CD" ;Patch 2
  1.  S BMC="BMC*4.0*2" Q:$$INSTALLD^BMC4P0(BMC)
  1.  D BMES^XPDUTL("BEGIN Indexing Expected Begining Date of Service.")
  1.  S DIK="^BMCREF("
  1.  S DIK(1)="1105^BA"
  1.  D ENALL^DIK
  1.  D BMES^XPDUTL("BEGIN Indexing Actual Appointment/begin DOS.")
  1.  S DIK(1)="1106^BB"
  1.  D ENALL^DIK
  1.  D BMES^XPDUTL("BEGIN Indexing CHS Denial Number.")
  1.  S DIK(1)="1128^CD"
  1.  D ENALL^DIK
  1.  D BMES^XPDUTL("Completed updating new indexes.")
  1.  K DA,DIC,DIK,X
  1.  Q
  1.  ; -----------------------------------------------------
  1. P5 ;Add Menu option for Vendor
  1.  S BMC="BMC*4.0*5" Q:$$INSTALLD^BMC4P0(BMC)
  1.  D BMES^XPDUTL("Begin adding new Provider/Vendor option.")
  1.  I $$ADD^XPDMENU("BMCMENU","BMCVEN","VEN") D MES^XPDUTL($J("",5)_"Provider/Vendor add/edit Menu added to RCIS Main Menu")
  1.  D MES^XPDUTL("END updating option.")
  1.  Q
  1.  ; -----------------------------------------------------
  1. P6 ;FX CHS PO'S WITH FY 00 INSTEAD OF FY 10
  1.  S BMC="BMC*4.0*6" Q:$$INSTALLD^BMC4P0(BMC)
  1.  D MES^XPDUTL("Updating CHS 2010 PO Numbers.")
  1.  S BMC=3090900 F  S BMC=$O(^BMCREF("B",BMC)) Q:BMC'?1N.N  D
  1.  .S BMC1="" F  S BMC1=$O(^BMCREF("B",BMC,BMC1)) Q:BMC1'?1N.N  D
  1.  ..I $D(^BMCREF(BMC1,41)) S BMC2=0 F  S BMC2=$O(^BMCREF(BMC1,41,BMC2)) Q:BMC2'?1N.N  D
  1.  ...S BMCPO=$P(^BMCREF(BMC1,41,BMC2,0),U,8)
  1.  ...I $E(BMCPO,1,2)="00",$L(BMCPO)=12 D
  1.  ....S $P(^BMCREF(BMC1,41,BMC2,0),U,8)="10"_$E(BMCPO,3,12)
  1.  ....S $P(^BMCREF(BMC1,41,BMC2,11),U)=10
  1.  D BMES^XPDUTL("Begin adding option for Adding Med Hx comments.")
  1.  I $$ADD^XPDMENU("BMC MENU EDIT REFERRAL","BMC MED HX COMMENTS","MED") D MES^XPDUTL($J("",5)_"Enter Medical Hx Comments Menu added to RCIS Edit Menu")
  1.  D MES^XPDUTL("END updating option.")
  1.  Q
  1.  ; ------------------------------------------------------
  1. P7 ;Adding new Report menu option for the printed C32
  1.  S BMC="BMC*4.0*7" Q:$$INSTALLD^BMC4P0(BMC)
  1.  D BMES^XPDUTL("Begin adding option for Active referrals without a printed C32.")
  1.  I $$ADD^XPDMENU("BMC MENU-RPTS ADMINISTRATIVE","BMC RPT-ACTIVE REFERRALS-C32","ARC") D MES^XPDUTL($J("",5)_"Report for Active ref w/o a C32 Menu added to Adm Report option")
  1.  D MES^XPDUTL("END updating option.")
  1.  Q
  1.  ; ------------------------------------------------------
  1. P8 ;Adding new Report menu option for TOC and Edit option for TOC
  1.  S BMC="BMC*4.0*8" Q:$$INSTALLD^BMC4P0(BMC)
  1.  D BMES^XPDUTL("Begin adding option for TOC Report for Approved referrals pending a TOC document.")
  1.  I $$ADD^XPDMENU("BMC MENU-RPTS ADMINISTRATIVE","BMC RPT-APPRV REF TOC PENDING","TOCR") D MES^XPDUTL($J("",5)_"Report for Approved ref w/o a TOC option added to Adm Report option")
  1.  D BMES^XPDUTL("Begin adding Edit option for TOC Information.")
  1.  I $$ADD^XPDMENU("BMC MENU EDIT REFERRAL","BMC MOD TOC","TOC") D MES^XPDUTL($J("",5)_"Edit Option for TOC information for Approved Referrals.")
  1.  D MES^XPDUTL("END updating option.")
  1.  ;
  1. PCCLNK  ;Add RCIS to PCC Visit Merge Utility
  1.  ;NEW INDEX NEED TO REINDEX FOR BETA SITES
  1.  S DIK="^BMCREF(",DIK(1)="1309^VSTR" D ENALL^DIK K DIK
  1.  I $D(^APCDLINK("B","REFERRED CARE INFORMATION SYST")) D  ;already exists
  1.  .S DA=0,DA=$O(^APCDLINK("B","REFERRED CARE INFORMATION SYST",DA))
  1.  .S DIE="^APCDLINK(",DR=".01///REFERRED CARE INFORMATION SYS;1///I $L($T(MRG^BMCPCCV))"
  1.  .D ^DIE K DIE,DA,DR
  1.  Q:$D(^APCDLINK("B","REFERRED CARE INFORMATION SYS"))  ;already exists
  1.  D BMES^XPDUTL("Adding RCIS to PCC Visit Merge Utility . . .")
  1.  NEW DD,DO,DIC,DLAYGO,X,Y
  1.  S DIC="^APCDLINK(",DIC(0)="LE",DLAYGO=9001002
  1.  S DIC("DR")=".02///BMC;1///I $L($T(MRG^BMCPCCV)) D MRG^BMCPCCV;3///I $L($T(DEL^BMCPCCV)) D DEL^BMCPCCV"
  1.  S X="REFERRED CARE INFORMATION SYS" D FILE^DICN
  1.  Q
  1.  ; ------------------------------------------------------
  1. P9 ;Add Report menu options
  1.  S BMC="BMC*4.0*9" ;Q:$$INSTALLD^BMC4P0(BMC)
  1.  D MES^XPDUTL("Begin updating Special Print Menu option.")
  1.  I $$ADD^XPDMENU("BMC MENU SPECIAL","BMC DISPLAY REFERRAL RECORD","DSP")
  1.  I $$ADD^XPDMENU("BMC MENU SPECIAL","BMC PRINT REFERRAL FORMS","PRF")
  1.  I $$ADD^XPDMENU("BMC MENU SPECIAL","BMC PRINT ROUTING SLIP","PRS")
  1.  I $$ADD^XPDMENU("BMC MENU SPECIAL","BMC MENU-PRINT REPORTS","RPT")
  1.  D MES^XPDUTL("END updating Special Print Menu option.")
  1.  Q
  1.  ; ------------------------------------------------------
  1. P10 ;Patch 10
  1.  S BMC="BMC*4.0*10" Q:$$INSTALLD^BMC4P0(BMC)
  1.  ;Delete GEN RET option 99.1 CHS Paid To Date
  1.  NEW DA,DIE,DIC,DR
  1.  S DA=192,DIE="^BMCTSORT(",DR=".01////"_"@"
  1.  D ^DIE
  1.  D BMES^XPDUTL("CHS Paid To Date removed from Gen Ret items . . .")
  1.  Q
  1.  ;
  1. P10VR ;Clean up clinic stop in V Referral file
  1.  S BMC="BMC*4.0*10" Q:$$INSTALLD^BMC4P0(BMC)
  1.  NEW DA,DIE,DIC,DR
  1.  S DA=0
  1.  S DIE="^AUPNVREF(",DR="1203////"_"@"
  1.  F  S DA=$O(^AUPNVREF(DA)) Q:DA'?1N.N  D:$P($G(^AUPNVREF(DA,12)),U,3)'=""
  1.  .D ^DIE
  1.  D BMES^XPDUTL("Completed clean up of clinic stop field in V Referral file . . .")
  1.  Q
  1. P10COM ;Clean up of comments file
  1.  S BMC="BMC*4.0*10" Q:$$INSTALLD^BMC4P0(BMC)
  1.  NEW DA,DIE,DIC,DR
  1.  S BEGDT=3130100
  1.  F  S BEGDT=$O(^BMCCOM("B",BEGDT)) Q:BEGDT'?1N.N  D
  1.  .S DA=0
  1.  .F  S DA=$O(^BMCCOM("B",BEGDT,DA)) Q:DA'?1N.N  D
  1.  ..Q:'$D(^BMCCOM(DA,1,0))
  1.  ..S DA(1)=0,FLG=0 F  S DA(1)=$O(^BMCCOM(DA,1,DA(1))) Q:DA(1)'?1N.N  I $L(^BMCCOM(DA,1,DA(1),0))>80 S FLG=1
  1.  ..Q:FLG'=1
  1.  ..S DA(1)=0 F  S DA(1)=$O(^BMCCOM(DA,1,DA(1))) Q:DA(1)'?1N.N  D
  1.  ...S ^BMCCOMT(DA,1,DA(1),0)=^BMCCOM(DA,1,DA(1),0)
  1.  ..S ^BMCCOMT(DA,1,0)=^BMCCOM(DA,1,0),BMCDA=(DA(1)-1)
  1.  ..K ^BMCCOM(DA,1)
  1.  ..S BMCDA=0,BMCDA2=0
  1.  ..F  S BMCDA=$O(^BMCCOMT(DA,1,BMCDA)) Q:BMCDA'?1N.N  D
  1.  ...S BMCCOM=^BMCCOMT(DA,1,BMCDA,0)
  1.  ...S L=($L(BMCCOM)/80) I L#1>0 S L=L+1
  1.  ...S (LGTH,LGTH2)=0 F I=1:1:L D
  1.  ....S LGTH=LGTH2+1,BMCDA2=BMCDA2+1,LGTH2=80*BMCDA2 S ^BMCCOM(DA,1,BMCDA2,0)=$E(BMCCOM,LGTH,LGTH2)
  1.  ...S ^BMCCOM(DA,1,0)=^BMCCOMT(DA,1,0),$P(^BMCCOM(DA,1,0),U,2,4)="90001.031"_U_BMCDA2_U_BMCDA2
  1.  K L,LGTH,LGHT2,BMCDA,BMCDA2,BMCCOM,FLG,BEGDT,CT
  1.  D BMES^XPDUTL("Completed clean up RCIS Comments file . . .")
  1.  Q
  1.  ; ------------------------------------------------------