Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BQIPLUS1

BQIPLUS1.m

Go to the documentation of this file. 
  1. BQIPLUS1 ;GDIT/HS/ALA-User Preferences continued ; 26 Apr 2013  11:11 AM
  1.  ;;2.3;ICARE MANAGEMENT SYSTEM;**3,4**;Apr 18, 2012;Build 66
  1.  ;
  1. UGVMCH(DATA,FAKE) ;EP -- BQI GET USER VERSION
  1.  ;
  1.  ;Description
  1.  ;  Determine if user iCare version does not match iCare server version
  1.  ;  
  1.  ;Input
  1.  ;  FAKE - extra 'blank' parameter required by BMXNET async 'feature'
  1.  ;Output
  1.  ;  Returns user GUI version, server version, and whether versions match (1-Match/0-Do Not Match)
  1.  ;          
  1.  ;Expects
  1.  ;  DUZ - the internal entry number of the person signed on
  1.  ;
  1.  NEW UID,II,BQIDA,MVRSN,UVRSN,SVRSN
  1.  S UID=$S($G(ZTSK):"Z"_ZTSK,1:$J)
  1.  S DATA=$NA(^TMP("BQIPLUSR",UID))
  1.  K @DATA
  1.  ;
  1.  I '$$OWNR(DUZ) S BMXSEC="There is a problem with your entry." Q
  1.  ;
  1.  S II=0
  1.  S @DATA@(II)="T00001MATCHING_VERSION^T00020USER_VERSION^T00020SERVER_VERSION"_$C(30)
  1.  ;
  1.  NEW $ESTACK,$ETRAP S $ETRAP="D ERR^BQIPLUSR D UNWIND^%ZTER" ; SAC 2006 2.2.3.3.2
  1.  ;
  1.  S BQIDA=$$SPM^BQIGPUTL()
  1.  ;
  1.  S UVRSN=$$GET1^DIQ(90505,DUZ_",",.17,"E")
  1.  S SVRSN=$$GET1^DIQ(90508,BQIDA_",",.08,"E")
  1.  S MVRSN=0 I UVRSN=SVRSN S MVRSN=1
  1.  ;
  1.  S II=II+1,@DATA@(II)=MVRSN_U_UVRSN_U_SVRSN_$C(30)
  1.  S II=II+1,@DATA@(II)=$C(31)
  1.  Q
  1.  ;
  1. USVMCH(DATA,FAKE) ;EP -- BQI SET USER VERSION
  1.  ;
  1.  ;Description
  1.  ;  Set the user's iCare GUI version to match the iCare server GUI version
  1.  ;  
  1.  ;Input
  1.  ;  FAKE - extra 'blank' parameter required by BMXNET async 'feature'
  1.  ;Output
  1.  ;  Returns 1-Successful save/-1 - Unsuccessful save
  1.  ;          
  1.  ;Expects
  1.  ;  DUZ - the internal entry number of the person signed on
  1.  ;
  1.  NEW UID,II,BQIDA,SVRSN,BQIUPD,ERROR
  1.  S UID=$S($G(ZTSK):"Z"_ZTSK,1:$J)
  1.  S DATA=$NA(^TMP("BQIPLUSR",UID))
  1.  K @DATA
  1.  ;
  1.  I '$$OWNR(DUZ) S BMXSEC="There is a problem with your entry." Q
  1.  ;
  1.  S II=0
  1.  S @DATA@(II)="I00010RESULT"_$C(30)
  1.  ;
  1.  NEW $ESTACK,$ETRAP S $ETRAP="D ERR^BQIPLUSR D UNWIND^%ZTER" ; SAC 2006 2.2.3.3.2
  1.  ;
  1.  S BQIDA=$$SPM^BQIGPUTL()
  1.  S SVRSN=$$GET1^DIQ(90508,BQIDA_",",.08,"E")
  1.  ;
  1.  S BQIUPD(90505,DUZ_",",.17)=SVRSN
  1.  ;
  1.  D FILE^DIE("","BQIUPD","ERROR")
  1.  K BQIUPD
  1.  S II=II+1
  1.  I '$D(ERROR) S @DATA@(II)="1"_$C(30)
  1.  I $D(ERROR) S @DATA@(II)="-1"_$C(30)
  1.  S II=II+1,@DATA@(II)=$C(31)
  1.  Q
  1.  ;
  1. OWNR(USR) ;EP -- Check owner
  1.  ;
  1.  ;Description
  1.  ;  Check if this user who has signed into iCare is already
  1.  ;  in ICARE USER File #90505
  1.  ;Input
  1.  ;  DUZ - User internal entry number signed into iCare
  1.  ;Output
  1.  ;   1 - if user exists or if user added okay
  1.  ;   0 - if there was an error adding user
  1.  ;
  1.  I $G(^BQICARE(USR,0))'="" Q 1
  1.  I $D(^BQICARE(USR)),$G(^BQICARE(USR,0))="" D  Q 1
  1.  . NEW DIE,DA,DR
  1.  . S DIE="^BQICARE(",DA=USR,DR=".01///^S X=USR" D ^DIE
  1.  ;
  1. CR ;  Create new entry
  1.  NEW IENARRY,BQIUSR,ERROR
  1.  S IENARRY(1)=USR
  1.  S BQIUSR(90505,"+1,",.01)=USR
  1.  D UPDATE^DIE("","BQIUSR","IENARRY","ERROR")
  1.  I $D(ERROR) Q 0
  1.  Q 1