Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DDSR

DDSR.m

Go to the documentation of this file. 
  1. DDSR ;SFISC/MKO-PAINT ;3:11 PM  11 Jun 1996
  1.  ;;22.0;VA FileMan;;Mar 30, 1999
  1.  ;Per VHA Directive 10-93-142, this routine should not be modified.
  1. R ;All pages
  1.  ;Called after wp, mults, & deletions
  1.  F DDSSC=1:1:DDSSC D RP(DDSSC(DDSSC),DDSSC=1)
  1.  Q
  1.  ;
  1. RP(X,DDS3LIN) ;Paint page
  1.  ; X       = DDSSC(DDSSC) node
  1.  ; DDS3LIN = paint bottom line
  1.  ;
  1.  S DDS3P=$P(X,U),DDS3UL=$P(X,U,2),DDS3LR=$P(X,U,3)
  1.  I DDS3UL="" W $P(DDGLCLR,DDGLDEL,2)
  1.  E  D ^DDSBOX(DDS3UL,DDS3LR)
  1.  ;
  1.  ;Write caps in "X" nodes
  1.  D CAP^DDSR1
  1.  ;
  1.  ;Paint data & exec caps
  1.  ;Hdr blk
  1.  S DDS3B=$P($G(^DIST(.403,+DDS,40,DDS3P,0)),U,2)
  1.  D:DDS3B]"" DB(DDS3P,DDS3B)
  1.  ;
  1.  ;Other blks
  1.  S DDS3BO="" F  S DDS3BO=$O(^DIST(.403,+DDS,40,DDS3P,40,"AC",DDS3BO)) Q:'DDS3BO  S DDS3B=$O(^(DDS3BO,"")) Q:'DDS3B  D DB(DDS3P,DDS3B)
  1.  K DDS3B,DDS3BO
  1.  ;
  1.  I DDS3LIN D
  1.  . S DDSH=1,DX=0,DY=DDSHBX X IOXY W $TR($J("",IOM-1)," ","_")
  1.  . I DDS3UL]"" S DY=DY+1 X IOXY W $P(DDGLCLR,DDGLDEL,3)
  1.  K DDS3P,DDS3UL,DDS3LR
  1.  Q
  1.  ;
  1. DB(DDS3P,DDS3B) ;Paint data
  1.  K @DDSREFT@("XCAP",DDS3P,DDS3B)
  1.  S DDS3=@DDSREFS@(DDS3P,DDS3B)
  1.  S DDS3FN="F"_$P(DDS3,U,3),DDS3REP=$P(DDS3,U,7),DDS3PTB=$P(DDS3,U,8)
  1.  K DDS3
  1.  ;
  1.  I $G(DDS3REP)'>1 D
  1.  . N DIE
  1.  . S DDS3DA=$G(@DDSREFT@(DDS3P,DDS3B))
  1.  . S:DDS3DA]"" DIE=$G(@DDSREFT@(DDS3P,DDS3B,DDS3DA,"GL"))
  1.  . S DDS3DDO=0
  1.  . F  S DDS3DDO=$O(@DDSREFS@(DDS3P,DDS3B,DDS3DDO)) Q:DDS3DDO'=+DDS3DDO  S DDS3C=$G(^(DDS3DDO,"D")) D:DDS3C]"" DF(DDS3P,DDS3B,DDS3DDO,DDS3DA,DDS3C,DDS3FN,DDS3PTB)
  1.  . K DDS3C,DDS3DA,DDS3DDO
  1.  E  D DMULT(DDS3P,DDS3B,DDS3FN)
  1.  ;
  1.  K DDS3FN,DDS3PTB,DDS3REP
  1.  Q
  1.  ;
  1. DMULT(DDS3P,DDS3B,DDS3FN) ;Paint data, all lines
  1.  N X,DIE
  1.  S DDS3PDA=$P($G(@DDSREFT@(DDS3P,DDS3B)),U)
  1.  I 'DDS3PDA D
  1.  . S X="",DDS3STL=1
  1.  . S DDS3NREP=$P(@DDSREFS@(DDS3P,DDS3B),U,7),DDS3SEL=$P(^(DDS3B),U,10)
  1.  E  D
  1.  . S X=@DDSREFT@(DDS3P,DDS3B,DDS3PDA)
  1.  . S DDS3STL=$P(X,U,3),DDS3NREP=$P(X,U,6),DDS3SEL=$P(X,U,9)
  1.  S DIE=$G(@DDSREFT@(DDS3P,DDS3B,DDS3PDA,"GL"))
  1.  ;
  1.  F DDS3LN=1:1:DDS3NREP D
  1.  . S DDS3SN=DDS3LN+DDS3STL-1
  1.  . S DDS3DA=$G(@DDSREFT@(DDS3P,DDS3B,DDS3PDA,DDS3SN))
  1.  . S:DDS3LN=1 DDS3MORE=$S(DDS3STL>1:"+",1:" ")
  1.  . S:DDS3LN=DDS3REP DDS3MORE=$S($D(@DDSREFT@(DDS3P,DDS3B,DDS3PDA,DDS3SN+1))#2:"+",1:" ")
  1.  . D DMULT1(DDS3P,DDS3B,DDS3FN,DDS3DA,DDS3LN,DDS3SN,$G(DDS3MORE),DDS3SEL)
  1.  . K DDS3MORE
  1.  ;
  1.  K DDS3DA,DDS3LN,DDS3NREP,DDS3PDA,DDS3SEL,DDS3SN,DDS3STL
  1.  Q
  1.  ;
  1. DMULTN(DDS3P,DDS3B,DDS3PDA,DDS3REP,DDS3LN) ;Paint lines from DDS3LN
  1.  S DDS3FN="F"_$P(@DDSREFS@(DDS3P,DDS3B),U,3)
  1.  S DDS3STL=$P(@DDSREFT@(DDS3P,DDS3B,DDS3PDA),U,3),DDS3SEL=$P(^(DDS3PDA),U,9)
  1.  F DDS3LN=DDS3LN:1:DDS3REP D
  1.  . S DDS3SN=DDS3LN+DDS3STL-1
  1.  . S DDS3DA=$G(@DDSREFT@(DDS3P,DDS3B,DDS3PDA,DDS3SN))
  1.  . S:DDS3LN=1 DDS3MORE=$S(DDS3STL>1:"+",1:" ")
  1.  . S:DDS3LN=DDS3REP DDS3MORE=$S($D(@DDSREFT@(DDS3P,DDS3B,DDS3PDA,DDS3SN+1))#2:"+",1:" ")
  1.  . D DMULT1(DDS3P,DDS3B,DDS3FN,DDS3DA,DDS3LN,DDS3SN,$G(DDS3MORE),DDS3SEL)
  1.  . K DDS3MORE
  1.  K DDS3DA,DDS3FN,DDS3LN,DDS3SEL,DDS3SN,DDS3STL
  1.  Q
  1.  ;
  1. DMULT1(DDS3P,DDS3B,DDS3FN,DDS3DA,DDS3LN,DDS3SN,DDS3MORE,DDS3SEL) ;Paint 1 line
  1.  S DDS3DDO=0
  1.  F  S DDS3DDO=$O(@DDSREFS@(DDS3P,DDS3B,DDS3DDO)) Q:DDS3DDO'=+DDS3DDO  S DDS3C=$G(^(DDS3DDO,"D")) I DDS3C]"" D
  1.  . S $P(DDS3C,U)=$P(DDS3C,U)+DDS3LN-1
  1.  . S:$P(DDS3C,U,5)]"" $P(DDS3C,U,5)=$P(DDS3C,U,5)+DDS3LN-1
  1.  . I $D(DDS3MORE),DDS3SEL=DDS3DDO,$P(DDS3C,U) D
  1.  .. S DY=+DDS3C,DX=$P(DDS3C,U,2)-1 Q:DX<0
  1.  .. X IOXY W DDS3MORE
  1.  . D DF(DDS3P,DDS3B,DDS3DDO,DDS3DA,DDS3C,DDS3FN,1,DDS3LN,DDS3SN)
  1.  K DDS3C,DDS3DDO
  1.  Q
  1.  ;
  1. DF(DDS3P,DDS3B,DDS3DDO,DDS3DA,DDS3C,DDS3FN,DDS3FLG,DDS3LN,DDS3SN) ;
  1.  ;Paint field
  1.  N DDS3FLD,DDS3LEN,DDSX
  1.  D:$P(DDS3C,U,5)]"" XCAP
  1.  ;
  1.  S DY=+DDS3C,DX=$P(DDS3C,U,2)
  1.  S DDS3LEN=$P(DDS3C,U,3),DDS3FLD=$P(DDS3C,U,4)
  1.  ;
  1.  ;Computed flds
  1.  I DDS3DA]"",$P(DDS3C,U,9) S DDSX=$$VAL^DDSCOMP(DDS3DDO,DDS3B,DDS3DA)
  1.  ;
  1.  ;Form only flds
  1.  Q:DDS3FLD=""
  1.  I DDS3FLD'=+DDS3FLD N DDS3FN S DDS3FN="F0"
  1.  ;
  1.  ;External form
  1.  S:DDS3FLD DDSX=$S(DDS3DA="":"",$D(@DDSREFT@(DDS3FN,DDS3DA,DDS3FLD,"X"))#2:^("X"),1:$G(^("D")))
  1.  I $G(DDSX)]""!$G(DDS3FLG) D
  1.  . S:$D(DDSX)[0 DDSX=""
  1.  . X IOXY
  1.  . I '$P(DDS3C,U,10) S DDSX=$E(DDSX,1,DDS3LEN)_$J("",DDS3LEN-$L(DDSX))
  1.  . E  S DDSX=$J("",DDS3LEN-$L(DDSX))_$E(DDSX,1,DDS3LEN)
  1.  . W $P(DDGLVID,DDGLDEL)_DDSX_$P(DDGLVID,DDGLDEL,10)
  1.  Q
  1.  ;
  1. XCAP ;Paint exec caps
  1.  N Y,DDSLN,DDSSN
  1.  I 'DDS3DA N DA,D0 S (DA,D0)=""
  1.  ;
  1.  I DDS3DA N DDSDL S DDSDL=$L(DDS3DA,",")-2
  1.  I  N DA,@$$D0^DDS(DDSDL)
  1.  I  D BLDDA^DDS(DDS3DA)
  1.  ;
  1.  S DDS3TP=$P($G(@DDSREFS@(DDS3P,DDS3B)),U,5)
  1.  S DDS3L0=$G(^DIST(.404,DDS3B,40,DDS3DDO,0)) G:DDS3L0?."^" XCAPQ
  1.  S DDS3L01=$G(^DIST(.404,DDS3B,40,DDS3DDO,.1)) G:DDS3L01?."^" XCAPQ
  1.  ;
  1.  S:$D(DDS3LN) DDSLN=DDS3LN
  1.  S:$D(DDS3SN) DDSSN=DDS3SN
  1.  ;
  1.  X DDS3L01 G:$G(Y)="" XCAPQ
  1.  S DDS3CAP=Y
  1.  ;
  1.  I DDS3TP="e","^2^3^"[(U_$P(DDS3L0,U,3)_U)!'$P(DDS3L0,U,3) D
  1.  . S Y=$TR(Y,"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ")
  1.  . S @DDSREFT@("XCAP",DDS3P,Y,DDS3B,DDS3DDO)=""
  1.  ;
  1.  S DY=$P(DDS3C,U,5),DX=$P(DDS3C,U,6)
  1.  S DDS3CAP=DDS3CAP_$P(DDS3C,U,7)
  1.  S:$P(DDS3C,U,8) DDS3CAP=$P(DDGLVID,DDGLDEL,4)_DDS3CAP_$P(DDGLVID,DDGLDEL,10)
  1.  X IOXY W DDS3CAP
  1. XCAPQ K DDS3CAP,DDS3L0,DDS3L01,DDS3TP
  1.  Q