Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: BWPCC1

BWPCC1.m

Go to the documentation of this file. 
  1. BWPCC1 ;IHS/ANMC/MWR - WOMEN'S HEALTH PCC LINK;15-Feb-2003 22:06;PLS
  1.  ;;2.0;WOMEN'S HEALTH;**8**;MAY 16, 1996
  1.  ;;* MICHAEL REMILLARD, DDS * ALASKA NATIVE MEDICAL CENTER *
  1.  ;;  SUBROUTINES FOR BWPCC (CREATE/EDIT A VISIT & V FILE ENTRIES).
  1.  ;;  CHECK ON PASSING A PROCEDURE.  CHECK ON PCC SET UP CORRECTLY.
  1.  ;
  1.  ;
  1. CHECK(BW0,BWDUZ0,BWDUZ2,BWPCDN,BWSITE,BWVFIL) ;EP
  1.  ;---> CHECK TO SEE IF THIS PROCEDURE CAN BE PASSED TO PCC.
  1.  N BWPCCP,DIC,Y
  1.  ;---> QUIT IF THERE IS NO PROCEDURE TYPE, NO SITE WHERE PERFORMED,
  1.  ;---> OR NO V FILE# FOR THIS PROCEDURE.
  1.  Q:'BWPCDN!('BWSITE)!('BWVFIL) 1
  1.  ;
  1.  ;---> QUIT IF THE RESULT OF THE PROCEDURE IS "ERROR/DISREGARD".
  1.  Q:$P(BW0,U,5)=8 2
  1.  ;
  1.  ;---> QUIT IF RPMS SITE FILE IS NOT PRESENT AT THIS SITE.
  1.  Q:'$D(^AUTTSITE(1,0)) 3
  1.  ;
  1.  ;---> QUIT IF PCC IS NOT PRESENT AT THIS SITE (RPMS SITE FILE).
  1.  Q:$P(^AUTTSITE(1,0),U,8)'="Y" 4
  1.  ;
  1.  ;---> QUIT IF NO PCC MASTER CONTROL FILE FOR THIS SITE.
  1.  Q:'$D(^APCCCTRL(BWDUZ2)) 5
  1.  ;
  1.  ;---> QUIT IF WOMEN'S HEALTH IS NOT IN THE PACKAGE FILE.
  1.  D DIC^BWFMAN(9.4,"Q",.Y,"","","","WOMEN'S HEALTH")
  1.  Q:Y<0 6
  1.  ;
  1.  ;---> QUIT IF WOMEN'S HEALTH IS NOT IN PCC MASTER CONTROL FILE OR IF
  1.  ;---> "PASS DATA TO PCC" IS "NO".
  1.  Q:'$D(^APCCCTRL(BWDUZ2,11,+Y,0)) 7
  1.  Q:'$P(^APCCCTRL(BWDUZ2,11,+Y,0),U,2) 8
  1.  ;
  1.  ;---> QUIT IF VISIT TYPE ISN'T DEFINED IN PCC MASTER CONTROL FILE.
  1.  Q:$P(^APCCCTRL(BWDUZ2,0),U,4)']"" 9
  1.  ;
  1.  ;---> QUIT IF PCC DATE/TIME FIELD IS NULL.
  1.  Q:'$P(BW0,U,3) 10
  1.  ;
  1.  ;---> QUIT IF THIS SITE DOES NOT HAVE THE PCC PARAMETER SET FOR
  1.  ;---> THIS PROCEDURE TYPE.
  1.  S BWPCCP=$P($G(^BWSITE(BWDUZ2,BWPCDN)),U,2)
  1.  Q:BWPCCP']"" 11
  1.  ;
  1.  ;---> QUIT IF THIS PROC WAS ON-SITE AND SHOULD NOT BE PASSED.
  1.  Q:BWSITE=BWDUZ2&("fn"[BWPCCP) 12
  1.  ;
  1.  ;---> QUIT IF THIS PROC WAS OFF-SITE AND SHOULD NOT BE PASSED.
  1.  Q:BWSITE'=BWDUZ2&("on"[BWPCCP) 13
  1.  ;
  1.  ;---> QUIT IF THIS PROCEDURE TYPE DOES NOT HAVE A .01 VALUE TO PASS.
  1.  Q:((BWVFIL=9000010.08)&('$P(^BWPN(BWPCDN,0),U,14))) 14
  1.  Q:((BWVFIL=9000010.09)&('$P(^BWPN(BWPCDN,0),U,15))) 15
  1.  Q:((BWVFIL=9000010.13)&('$P(^BWPN(BWPCDN,0),U,16))) 16
  1.  Q:((BWVFIL=9000010.22)&('$P(^BWPN(BWPCDN,0),U,17))) 17
  1.  ;
  1.  ;---> QUIT IF PROBLEMS POINTING TO THE RADIOLOGY PROCEDURES FILE #71.
  1.  I BWVFIL=9000010.22 D  I Y Q Y
  1.  .N Z S Y=0,Z=+$P($P(^DD(BWVFIL,.01,0),U,2),"P",2)
  1.  .I 'Z S Y=19 Q
  1.  .S P=^DIC(Z,0,"GL")_$P(^BWPN(BWPCDN,0),U,17)_",0)"
  1.  .I '$D(@P) S Y=20 Q
  1.  ;
  1.  ;---> QUIT IF USER DOES NOT HAVE PROPER PERMISSIONS.
  1.  I BWDUZ0'["M"&(BWDUZ0'["@") D  Q 18
  1.  .W !?5,"* You do not have the required permission for the PCC Link."
  1.  .W !?7,"Please contact your site manager."  D DIRZ^BWUTL3
  1.  Q 0
  1.  ;
  1.  ;
  1.  ;---> DISPLAY PCC-WOMEN'S HEALTH LINK STATUS
  1.  N X D SETVARS^BWUTL5
  1.  S:'$D(IOF) IOF="!!!"
  1.  W @IOF
  1.  W !?21,"WOMEN'S HEALTH-PCC LINK ENVIRONMENT"
  1.  W !?18,"------------------------------------------",!?8
  1.  W "(All parameters must be ""YES"" for PCC link to be operational.)",!
  1.  ;
  1.  D
  1.  .I '$D(^AUTTSITE(1,0)) D  Q
  1.  ..W !!?5,"1) RPMS SITE file is present:" D DOTS W "NO"
  1.  .W !!?5,"1) PCC is running at this site (RPMS SITE file):" D DOTS
  1.  .W $S($P(^AUTTSITE(1,0),U,8)="Y":"YES",1:"NO")
  1.  ;
  1.  W !!?5,"2) PCC MASTER CONTROL file is defined for this site:" D DOTS
  1.  S X=$D(^APCCCTRL(DUZ(2))) W $S(X:"YES",1:"NO")
  1.  ;
  1.  W !!?5,"3) VISIT TYPE is defined in the PCC MASTER CONTROL file:"
  1.  D DOTS
  1.  W $S('X:"NO",$P(^APCCCTRL(DUZ(2),0),U,4)]"":"YES",1:"NO") K X
  1.  ;
  1.  W !!?5,"4) WOMEN'S HEALTH is defined in the PACKAGE file:" D DOTS
  1.  D DIC^BWFMAN(9.4,"Q",.Y,"","","","WOMEN'S HEALTH")
  1.  W $S(Y:"YES",1:"NO")
  1.  ;
  1.  W !!?5,"5) WOMEN'S HEALTH entry exists in the PCC MASTER CONTROL file:"
  1.  D DOTS
  1.  W $S($D(^APCCCTRL(DUZ(2),11,+Y,0)):"YES",1:"NO")
  1.  ;
  1.  I $D(^APCCCTRL(DUZ(2),11,+Y,0)) D
  1.  .W !!?5,"6) WOMEN'S HEALTH entry in PCC MASTER CONTROL file has"
  1.  .W !?8,"""PASS DATA TO PCC"" set to:" D DOTS
  1.  .W $S('Y:"NO",$P(^APCCCTRL(DUZ(2),11,+Y,0),U,2):"YES",1:"NO")
  1.  ;
  1.  D DIRZ^BWUTL3
  1.  Q
  1.  ;
  1. DOTS ;
  1.  F I=1:1:(69-$X) W "."
  1.  Q
  1.  ;
  1.  ;
  1. DISPLAY1 ;EP
  1.  ;---> DISPLAY VISIT IEN.
  1.  I $D(APCDALVR("APCDVSIT")) D
  1.  .W !,"APCDVSIT DEFINED: ",APCDALVR("APCDVSIT")
  1.  I $D(APCDALVR("APCDVSIT","NEW")) D
  1.  .W !,"NEW VISIT: ",APCDALVR("APCDVSIT","NEW")
  1.  ;---> SHOW FLAG IF VISIT WAS NOT CREATED.
  1.  I $D(APCDALVR("APCDAFLG")) D
  1.  .W !,"APCDAFLG DEFINED, FAILED: ",APCDALVR("APCDAFLG")
  1.  D DIRZ^BWUTL3
  1.  Q
  1.  ;
  1. DISPLAY2 ;EP
  1.  ;---> DISPLAY V FILE IEN.
  1.  I $D(APCDALVR("APCDADFN")) D
  1.  .W !,"APCDADFN DEFINED: ",APCDALVR("APCDADFN")
  1.  ;---> SHOW FLAG IF VISIT WAS NOT CREATED.
  1.  I $D(APCDALVR("APCDAFLG")) D
  1.  .W !,"APCDAFLG DEFINED, FAILED: ",APCDALVR("APCDAFLG")
  1.  D DIRZ^BWUTL3
  1.  Q
  1.  ;
  1. DISPLAY3 ;EP
  1.  ;---> DISPLAY VISIT AND V FILE GLOBAL NODES AND FILE#70 IENS.
  1.  W !!,"VISIT FILE: "
  1.  S N=APCDALVR("APCDVSIT")-3 S:N<0 N=0
  1.  F  S N=$O(^AUPNVSIT(N)) Q:'N  D
  1.  .W !,N,": ",^AUPNVSIT(N,0)
  1.  ;
  1.  W !!,"V FILE: "
  1.  S BWVGBL=^DIC(BWVFIL,0,"GL")
  1.  S N=APCDALVR("APCDADFN")-3,M=N+10 S:N<0 N=0
  1.  F  S N=$O(@(BWVGBL_"N)")) Q:'N  Q:N>M  D
  1.  .W !,N,": ",@(BWVGBL_"N,0)")
  1.  D DIRZ^BWUTL3
  1.  Q