Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DDGLIBW1

DDGLIBW1.m

Go to the documentation of this file. 
  1. DDGLIBW1 ;SFISC/MKO-WINDOWING PRIMITIVES ;02:23 PM  13 Jul 1994
  1.  ;;22.0;VA FileMan;;Mar 30, 1999
  1.  ;Per VHA Directive 10-93-142, this routine should not be modified.
  1. CREATE(I,A,B,N) ;
  1. CREATE1 ;Create window I of area A and draw border (if B)
  1.  ;N = nn; first n=1 means don't give the window focus
  1.  ;        second n=1 means don't write to screen
  1.  ;
  1.  S:$G(I)="" I=-1
  1.  S:$G(A)="" A="0^0^"_IOSL_U_IOM
  1.  K @DDGLREF@(I) S @DDGLREF@(I)=A
  1.  D:$G(B) BOX^DDGLIBW(I,"0^0^"_$P(A,U,3,4),1,$G(N))
  1.  D:$G(N)<9 FOCUS(I,$G(N)!$G(B))
  1.  Q
  1.  ;
  1. OPEN(I,N) ;
  1. OPEN1 ;Open window I
  1.  G FOCUS1
  1.  ;
  1. FOCUS(I,N) ;
  1. FOCUS1 ;Give focus to window I
  1.  ;If N=1; don't paint window
  1.  Q:$D(@DDGLREF@(I))[0
  1.  Q:$G(DDGLSCR(+$G(DDGLSCR)))=I
  1.  ;
  1.  I '$D(DDGLSCR("B",I)) D
  1.  . S DDGLSCR=$G(DDGLSCR)+1,DDGLSCR(DDGLSCR)=I,DDGLSCR("B",I,DDGLSCR)=""
  1.  E  D
  1.  . N M,N
  1.  . S DDGLSCR(DDGLSCR+1)=I
  1.  . S M=$O(DDGLSCR("B",I,""))
  1.  . F N=M:1:DDGLSCR D
  1.  .. K DDGLSCR("B",DDGLSCR(N),N)
  1.  .. S DDGLSCR(N)=DDGLSCR(N+1)
  1.  .. S DDGLSCR("B",DDGLSCR(N),N)=""
  1.  . K DDGLSCR(DDGLSCR+1)
  1.  D:'$G(N) REPAINT^DDGLIBW(I)
  1.  Q
  1.  ;
  1. CLOSE(I,NC) ;
  1. CLOSE1 ;Close window I
  1.  N A,M,N,W
  1.  S M=$O(DDGLSCR("B",I,""))
  1.  Q:M=""
  1.  ;
  1.  I '$G(NC) D
  1.  . S A=$$AREA(I)
  1.  . D CLEAR(I,"0^0^"_$P(A,U,3,4))
  1.  . F N=1:1:DDGLSCR D:N'=M
  1.  .. S W=DDGLSCR(N)
  1.  .. D REPAINT^DDGLIBW(W,$$RELAREA(W,$$INTSECT($$AREA(W),A)))
  1.  ;
  1.  F N=M:1:DDGLSCR-1 D
  1.  . K DDGLSCR("B",DDGLSCR(N),N)
  1.  . S DDGLSCR(N)=DDGLSCR(N+1)
  1.  . S DDGLSCR("B",DDGLSCR(N),N)=""
  1.  K DDGLSCR("B",DDGLSCR(DDGLSCR),DDGLSCR),DDGLSCR(DDGLSCR)
  1.  S DDGLSCR=DDGLSCR-1
  1.  Q
  1.  ;
  1. CLEAR(I,A) ;
  1. CLEAR1 ;Clear area A in window I
  1.  N Y,X,H,W,S,DY,DX
  1.  S:$G(I)="" I=-1 S:$G(A)="" A=$$AREA(I)
  1.  S A=$$ABSAREA(I,A)
  1.  S Y=$P(A,U),X=$P(A,U,2),H=$P(A,U,3),W=$P(A,U,4)
  1.  I Y=0,X=0,H=IOSL,W=IOM W $P(DDGLCLR,DDGLDEL,2) Q
  1.  S DX=X,S=$S(IOM-X=W:$P(DDGLCLR,DDGLDEL),1:$J("",W))
  1.  F DY=Y:1:Y+H-1 X IOXY W S
  1.  Q
  1.  ;
  1. ABSAREA(I,A) ;
  1.  ;Given relative area A in window I, return absolute area
  1.  N X,Y,H,W,X1,Y1
  1.  S Y=$P(A,U),X=$P(A,U,2),H=$P(A,U,3),W=$P(A,U,4)
  1.  S A=$$AREA(I)
  1.  S Y1=Y+$P(A,U),X1=X+$P(A,U,2)
  1.  S:Y1+H>IOSL H=IOSL-Y1 S:X1+W>IOM W=IOM-X1
  1.  Q Y1_U_X1_U_H_U_W
  1.  ;
  1. RELAREA(I,A) ;
  1.  ;Given absolute area A in window I, return relative area
  1.  N X,Y,H,W,X1,Y1
  1.  S Y=$P(A,U),X=$P(A,U,2),H=$P(A,U,3),W=$P(A,U,4)
  1.  S A=$$AREA(I)
  1.  S Y1=Y-$P(A,U),X1=X-$P(A,U,2)
  1.  Q Y1_U_X1_U_H_U_W
  1.  ;
  1. AREA(I) ;Return the coord and area of window I
  1.  Q $S($D(@DDGLREF@(I))#2:@DDGLREF@(I),1:"0^0^"_IOSL_U_IOM)
  1.  ;
  1. INTSECT(A1,A2) ;
  1.  ;Return the intersection of areas 1 and 2
  1.  N A,X1,Y1,H1,W1,X2,Y2,H2,W2
  1.  S Y1=$P(A1,U),X1=$P(A1,U,2),H1=$P(A1,U,3),W1=$P(A1,U,4)
  1.  S Y2=$P(A2,U),X2=$P(A2,U,2),H2=$P(A2,U,3),W2=$P(A2,U,4)
  1.  S A=""
  1.  S $P(A,U)=$$MAX(Y1,Y2),$P(A,U,2)=$$MAX(X1,X2)
  1.  S $P(A,U,3)=$$LEN(Y1,H1,Y2,H2)
  1.  S $P(A,U,4)=$$LEN(X1,W1,X2,W2)
  1.  Q:'$P(A,U,3)!'$P(A,U,4) ""
  1.  Q A
  1.  ;
  1. MAX(X,Y) ;
  1.  ;Return the max of X and Y
  1.  Q $S(X>Y:X,1:Y)
  1.  ;
  1. LEN(C1,L1,C2,L2) ;
  1.  ;Return intersection length of two lines
  1.  ; C = position along X or Y axis
  1.  ; L = length of line
  1.  Q:C1'>C2 $S(C1+L1'<(C2+L2):L2,C1+L1>C2:L1-C2+C1,1:0)
  1.  Q $S(C2+L2'<(C1+L1):L1,C2+L2>C1:L2-C1+C2,1:0)