Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DDMPSM

DDMPSM.m

Go to the documentation of this file. 
  1. DDMPSM ;SFISC/DPC-IMPORT SCREENMAN CALLS ;9/20/96  10:07
  1.  ;;22.0;VA FileMan;;Mar 30, 1999
  1.  ;Per VHA Directive 10-93-142, this routine should not be modified.
  1. FILESEL ;
  1.  ; Called form Post-actin on change of Primary File prompt
  1.  D PUT^DDSVALF("TMP_NM",1,1,"")
  1.  I DDSOLD'="",$D(DDMPFDSL) S DDMPOLDF=DDSOLD,DDSBR="3^1^3"
  1.  E  D
  1.  . K DDMPCPNM,DDMPCPTH,DDMPFCAP,DDMPCF,DDMPFDNM
  1.  . S DDMPF=X
  1.  . S DDMPFLNM=DDSEXT
  1.  . D UNED^DDSUTL("FLD_JUMP",1,1,$S(X:0,1:1))
  1.  . D UNED^DDSUTL("TMP_NM",1,1,$S(X:0,1:1))
  1.  . D REFRESH^DDSUTL
  1.  Q
  1.  ;
  1. TMPLSCR(DDMPSELF,DDSEXT,DUZ) ;
  1.  ;called from TMP_NM field.
  1.  ;DDMPSELF = currently selected primary file.
  1.  ;DDMPEXT  = External value of selected template.
  1.  I $P(^(0),U,4)'=DDMPSELF Q 0
  1.  I DUZ(0)["@" Q 1
  1.  N DDMPRDAC,DDMPI,DDMPOK
  1.  S DDMPRDAC=$P(^(0),U,3),DDMPOK=0
  1.  F DDMPI=1:1:$L(DDMPRDAC) I DUZ(0)[$E(DDMPRDAC,DDMPI) S DDMPOK=1 Q
  1.  Q DDMPOK
  1.  ;
  1. CHNGFILE ;
  1.  ;Called for Post-action on pop-up file change verification page.
  1.  I X D  ;code for changing selected file.
  1.  . K DDMPFDSL,DDMPCPNM,DDMPCPTH,DDMPFCAP,DDMPCF,DDMPFDNM
  1.  . S (DDMPOSET,DDMPFDCT)=0
  1.  . S DDMPF=$$GET^DDSVALF("F_SEL",1,1)
  1.  . S DDMPFLNM=$$GET^DDSVALF("F_SEL",1,1,"E")
  1.  . I DDMPF="" D UNED^DDSUTL("FLD_JUMP",1,1,1),UNED^DDSUTL("TMP_NM",1,1,1)
  1.  . S DDSBR="FLD_JUMP^1^1"
  1.  . ;D REFRESH^DDSUTL
  1.  E  D
  1.  . D PUT^DDSVALF("F_SEL",1,1,DDMPOLDF,"I")
  1.  . S DDSBR="F_SEL^1^1"
  1.  Q
  1.  ;
  1. IXF ;
  1.  ;Called from input transform of Field Selection field.
  1.  N D0,DA,DIC,DP,Y S DIC="^DD("_DDMPCF_",",DIC(0)="ENZ" D ^DIC
  1.  I Y'>0 K X
  1.  E  S (X,DDMPX)=+$P(Y,"E"),DDMPFDNM=Y(0,0)
  1.  Q
  1.  ;
  1. FDPROC ;
  1.  ;Called from post-action on change of Field Selection prompt.
  1.  N DDMP0P2
  1.  S DDMP0P2=$P(^DD(DDMPCF,DDMPX,0),U,2)
  1.  I +DDMP0P2 D
  1.  . S DDSBR="FLD"
  1.  . I 'DDMPFDCT D HLP^DDSUTL($C(7)_"You must select a field in the top level file before entering multiple.") Q
  1.  . N DDMPI,DDMPOK
  1.  . F DDMPI=1:1:DDMPFDCT I $P(DDMPFDSL(DDMPI),U,$L(DDMPFDSL(DDMPI),U))=DDMPCF S DDMPOK=1 Q
  1.  . I '$G(DDMPOK) D HLP^DDSUTL($C(7)_"You must select a field in a subfile before entering one of its multiples.") Q
  1.  . S DDMPFCAP=$$PATHNM(+DDMP0P2,DDMPFLNM)
  1.  . S DDMPCPTH=$S($L($G(DDMPCPTH)):DDMPCPTH_":",1:"")_DDMPX_U_DDMPCF
  1.  . S DDMPCF=+DDMP0P2
  1.  . S DDMPCPNM=$S($L($G(DDMPCPNM)):DDMPCPNM_":",1:"")_DDMPFDNM
  1.  E  D
  1.  . S DDMPFDCT=DDMPFDCT+1
  1.  . S DDMPFDSL(DDMPFDCT)=$S($L($G(DDMPCPTH)):DDMPCPTH_":",1:"")_DDMPX_U_DDMPCF
  1.  . S DDMPFDSL("CAP",DDMPFDCT)=$S($L($G(DDMPCPNM)):DDMPCPNM_":",1:"")_DDMPFDNM
  1.  . S DDMPOSET=$S(DDMPFDCT>9:DDMPFDCT-9,1:0)
  1.  . S DDSBR=$S($G(DDMPSMFF("FIXED"))="YES":"LEN",1:"FLD")
  1.  Q
  1.  ;
  1. PATHNM(DDMPSFNO,DDMPFLNM) ;
  1.  N DDMPPATH S DDMPPATH=""
  1.  I $D(^DD(DDMPSFNO,0,"UP")) F  D  Q:'$D(^DD(DDMPSFNO,0,"UP"))
  1.  . S DDMPPATH=" : "_$P($P(^DD(DDMPSFNO,0),U),"SUB-FIELD")_"Subfile"_DDMPPATH
  1.  . S DDMPSFNO=^DD(DDMPSFNO,0,"UP")
  1.  Q $G(DDMPFLNM,$P(^DIC(DDMPSFNO,0),U))_DDMPPATH
  1.  ;
  1. UP1 ;
  1.  ;Called from post-action on Field Selection prompt if null entered.
  1.  S DDMPFCAP=$P($G(DDMPFCAP)," : ",1,$L($G(DDMPFCAP)," : ")-1)
  1.  S DDMPCF=$P(DDMPCPTH,U,$L(DDMPCPTH,U))
  1.  S DDMPCPTH=$P(DDMPCPTH,":",1,$L(DDMPCPTH,":")-1)
  1.  S DDMPCPNM=$P(DDMPCPNM,":",1,$L(DDMPCPNM,":")-1)
  1.  Q
  1.  ;
  1. DELFLD ;
  1.  ;Called from post-action on change of the "Do you want to delete" prompt
  1.  I DDMPFDCT=0 Q
  1.  N DDMPL S DDMPL=$L($G(DDMPFDSL(DDMPFDCT-1)),":")
  1.  I DDMPL=1 D
  1.  . S DDMPCF=DDMPF
  1.  . S DDMPFCAP=DDMPFLNM
  1.  . S (DDMPCPNM,DDMPCPTH)=""
  1.  E  D
  1.  . S DDMPCF=$P(DDMPFDSL(DDMPFDCT-1),U,$L(DDMPFDSL(DDMPFDCT-1),U))
  1.  . S DDMPFCAP=$$PATHNM(+DDMPCF,DDMPFLNM)
  1.  . S DDMPCPTH=$P(DDMPFDSL(DDMPFDCT-1),":",1,DDMPL-1)
  1.  . S DDMPCPNM=$P(DDMPFDSL("CAP",DDMPFDCT-1),":",1,DDMPL-1)
  1.  K DDMPFDSL(DDMPFDCT),DDMPFDSL("CAP",DDMPFDCT),DDMPFDSL("LN",DDMPFDCT)
  1.  S DDMPFDCT=DDMPFDCT-1
  1.  I DDMPOSET S DDMPOSET=DDMPOSET-1
  1.  Q
  1.  ;
  1.  ;
  1. VAL ;
  1.  ;Called from form level validation.
  1.  N DDMPMSG
  1.  ;1)Validate format of import.
  1.  I (($G(DDMPSMFF("FIXED"))="YES")&($G(DDMPSMFF("FDELIM"))'=""))!(($G(DDMPSMFF("FIXED"))'="YES")&($G(DDMPSMFF("FDELIM"))="")) D  G VALERR
  1.  . D BLD^DIALOG(1821)
  1.  . S DDSERROR=2
  1.  . S DDSBR="FOR_FMT^1^1"
  1.  . D MSG^DIALOG("AE",.DDMPMSG)
  1.  ;
  1.  ;2) If file specified, move fields selected into DR().  Look for DIERRs created during move.
  1.  I $G(DDMPF)]"" D
  1.  . I $$GET^DDSVALF("TMP_NM",1,1)]"" D
  1.  . . S DDMPFDSL=$$GET^DDSVALF("TMP_NM",1,1,"E")
  1.  . . D TMPL2SQ^DDMP1(DDMPF,.DDMPFDSL)
  1.  . I '$D(DDMPFDSL(1)) D  Q
  1.  . . S DDSERROR=$G(DDSERROR)+1
  1.  . . S DDMPMSG(DDSERROR)="You must specify some fields into which to import data."
  1.  . . S DDSBR="FLD_JUMP^1^1"
  1.  . K DDMPDR
  1.  . S DDMPFDSL=1
  1.  . N DDMPDIER S DDMPDIER=$G(DIERR)
  1.  . D TODR^DDMP1(DDMPF,.DDMPFDSL,.DDMPDR)
  1.  . I $G(DIERR)>DDMPDIER D
  1.  . . S DDSERROR=$G(DDSERROR)+DIERR
  1.  . . D MSG^DIALOG("AE",.DDMPMSG)
  1.  . . S DDSBR="2.2^1^2"
  1.  . . K DDMPDR
  1.  ;
  1. VALERR I $G(DDSERROR) D MSG^DDSUTL(.DDMPMSG) Q
  1.  Q
  1.  ;
  1. FF ;
  1.  ;Called from post-action on change of the Foreign Format field.
  1.  N DDMPI
  1.  I X'="" D
  1.  . S DDMPSMFF=DDSEXT
  1.  . S DDMPSMFF("IEN")=X
  1.  . S DDMPSMFF("FDELIM")=$$GET1^DIQ(.44,X_",",1)
  1.  . S DDMPSMFF("FIXED")=$$GET1^DIQ(.44,X_",",5)
  1.  . S DDMPSMFF("QUOTED")=$$GET1^DIQ(.44,X_",",8)
  1.  . F DDMPI="FIX","FLD_DLM","QUOTE" D
  1.  . . D PUT^DDSVALF(DDMPI,1,1,"")
  1.  . . D UNED^DDSUTL(DDMPI,1,1,1)
  1.  E  D
  1.  . K DDMPSMFF
  1.  . F DDMPI="FIX","FLD_DLM","QUOTE" D UNED^DDSUTL(DDMPI,1,1,0)
  1.  Q