Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BMXADOXY

BMXADOXY.m

Go to the documentation of this file. 
  1. BMXADOXY ; IHS/CIHA/GIS - RPC CALL: GENERATE AN ADO SCHEMA STRING AND DATA SET ;
  1.  ;;2.0;BMX;;FEB 26, 2007
  1.  ; EXMAPLES OF FILEMAN SCHEMA GENERATION
  1.  ;
  1.  ;
  1.  ;
  1. DISP(OUT) ; TEMP DISPLAY OF THE ANR
  1.  N I,X
  1.  S I=0 W !
  1.  F  S I=$O(@OUT@(I)) Q:'I  S X=@OUT@(I) S X=$TR(X,$C(30),"}") S X=$TR(X,$C(31),"{") W !,X
  1.  Q
  1.  ;
  1. SCHEMA(NAME) ; GIVEN SCHEMA NAME, RETURN THE IEN
  1.  N IEN
  1.  S IEN=$O(^BMXADO("B",NAME,0))
  1.  Q IEN
  1.  ; 
  1. NUM ; ITERATE BY IEN
  1.  ; IX="",START WITH IEN=1, STOP AFTER IEN=20, MAX # RECORDS RETURNED = 5
  1.  ; TO VIEW INTERNAL VALUES SET VSTG="~1~20~5~I"
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("IHS PATIENT")
  1.  D SS^BMXADO(.OUT,SIEN,"","~1~20~5")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. IX ; ITERATE BY INDEX
  1.  ; ITERATE USING THE "B" INDEX
  1.  ; START WITH PT NAME "C", STOP AFTER PATIENT NAME = "D", MAX # RECORDS RETURNED = 5
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("IHS PATIENT")
  1.  D SS^BMXADO(.OUT,SIEN,"","B~C~D~5")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. RENT ; ITERATE IN CHUNKS
  1.  ; RE-ITERATE USING THE "B" INDEX
  1.  ; START WITH PT IEN 5 AS THE "SEED", STOP AFTER PATIENT NAME = "D", MAX # RECORDS RETURNED = 5
  1.  N OUT,%,SIEN,SEED,LSEED,X,Y
  1.  S SEED=0,LSEED=""
  1.  S SIEN=$$SCHEMA("IHS PATIENT")
  1. RIT F  D  I '$G(SEED) Q
  1.  . D SS^BMXADO(.OUT,SIEN,SEED,"B~CA~CB~5")
  1.  . D DISP(OUT) R %:$G(DTIME,60) E  S SEED="" Q
  1.  . I %?1"^" S SEED="" Q
  1.  . S X=$P(@OUT@(1),U,1)
  1.  . S SEED=$P(X,"|",3)
  1.  . I SEED=LSEED S SEED="" Q
  1.  . S LSEED=SEED
  1.  . K ^TMP("BMX ADO",$J)
  1.  . Q
  1.  Q
  1.  ;
  1. SUB ; SUBFILE ITERATION
  1.  ; THE SCHEMA IS ATTACHED TO THE MEDICARE ELIGIBILITY FILE/ELIG DATE SUBFILE
  1.  ; THE DA STRING HAS A VALUE OF '4,',: THE IEN IN THE PARENT FILE (PATIENT DFN).
  1.  ; NOTE THE COMMA IN THE DA STRING.  THIS INDICATES THAT THE FILE IEN IS 4 BUT THE SUBFILE IEN IS UNSPECIFIED 
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("UPDATE MEDICARE DATES")
  1.  ;D SS^BMXADO(.OUT,SIEN,"1,","~~~")
  1.  D SS^BMXADO(.OUT,18,"1,","~~~")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. DINUM ; DINUMED POINTER ITERATION
  1.  ; THE SCHEMA IS ATTACHED TO THE PATIENT FILE (9000001)
  1.  ; THE PATIENT FILE IS DINUM'D AND ITS .01 FIELD POINTS TO THE VA PATIENT FILE (2)
  1.  ; BECAUSE OF THE SPECIAL RELATIONSHIP BETWEEN THE FILES, WE CAN USE THE B INDEX OF FILE 2 TO ITERATE FILE 9000001.
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("IHS PATIENT")
  1.  D SS^BMXADO(.OUT,SIEN,"","B~A~B~5")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. IXP ; INDEXED POINTER ITERATION
  1.  ; THE SCHEMA IS ATTACHED TO THE V POV FILE
  1.  ; THE AC CROSS REFERENCE INDEXES THE PATIENT FIELD
  1.  ; BY STARTING AND STOPING WITH PATIENT 235 (MAX=5) WE COLLECT THE FIRST 5 POVS FOR PATIENT 235 IN THE FILE
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("VIEW POVS")
  1.  D SS^BMXADO(.OUT,SIEN,"","AC~235~235~5")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. AA ; ITERATE USING AA INDEX
  1.  ; INDEX IS 'AA"  THE START AND STOP DATES ARE SPECIFIED IN EXTERNAL FORMAT.  MAX=10
  1.  ; THE FOLLOWING FILTERS ARE SPECIFIED IN THE LAST PARAMETER ("235|WT|C"):
  1.  ;   235=PATIENT DFN #235
  1.  ;   WT=RETURN ONLY WEIGHTS. MEASUREMENT TYPE MUST BE SPECIFIED WITH A VALID, UNAMBIGUOUS LOOKUP VALUE.
  1.  ;   C=RETRUN VALUES IN CHRONOLOGICAL ORDER USE 'R' INSTEAD OF 'C' FOR REVERSE CHRONOLOGICAL ORDER. DEFAULT=C
  1.  ;   THE SEED PARAMTER IS SET AND CAN BE USED TO RETURN DATA IN CHUNKS
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("VIEW MEASUREMENTS")
  1.  D SS^BMXADO(.OUT,SIEN,"","AA~3/21/1965~6/4/2004~5~~~~235|WT|C")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. AA2 ; ITERATE USING AA INDEX
  1.  ; THIS SCHEMA IS ATTACHED TO THE VISIT FILE (9000010)
  1.  ; IN THIS CASE THERE IS NO ATTRIBUTE TYPE SO THE FILTER PARAM HAS ONLY 2 PIECES "1|R"
  1.  ;   235=PATIENT DFN
  1.  ;   R=RETURN DATA IN REVERSE CHRONOLOGICAL ORDER
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("VISITS") ;12
  1.  D SS^BMXADO(.OUT,SIEN,"","AA~3/21/1965~6/4/2004~5~~~~235|R")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. CIT ; CUSTOM ITERATOR
  1.  ; IF COMPLEX OR UNUSUAL SORTING/FILTERING IS REQUITED, USE A CUSTOM ITERATOR
  1.  ; THE CUSTOM ITERATOR IS DEFINED BY 6TH, 7TH AND 8TH PIECES IN THE VSTG
  1.  ;   PIECE 8=TAG, PIECE 9=ROUTINE, PIECE 8=A PARAMETER PASSED TO THE ENTRY POINT
  1.  ;   THE 9TH PIECE CONTAINS PT DFN, TIMESTAMP, VISIT TYPE, LOC IEN, AND SERVICE CATEGORY IN A "|" DELIMTED STRING
  1.  ;   THE ITERATOR CALL TAG^ROUTINE(PARAM) TO GENERATE IENS
  1.  ; IN THIS CASE THE SCHEMA IS ATTACHED TO THE VISIT FILE.
  1.  ; GIVEN THE INFORMATION IN THE PARAMETER, THE CUSTOM ITERATOR RETURNS POSSIBLE DUPLICATE VISITS
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("VISITS")
  1.  D SS^BMXADO(.OUT,SIEN,"","~~~~~DUPV~BMXADOV2~9285|5/24/04@1PM|I|516|~")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. ID ; IDENTIFIER FIELD
  1.  ; THE SCHEMA IS ATTACHED TO THE VA PATIENT FILE (2)
  1.  ; THE SCHEMA HAS A BUILT IN FIELD (.01ID) THAT RETURNS THE IDENTIFIERS
  1.  ; THE ENTRY POINT THAT GENERATES THE IDETIFIERS IS STORED IN THE BMX ADO SCHEMA FILE
  1.  ; PATIENT DFN=235
  1.  N OUT,%,SIEN
  1.  S SIEN=$$SCHEMA("UPDATE PATIENT DEMOGRAPHICS")
  1.  D SS^BMXADO(.OUT,SIEN,"","~235~235~")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. JSTD ; STANDARD JOIN
  1.  ; BY SPECIFYING A JOIN IN THE VSTG, MULTIPLE SCHEMAE AND DATA SETS ARE RETURNED IN ONE PASS
  1.  ; THE SCHEMA IS ATTACHED TO THE V MEASUREMENT FILE
  1.  ; THIS IS JOINED TO A SECOND FILE, THE VA PATIENT FILE VIA A JOIN
  1.  ; THE JOIN IS BASTED ON THE FACT THAT THE PATIENT FIELD (.02) IN THE V MEASUREMENT FILE POINTS TO THE VA PATIENT FILE
  1.  ; THE JOIN PARAMETER IS THE 9TH PIECE OF THE VSTG. IT CONSISTS OF 2 PIECES DELIMITED BY A ","
  1.  ;   PIECE 1 IS THE SCHEMA THAT YOU ARE JOINING TO
  1.  ;   PIECE 2 IS THE FIELD IN THE PRIMARY FILE THAT ENABLES THE JOIN
  1.  ; THE DATA SET FROM THE SECOND (JOIN) FILE CONTAINS ONLY THOSE RECORDS NECESSARY TO COMPLETE THE JOIN
  1.  ; PATIENT DFN=235, INDEX=AA, MAX=5, START=3/21/65, STOP=6/4/04
  1.  N OUT,%,SIEN1,SIEN2
  1.  S SIEN2=$$SCHEMA("VIEW MEASUREMENTS")
  1.  S SIEN1=$$SCHEMA("PATIENT DEMOGRAPHICS")
  1.  ;SIEN1=23, SIEN2=11
  1.  ;D SS^BMXADO(.OUT,SIEN1,"","AA~3/21/1965~6/4/2004~5~~~~234|WT|C~"_SIEN2_",.02")
  1.  D SS^BMXADO(.OUT,SIEN1,"","~234~236~~~~~~"_SIEN2_",.01")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. HWSTD ;
  1.  ; PATIENT DFN=235, INDEX=AA, MAX=5, START=3/21/65, STOP=6/4/04
  1.  N OUT,%,SIEN1,SIEN2
  1.  S SIEN1=$$SCHEMA("PATIENT DEMOGRAPHICS")
  1.  S SIEN2=$$SCHEMA("VIEW MEASUREMENTS")
  1.  ;SIEN2=23, SIEN1=11
  1.  D SS^BMXADO(.OUT,SIEN1,"","~235~250~~~~~~"_SIEN2_",.01")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. JMD ;JOIN MASTER TO DETAIL
  1.  N OUT,%,SIEN1,SIEN2,SIEN3,VSTG
  1.  S SIEN1=$$SCHEMA("PATIENT DEMOGRAPHICS")
  1.  S SIEN2=$$SCHEMA("VIEW MEASUREMENTS")
  1.  S SIEN3=$$SCHEMA("VIEW MEDS")
  1.  S VSTG="~1~5~~~~~~"
  1.  ;S VSTG=VSTG_SIEN3_",.001,.02IEN,AA~1/1/1960~6/30/2004~~~~~|C"
  1.  S VSTG=VSTG_SIEN3_",.001,.02IEN,AA~1/1/1960~6/30/2004~~~~~|C"
  1.  ;S VSTG="~1~5~~~~~~23,.001,.02IEN,AA~1/1/1960~6/30/2004~~~~~|WT|C"
  1.  ;BMX ADO SS^11^^~1~5~~~~~~23,.001,.02IEN,AA~1/1/1960~6/30/2004~~~~~|WT|C
  1.  ;BMX ADO SS^11^^~1~5~~~~~~25,.001,.02IEN,AA~1/1/1960~6/30/2004~~~~~|C
  1.  D SS^BMXADO(.OUT,SIEN1,"",VSTG)
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. JSUB ; SUBFILE JOIN
  1.  ; IN THIS CASE THE RECORDS IN A PARENT FILE ARE "JOINED" TO THE RECORDS IN ONE OF ITS SUB FILES
  1.  ; THE SCHEMA IS ATTACHED TO THE "MEDICARE ELIGIBLE" FILE
  1.  ; IT IS JOINED TO ITS SUBFILE, "ELIG DATES", VIA THE UPDATE MEDICARE DATES SCHEMA
  1.  ; THE SYNTAX FOR THE JOIN PIECE IS "sien2,SUB" WHERE sien2=IEN OF SECOND SCHEMA
  1.  ; PATIENT DFN=4
  1.  N OUT,%,SIEN1,SIEN2
  1.  S SIEN1=$$SCHEMA("UPDATE MEDICARE INFO") ;17
  1.  S SIEN2=$$SCHEMA("UPDATE MEDICARE DATES") ;18
  1.  ;BMX ADO SS^17^^~4~5~~~~~~18,SUB
  1.  D SS^BMXADO(.OUT,SIEN1,"","~4~5~~~~~~"_SIEN2_",SUB")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ;
  1. JPAR ; PARENT FILE JOIN
  1.  ; SIMILAR TO A SUBFILE JOIN EXCEPT THE SUB-FILE IS TREATED AS THE PRIMARY FILE AND IT IS JOINED TO ITS PARENT
  1.  ; BECAUSE WE ARE STARTING IN A SUBFILE, THE DA STRING CONTAINS THE IEN OF THE PARENT FILE ("4,"
  1.  ; THE SYNTAX OF THE 9TH PIECE IS "sien2,PARENT" WHERE sien2 IS THE IEN OF THE SECONDARY SCHEMA
  1.  ; PATIENT DFN=4
  1.  N OUT,%,SIEN1,SIEN2
  1.  S SIEN1=$$SCHEMA("UPDATE MEDICARE DATES")
  1.  S SIEN2=$$SCHEMA("UPDATE MEDICARE INFO")
  1.  D SS^BMXADO(.OUT,SIEN1,"4,","~~~5~~~~~"_SIEN2_",PARENT")
  1.  D DISP(OUT) R %:$G(DTIME,60)
  1.  K ^TMP("BMX ADO",$J)
  1.  Q
  1.  ; 
  1. ADD ; ADD A NEW ENTRY
  1.  ; THIS IS A 2 STEP PROCESS:
  1.  ;   FIRST GET THE SCHEMA FOR THE FILE YOU WISH TO UPDATE
  1.  ;     THIS SCHEMA'S NAME TYPICALLY BEGINS WITH THE WORD "UPDATE"
  1.  ;     IT CONTAINS NO ID OR IEN FIELDS
  1.  ;   SECOND ADD THE DATA NODE TO THE ARRAY
  1.  ;     IT HAS THE SAME FORMAT AS A DATA STRING ASSOCIATED WITH THE SCHEMA EXCEPT THE FIRST "^" PIECE IS NULL
  1.  ;     THIS PIECE CORRESPONDS TO THE IEN OF THE RECORD. SINCE THE RECORD HAS NOT BEEN ADDED YET, IT IS NULL.
  1.  ;     IN THE DATA STRING, ALL POINTER VALUES ARE PRECEDED BY THE '`' CHARACTER AND EA. STRING ENDS IN $C(30)
  1.  ;     MULTIPLE DATA STRINGS CAN BE APPENDED AS NEW NODES AT THE BOTTOM OF THE ARRAY
  1.  ;     IN THIS CASE WE ARE ADDING A RECORD TO THE V MEASUREMENT FILE
  1.  ;     DATA STRING="^MEASUREMENT TYPE IEN^PATIENT DFN^VISIT IEN^RESULT"_$C(30)
  1.  ; THERE ARE 2 INPUT PARAMS:
  1.  ;   THE CLOSED REF WHERE THE INPUT ARRAY IS STORED
  1.  ;   SINCE IT IS PASSED BY REFERENCE "OUT" CAN BE NULL OR UNDEFIEND.
  1.  ;   OUT WILL BE DEFINED AT THE CONCLUSION OF THE TRANSACTION.
  1.  ; THE OUTPUT IS IN THE OUT ARRAY
  1.  ;   OUT(1)="OK|ien" WHERE ien IS THE IEN OF THE RECORD THAT HAS BEE ADDED.
  1.  ;   IF THE TRANSACTION FAILED, AN ERROR MSG WILL BE IN THE OUT ARRAY
  1.  ; MEASUREMENT TYPE=2, PATIENT DFN=2, VISIT IEN=7806, PATIENT'S WEIGHT=172.75
  1.  N OUT,%,SIEN,NODE,DFN
  1.  S DFN=2
  1.  S SIEN=$$SCHEMA("UPDATE MEASUREMENTS")
  1.  D SS^BMXADO(.OUT,SIEN,"","") ; GET SCHEMA
  1.  S NODE=$O(^TMP("BMX ADO",$J,999999),-1)+1
  1.  S ^TMP("BMX ADO",$J,NODE)="^`2^`"_DFN_"^`7806^172.75"_$C(30)
  1.  D DISP(OUT) R %:$G(DTIME,60) ; DISPLAY THE INPUT ARRAY BEFORE UPDATING THE RECORD
  1.  D BAFM^BMXADOF1(.OUT,$NA(^TMP("BMX ADO",$J))) ; EP FOR UPDAING THE RECORD
  1.  K ^TMP("BMX ADO",$J)
  1.  W !!,OUT S %=0 F  S %=$O(OUT(%)) Q:'%  W !,OUT(%) ; SEND BACK AN ACKNOWLEDGEMENT OR ERROR MSG
  1.  Q
  1.  ;
  1. DEL ; DELETE A RECORD
  1.  ; THE SIPLEST WAY TO DELETE AN ENTRY IS TO PUT THE RECORD IEN IN THE DA STRING PRECEDED BY A MINUS SIGN
  1.  ; YOU CAN ALSO SET THE VALUE OF THE .01 FIELD TO "@"
  1.  ; IF THE VALUE OF THE .01 FIELD IS NULL AND THE DA STRING IS NOT PRECEDED BY A MINUS SIGN, THE TRANSACTION WILL BE CANCELLED
  1.  ; IF THE DA STRING IS NULL, THE TRANSACTION WILL BE CANCELLED
  1.  ; IN THIS EXAMPLE, WE DELETE A V MEASUREMENT RECORD THAT WAS JUST ADDED
  1.  N OUT,%,SIEN,NODE,DEL
  1.  S DEL=1621
  1.  S SIEN=$$SCHEMA("UPDATE MEASUREMENTS")
  1.  D SS^BMXADO(.OUT,SIEN,"","") ; GET SCHEMA
  1.  S NODE=$O(^TMP("BMX ADO",$J,999999),-1)+1
  1.  S ^TMP("BMX ADO",$J,NODE)="-"_DEL_$C(30)
  1.  D DISP(OUT) R %:$G(DTIME,60) ; DISPLAY THE INPUT ARRAY BEFORE UPDATING THE RECORD
  1.  D BAFM^BMXADOF1(.OUT,$NA(^TMP("BMX ADO",$J))) ; EP FOR UPDAING THE RECORD
  1.  K ^TMP("BMX ADO",$J)
  1.  W !!,OUT S %=0 F  S %=$O(OUT(%)) Q:'%  W !,OUT(%) ; SEND BACK AN ACKNOWLEDGEMENT OR ERROR MSG
  1.  Q
  1.  ;
  1. EDIT ; EDIT AN EXISTING ENTRY
  1.  ; SIMILAR TO ABOVE EXCEPT THAT THE FIRST "^" PIECE OF THE DATA NODE IS THE IEN OF THE RECORD TO BE EDITIED
  1.  ; NOTE THAT THERE IS NO '`' IN FRONT OF THE FIRST PIECE.  IT IS A PURE INTEGER
  1.  ; LAB TEST=175, PATIENT DFN=2, VISIT IEN=8040, PT'S GLUCOSE=276, ANORMAL="ABNORMAL"
  1.  N OUT,%,SIEN,NODE
  1.  S SIEN=$$SCHEMA("UPDATE LABS")
  1.  D SS^BMXADO(.OUT,SIEN,"","") ; GET SCHEMA
  1.  S NODE=$O(^TMP("BMX ADO",$J,999999),-1)+1
  1.  S ^TMP("BMX ADO",$J,NODE)="279^`175^`2^`8040^280^H"_$C(30)
  1.  D DISP(OUT) R %:$G(DTIME,60) ; DISPLAY THE INPUT ARRAY BEFORE UPDATING THE RECORD
  1.  D BAFM^BMXADOF1(.OUT,$NA(^TMP("BMX ADO",$J))) ; EP FOR UPDAING THE RECORD
  1.  K ^TMP("BMX ADO",$J)
  1.  W !!,OUT S %=0 F  S %=$O(OUT(%)) Q:'%  W !,OUT(%) ; SEND BACK AN ACKNOWLEDGEMENT OR ERROR MSG
  1.  Q
  1.  ;
  1. DELVAL ; DELETE A VALUE IN A FIELD
  1.  ; SIMILAR TO EDIT EXCEPT THE VALUE IS "@"
  1.  ; DELETE WILL BE ABORTED IF IF FILEMAN SAYS THIS IS A REQUIRED FIELD
  1.  N OUT,%,SIEN,NODE
  1.  S SIEN=$$SCHEMA("UPDATE LABS")
  1.  D SS^BMXADO(.OUT,SIEN,"","") ; GET SCHEMA
  1.  S NODE=$O(^TMP("BMX ADO",$J,999999),-1)+1
  1.  S ^TMP("BMX ADO",$J,NODE)="279^`175^`2^`8040^^@"_$C(30)
  1.  D DISP(OUT) R %:$G(DTIME,60) ; DISPLAY THE INPUT ARRAY BEFORE UPDATING THE RECORD
  1.  D BAFM^BMXADOF1(.OUT,$NA(^TMP("BMX ADO",$J))) ; EP FOR UPDAING THE RECORD
  1.  K ^TMP("BMX ADO",$J)
  1.  W !!,OUT S %=0 F  S %=$O(OUT(%)) Q:'%  W !,OUT(%) ; SEND BACK AN ACKNOWLEDGEMENT OR ERROR MSG
  1.  Q
  1.  ;