Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BVPMAIN

BVPMAIN.m

Go to the documentation of this file. 
  1. BVPMAIN ; IHS/ITSC/LJF - VPR ENTRY POINT ;
  1.  ;;1.0;VIEW PATIENT RECORD;;NOV 17, 2004
  1.  ;
  1.  ;This routine calls a list template to view a patient's record.
  1.  ;The first screen displayed is the patient's health summary.
  1.  ;
  1.  I '$$PKGCK^BVPU("APCHS","PCC HEALTH SUMMARY") D  D EXIT Q
  1.  . D MSG^BVPU("**HEALTH SUMMARY SOFTWARE NOT INSTALLED**",2,1,1)
  1.  ;
  1.  K ^TMP("BVP",$J) D KILL^AUPNPAT
  1.  F  D GETPAT Q:$G(DFN)<1  D
  1.  . NEW APCHSPAT,APCHSTYP,APCHSTAT,APCHSMTY,AMCHDAYS,AMCHDOB,BVPSAV
  1.  . D GETHSTYP I '$G(APCHSTYP) D EXIT Q
  1.  . S APCHSPAT=DFN,BVPSAV=DFN
  1.  . D EN,FULL^VALM1,EXIT
  1.  ;
  1. EOJ ; -- end of job
  1.  D KILL^AUPNPAT,EN^XBVK("VALM"),EN^XBVK("APCH")
  1.  D KILL^%ZISS
  1.  Q
  1.  ;
  1. EN ;EP -- main entry point for list template BVP HS VIEW
  1.  NEW VALMCNT D TERM^VALM0,CLEAR^VALM1
  1.  D MSG^BVPU("Building Health Summary Display.  Please wait...",1,0,0)
  1.  D EN^VALM("BVP HS VIEW")
  1.  D CLEAR^VALM1
  1.  Q
  1.  ;
  1. HDR ;EP -- header code
  1.  S VALMSG=$$VALMSG^BVPU
  1.  Q
  1.  ;
  1. INIT ;EP -- init variables and list array
  1.  NEW X
  1.  K ^TMP("BVP",$J)
  1.  D GUIR^XBLM("EN^APCHS","^TMP(""BVP"",$J,")
  1.  S X=0 F  S X=$O(^TMP("BVP",$J,X)) Q:'X  D
  1.  . S VALMCNT=X
  1.  . S ^TMP("BVP",$J,X,0)=^TMP("BVP",$J,X)
  1.  D TERM^VALM0
  1.  S VALMSG=$$VALMSG^BVPU
  1.  Q
  1.  ;
  1. HELP ;EP -- help code
  1.  S X="?" D DISP^XQORM1,MSG^BVPU("",2,0,0)
  1.  Q
  1.  ;
  1. EXIT ;EP -- exit code
  1.  K ^TMP("BVP",$J)
  1.  K DFN,BVPSAV,APCHSPAT
  1.  Q
  1.  ;
  1. EXPND ;EP -- expand code
  1.  Q
  1.  ;
  1. RESET ;EP -- update partition for return to list manager
  1.  I $D(VALMQUIT) S VALMBCK="Q" Q
  1.  D TERM^VALM0 S VALMBCK="R"
  1.  D MSG^BVPU("Updating Health Summary Display.  Please Wait...",1,0,0)
  1.  S DFN=BVPSAV D SETPT(DFN)   ;make sure patient is still set
  1.  D INIT,HDR K BVPSECX Q
  1.  ;
  1. RESET2 ;EP -- update partition without recreating display array
  1.  I $D(VALMQUIT) S VALMBCK="Q" Q
  1.  D TERM^VALM0 S VALMBCK="R" D HDR Q
  1.  ;
  1. GETPAT ; -- ask user to select patient
  1.  K DIC,DFN S DIC=9000001,DIC(0)="AEMQZ" D ^DIC I Y>0 S DFN=+Y K DIC,Y
  1.  Q
  1.  ;
  1. GETHSTYP ;EP -- ask user for health summary type
  1.  ; Called by ^BVPVRL1
  1.  NEW DIC,DR,DD,X,Y
  1.  S DIC="^APCHSCTL(",DIC(0)="AEMQ"
  1.  ; get default health summary type
  1.  S Y=$G(^DISV(DUZ,"^APCHSCTL(")) I $D(^APCHSCTL(+Y,0)) S DIC("B")=$P(^(0),U) ;last selected by user
  1.  I '$D(DIC("B")) S DIC("B")="VPR MINI"                                       ;OR set to general HS type
  1.  D ^DIC K DIC Q:Y<1  S APCHSTYP=+Y
  1.  Q
  1.  ;
  1. VST ;EP -- view/edit pcc visits
  1.  ; Called by BVP VISIT VIEW (Visit Details) protocol
  1.  D FULL^VALM1
  1.  S APCDPAT=DFN D GETVISIT^APCDDISP,^APCDVD,EOJ^APCDDISP
  1.  S (DFN,AUPNPAT)=BVPSAV D SETPT(DFN)
  1.  D RESET2
  1.  Q
  1.  ;
  1. HS ;EP; -- change health summary
  1.  ; Called by BVP HS CHANGE (Change Health Summary) protocol
  1.  NEW BVPHS,X,Y
  1.  D FULL^VALM1
  1.  S BVPHS=APCHSTYP D GETHSTYP
  1.  I +$G(APCHSTYP)<1 S APCHSTYP=BVPHS D RESET2 Q
  1.  D EN^BVPMAIN S VALMBCK="Q"
  1.  Q
  1.  ;
  1. SETPT(DFN) ;EP; -- sets AUPN variables when DFN is set
  1.  NEW X,DIC,Y S X="`"_DFN,DIC=2,DIC(0)="" D ^DIC Q