Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BTPWLOCK

BTPWLOCK.m

Go to the documentation of this file. 
  1. BTPWLOCK ;VNGT/HS/ALA-Locking Routine for CMET ; 31 Dec 2009  10:11 AM
  1.  ;;1.0;CARE MANAGEMENT EVENT TRACKING;;Feb 07, 2011
  1.  ;
  1. LOCK(DATA,DFN,TYPE,CMIEN) ; EP - BTPW LOCK CMET RECORD
  1.  ; Input
  1.  ;   DFN   - Patient IEN
  1.  ;   TYPE  - T=Tracked, Q=Queued
  1.  ;   CMIEN - Record IEN
  1.  ; Output:
  1.  ;   DATA  = name of global (passed by reference) in which the data is stored
  1.  ;
  1.  ;   RESULT = 1 if the lock succeeded
  1.  ;          = 0 if the lock failed
  1.  ;          = -1 if problem identified with file 90507 (shouldn't happen)
  1.  ;   USER   = DUZ of the last user to successfully lock this panel
  1.  ; or
  1.  ;   BMXSEC - if M error encountered
  1.  ;            
  1.  NEW UID,X,II,MSG,VAL,RESULT
  1.  S UID=$S($G(ZTSK):"Z"_ZTSK,1:$J)
  1.  S DATA=$NA(^TMP("BTPWLCK",UID))
  1.  K @DATA
  1.  ;
  1.  NEW $ESTACK,$ETRAP S $ETRAP="D ERR^BTPWLOCK D UNWIND^%ZTER" ; SAC 2006 2.2.3.3.2
  1.  ;
  1.  ; Create header record
  1.  S II=0,@DATA@(II)="I00010RESULT^T00080MESSAGE"_$C(30)
  1.  ;
  1.  S VAL=$$VAL(TYPE,CMIEN),MSG=$P(VAL,U,2),VAL=$P(VAL,U)
  1.  I VAL=-1 S RESULT=-1 D SET Q
  1.  ;
  1.  NEW USER
  1.  ; Attempt lock and set RESULT accordingly
  1.  S RESULT=1
  1.  I TYPE="T" L +^BTPWP(CMIEN):1 E  S RESULT=0
  1.  I TYPE="Q" L +^BTPWQ(CMIEN):1 E  S RESULT=0
  1.  ;
  1.  ; If lock is unsuccessful, get 'LAST LOCKED BY' from the panel.
  1.  I RESULT=0 D
  1.  . S USER=$G(^XTMP("BTPWLCK",TYPE,CMIEN))
  1.  . S NAME=$$GET1^DIQ(200,USER,.01,"E")
  1.  . I NAME="" S NAME="an unknown user"
  1.  . S MSG="This event is locked for editing by "_NAME_"."
  1.  ; If lock is successful, update 'LAST LOCKED BY' in ^XTMP.
  1.  I RESULT=1 D
  1.  . S ^XTMP("BTPWLCK",0)=$$FMADD^XLFDT(DT,1)_U_$$DT^XLFDT()_U_"Maintain locked by information for current locks of CMET data"
  1.  . S ^XTMP("BTPWLCK",TYPE,CMIEN)=DUZ
  1.  ;
  1.  D SET
  1.  Q
  1.  ;
  1. UNLOCK(DATA,DFN,TYPE,CMIEN) ; EP - BTPW UNLOCK CMET RECORD
  1.  ; Input
  1.  ;   DFN   - Patient IEN
  1.  ;   TYPE  - T=Tracked, Q=Queued
  1.  ;   CMIEN - Record IEN
  1.  ; Output:
  1.  ;   DATA  = name of global (passed by reference) in which the data is stored
  1.  ;   RESULT = 1 (unlock will always succeed)
  1.  ;   RESULT = -1 if problem identified with file 90507 (shouldn't happen)
  1.  ; or
  1.  ;   BMXSEC - if M error encountered
  1.  ;            
  1.  NEW UID,X,II,MSG,VAL
  1.  S UID=$S($G(ZTSK):"Z"_ZTSK,1:$J)
  1.  S DATA=$NA(^TMP("BTPWLCK",UID))
  1.  K @DATA
  1.  ;
  1.  NEW $ESTACK,$ETRAP S $ETRAP="D ERR^BTPWLOCK D UNWIND^%ZTER" ; SAC 2006 2.2.3.3.2
  1.  ;
  1.  ; Create header record
  1.  S II=0,@DATA@(II)="I00010RESULT^T00080MESSAGE"_$C(30)
  1.  NEW RESULT,USER
  1.  S VAL=$$VAL(TYPE,CMIEN),MSG=$P(VAL,U,2),VAL=$P(VAL,U)
  1.  I VAL=-1 S RESULT=-1 D SET Q
  1.  ;
  1.  ; Unlock and set RESULT
  1.  D UNL(TYPE,CMIEN)
  1.  S RESULT=1
  1.  D SET
  1.  Q
  1.  ;
  1. SET ; Report results
  1.  S II=II+1,@DATA@(II)=RESULT_"^"_$G(MSG)_$C(30)
  1.  S II=II+1,@DATA@(II)=$C(31)
  1.  Q
  1.  ;
  1. ERR ;
  1.  D ^%ZTER
  1.  NEW Y,ERRDTM
  1.  S Y=$$NOW^XLFDT() X ^DD("DD") S ERRDTM=Y
  1.  S BMXSEC="Recording that an error occurred at "_ERRDTM
  1.  I $D(II),$D(DATA) S II=II+1,@DATA@(II)=$C(31)
  1.  Q
  1.  ;
  1. VAL(TYPE,IEN) ;EP - Validate RECORD ien
  1.  I IEN="" Q "-1^Invalid CMET record selected"
  1.  I TYPE="" Q "-1^Invalid CMET event selected"
  1.  I TYPE="T",'$D(^BTPWP(IEN)) Q "-1^Tracked Event does not exist"
  1.  I TYPE="Q",'$D(^BTPWQ(IEN)) Q "-1^Queued Event does not exist"
  1.  Q 1
  1.  ;
  1. UNL(TYPE,CMIEN) ; EP
  1.  ; Get 'LAST LOCKED BY'.
  1.  S USER=$G(^XTMP("BTPWLCK",TYPE,CMIEN))
  1.  ;
  1.  ; If 'LAST LOCKED BY' is this DUZ then delete the lock entry from ^XTMP.
  1.  I USER=DUZ K ^XTMP("BTPWLCK",TYPE,CMIEN)
  1.  I TYPE="T" L -^BTPWP(CMIEN)
  1.  I TYPE="Q" L -^BTPWQ(CMIEN)
  1.  Q