Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DDMP1

DDMP1.m

Go to the documentation of this file. 
  1. DDMP1 ;SFISC/DPC-ASCII IMPORT UTIILTIES ;9/19/96  14:58
  1.  ;;22.0;VA FileMan;;Mar 30, 1999
  1.  ;Per VHA Directive 10-93-142, this routine should not be modified.
  1. GETFMT(DDMPFMT) ;
  1.  ; Sets up format info.
  1.  ;DDMPFMT passed by reference.
  1.  N DDMPFRMT
  1.  I '($D(DDMPFMT)\10) D  Q:'($D(DDMPFMT)\10)
  1.  . D FIND^DIC(.44,"","1;5;8","X",DDMPFMT,"","","","","DDMPFRMT")
  1.  . I 'DDMPFRMT("DILIST",0) D BLD^DIALOG(1820,DDMPFMT,DDMPFMT) Q
  1.  . S DDMPFMT("IEN")=DDMPFRMT("DILIST",2,1)
  1.  . S DDMPFMT("FDELIM")=DDMPFRMT("DILIST","ID",1,1)
  1.  . S DDMPFMT("FIXED")=DDMPFRMT("DILIST","ID",1,5)
  1.  . S DDMPFMT("QUOTED")=DDMPFRMT("DILIST","ID",1,8)
  1.  S DDMPFMT("FDELIM")=$G(DDMPFMT("FDELIM"))
  1.  I DDMPFMT("FDELIM") D
  1.  . N DDMPI,DDMPPC,DDMPASCI S DDMPASCI=""
  1.  . F DDMPI=1:1 S DDMPPC=$P(DDMPFMT("FDELIM"),",",DDMPI) Q:'DDMPPC  S DDMPASCI=DDMPASCI_$C(DDMPPC)
  1.  . S DDMPFMT("FDELIM")=DDMPASCI
  1.  S DDMPFMT("QUOTED")=$G(DDMPFMT("QUOTED"),"NO")
  1.  S DDMPFMT("FIXED")=$G(DDMPFMT("FIXED"),"NO")
  1.  I ((DDMPFMT("FIXED")="YES")&(DDMPFMT("FDELIM")'=""))!((DDMPFMT("FIXED")'="YES")&(DDMPFMT("FDELIM")="")) D BLD^DIALOG(1821)
  1.  Q
  1.  ;
  1. GETSRC(DDMPFSRC) ;
  1.  ;Moves data from source file into global.
  1.  N DDMPIMWK
  1.  K ^TMP($J,"DDMP")
  1.  S DDMPIMWK=$$FTG^%ZISH(DDMPFSRC("PATH"),DDMPFSRC("FILE"),$NA(^TMP($J,"DDMP",0)),3)
  1.  I 'DDMPIMWK D BLD^DIALOG(1810,DDMPFSRC("FILE"),DDMPFSRC("FILE")) Q
  1.  I '$D(^TMP($J,"DDMP")) D BLD^DIALOG(1812,DDMPFSRC("FILE"),DDMPFSRC("FILE"))
  1.  Q
  1.  ;
  1. RQIDOK(DDMPFLDS) ;
  1.  ;Verifies that required identifiers present in fields being imported.
  1.  N DDMPF,DDMPRIDS,DDMPRID,DDMPERCT S DDMPF=0,DDMPERCT=$G(DIERR)
  1.  F  S DDMPF=$O(DDMPFLDS(DDMPF)) Q:DDMPF=""  D
  1.  . D REQIDS^DICU(DDMPF,"DDMPRIDS")
  1.  . S DDMPRID=0
  1.  . F  S DDMPRID=$O(DDMPRIDS("REQUIRED IDENTIFIERS",DDMPRID)) Q:DDMPRID=""  D
  1.  . . I ";"_DDMPFLDS(DDMPF)_";"'[(";"_DDMPRID_";"),";"_DDMPFLDS(DDMPF)'[(";"_DDMPRID_"[") D
  1.  . . . N DDMPP S DDMPP("FILE")=DDMPF
  1.  . . . D BLD^DIALOG(312,.DDMPP,.DDMPP)
  1.  Q DDMPERCT=$G(DIERR)
  1.  ;
  1. INFILE(DDMPINAR,DDMPFMT,DDMPFBCK,DDMPDR,DDMPNCNT) ;
  1.  N DDMPDELM,DDMPFLDS,DDMPF,DDMPFSTR,DDMPI,DDMPJ,DDMPVAL,DDMPDONE
  1.  S DDMPNCNT=""
  1.  I DDMPFMT("FIXED")="YES" S DDMPDELM=","
  1.  E  S DDMPDELM=DDMPFMT("FDELIM")
  1.  F  S DDMPNCNT=$O(@DDMPINAR@(DDMPNCNT)) Q:DDMPNCNT=""!$G(DDMPDONE)  S DDMPVAL=^(DDMPNCNT) D  Q:$G(DIERR)
  1.  . I DDMPVAL="" Q
  1.  . I '$D(DDMPF) D  Q
  1.  . . S DDMPF=$P(DDMPVAL,"FILE=",2)
  1.  . . I DDMPF="" D BLD^DIALOG(1831) Q
  1.  . . S DDMPF=$$FILENUM(DDMPF)
  1.  . F DDMPI=1:1 S DDMPFSTR=$P(DDMPVAL,DDMPDELM,DDMPI) Q:DDMPFSTR=""  D
  1.  . . N DDMPFDF,DDMPDPTH,DDMPFLD
  1.  . . S DDMPDPTH=$L(DDMPFSTR,":")
  1.  . . S DDMPFDF=DDMPF
  1.  . . F DDMPJ=1:1:DDMPDPTH S DDMPFLD=$P(DDMPFSTR,":",DDMPJ) D  Q:$G(DIERR)
  1.  . . . N DDMP0P2
  1.  . . . D FLDVAL Q:$G(DIERR)
  1.  . . . S $P(DDMPFSTR,":",DDMPJ)=DDMPFLD_U_DDMPFDF
  1.  . . . S DDMPFDF=+DDMP0P2
  1.  . . S DDMPFLDS(DDMPI)=DDMPFSTR
  1.  . S DDMPDONE=1
  1.  I $O(@DDMPINAR@(DDMPNCNT))="" S DDMPNCNT=""
  1.  I $G(DIERR)!(DDMPNCNT="") Q
  1.  S DDMPFLDS=1
  1.  D TODR(DDMPF,.DDMPFLDS,.DDMPDR)
  1.  S DDMPFBCK=DDMPF
  1.  Q
  1.  ;
  1. FILENUM(DDMPF) ;
  1.  I DDMPF,$$VFILE^DILFD(DDMPF) Q DDMPF
  1.  I $D(^DIC("B",DDMPF))=10 Q $O(^(DDMPF,""))
  1.  D BLD^DIALOG(409,DDMPF,DDMPF)
  1.  Q 0
  1. FLDVAL ;
  1.  N DDMP0
  1.  I 'DDMPFLD S DDMPFLD=$$FLDNUM^DILFD(DDMPFDF,DDMPFLD) Q:$G(DIERR)
  1.  S DDMP0=$G(^DD(DDMPFDF,DDMPFLD,0))
  1.  I DDMP0="" D  Q
  1.  . N DDMPP S DDMPP("FILE")=DDMPFDF,DDMPP(1)=DDMPFLD
  1.  . D BLD^DIALOG(501,.DDMPP,.DDMPP)
  1.  S DDMP0P2=$P(DDMP0,U,2)
  1.  I 'DDMP0P2 D
  1.  . I DDMPJ<DDMPDPTH D BLD^DIALOG(1841)
  1.  E  D
  1.  . I DDMPJ=DDMPDPTH D BLD^DIALOG(1842)
  1.  . I $P($G(^DD(+DDMP0P2,.01,0)),U,2)["W" D
  1.  . . N DDMPP
  1.  . . S DDMPP("FILE")=DDMPFDF,DDMPP("FIELD")=DDMPFLD,DDMPP(1)="word processing"
  1.  . . D BLD^DIALOG(520,.DDMPP,.DDMPP)
  1.  I DDMPI>1,$P($P(DDMPFLDS(DDMPI-1),":",DDMPJ-1),U,2)'=$P($P(DDMPFSTR,":",DDMPJ-1),U,2) D
  1.  . D BLD^DIALOG(1844)
  1.  Q
  1.  ;
  1. TMPL2DR(DDMPF,DDMPFLDS) ;
  1.  N DDMPDR
  1.  N DDMPERR S DDMPERR=$G(DIERR)
  1.  D TMPL2SQ(DDMPF,.DDMPFLDS)
  1.  I DDMPERR'=$G(DIERR) Q
  1.  S DDMPFLDS=1
  1.  D TODR(DDMPF,.DDMPFLDS,.DDMPDR)
  1.  K DDMPFLDS
  1.  M DDMPFLDS=DDMPDR
  1.  Q
  1.  ;
  1. TMPL2SQ(DDMPF,DDMPFLSQ) ;
  1.  N DDMPTPNM,DDMPTPNO,DDMPSQ,DDMPPATH
  1.  S DDMPTPNM=$S($E(DDMPFLSQ)="[":$P($P(DDMPFLSQ,"[",2),"]"),1:DDMPFLSQ)
  1.  S DDMPTPNO=$O(^DIST(.46,"F"_DDMPF,DDMPTPNM,""))
  1.  I 'DDMPTPNO D  Q  ;Template does not exist.
  1.  . N DDMPARAM
  1.  . S DDMPARAM(1)=DDMPTPNM,DDMPARAM("FILE")=DDMPF
  1.  . D BLD^DIALOG(1870,.DDMPARAM,.DDMPARAM)
  1.  D LIST^DIC(.463,","_DDMPTPNO_",","1;2;3;10","I")
  1.  I '$D(^TMP("DILIST",$J,0)) Q
  1.  F DDMPSQ=1:1:+^TMP("DILIST",$J,0) D
  1.  . S DDMPPATH=^TMP("DILIST",$J,"ID",DDMPSQ,10)
  1.  . S DDMPFLSQ(DDMPSQ)=$S(DDMPPATH]"":DDMPPATH_":",1:"")_^(2)_U_^(1) ;naked set on prior line.
  1.  . I ^(3) S DDMPFLSQ("LN",DDMPSQ)=^(3) ;naked set 2 lines above.
  1.  K ^TMP("DILIST",$J)
  1.  Q
  1.  ;
  1. TODR(DDMPF,DDMPFLDS,DDMPDR,DDMPDRTP) ;
  1.  N DDMPPPTH,DDMPCPTH,DDMPDPTH,DDMPFDWN,DDMPDONE,DDMPODTH
  1.  F  D  Q:$G(DDMPDONE)!$G(DIERR)
  1.  . I '$D(DDMPFLDS(DDMPFLDS)) D TMP2DR Q
  1.  . I '$D(DDMPDPTH) S DDMPODTH=$L(DDMPFLDS(DDMPFLDS),":")
  1.  . S DDMPDPTH=$L(DDMPFLDS(DDMPFLDS),":")
  1.  . I '$D(DDMPCPTH) S DDMPPPTH=$P(DDMPFLDS(DDMPFLDS),":",1,DDMPDPTH-1)
  1.  . S DDMPCPTH=$P(DDMPFLDS(DDMPFLDS),":",1,DDMPDPTH-1)
  1.  . I DDMPCPTH=DDMPPPTH D
  1.  . . I $G(DDMPDRTP(DDMPF))[(";"_+$P(DDMPFLDS(DDMPFLDS),":",DDMPDPTH)_";") D  Q
  1.  . . . I +$P(DDMPFLDS(DDMPFLDS),":",DDMPDPTH)=$P(DDMPDRTP(DDMPF),";",2),DDMPDPTH>1 D
  1.  . . . . D TMP2DR
  1.  . . . E  D BLD^DIALOG(1845)
  1.  . . S DDMPDRTP(DDMPF)=$G(DDMPDRTP(DDMPF),";")_+$P(DDMPFLDS(DDMPFLDS),":",DDMPDPTH)_$S('$D(DDMPFLDS("LN")):"",1:"["_DDMPFLDS("LN",DDMPFLDS)_"]")_";"
  1.  . . S DDMPFLDS=DDMPFLDS+1
  1.  . . S DDMPPPTH=DDMPCPTH
  1.  . . S DDMPODTH=DDMPDPTH
  1.  . E  I DDMPDPTH'>DDMPODTH D
  1.  . . D TMP2DR
  1.  . E  D
  1.  . . S DDMPDRTP(DDMPF)=DDMPDRTP(DDMPF)_+$P(DDMPFLDS(DDMPFLDS),":",DDMPDPTH-1)_";"
  1.  . . S DDMPFDWN=$P($P(DDMPFLDS(DDMPFLDS),":",DDMPDPTH),U,2)
  1.  . . D TODR(DDMPFDWN,.DDMPFLDS,.DDMPDR,.DDMPDRTP)
  1.  Q
  1.  ;
  1. TMP2DR ;
  1.  S DDMPDONE=1
  1.  I '$D(DDMPDR(DDMPF)) S DDMPDR(DDMPF)=$E(DDMPDRTP(DDMPF),2,$L(DDMPDRTP(DDMPF))-1)
  1.  E  I DDMPDR(DDMPF)'=$E(DDMPDRTP(DDMPF),2,$L(DDMPDRTP(DDMPF))-1) D
  1.  . D BLD^DIALOG(1846,DDMPF,DDMPF)
  1.  K DDMPDRTP(DDMPF)
  1.  Q
  1.  ;