Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DDSZ1

DDSZ1.m

Go to the documentation of this file. 
  1. DDSZ1 ;SFISC/MKO-GET BLOCK INFO,SCREEN IMAGE ;9:59 AM  15 Jul 1997
  1.  ;;22.0;VA FileMan;;Mar 30, 1999
  1.  ;Per VHA Directive 10-93-142, this routine should not be modified.
  1. EN(DDSPG,DDSBK,DDP,DDSBY,DDSBX,DDSBO,DDSTP,DDSREP,DDSNDD,DDSPGRP,DDSSCR,DDSNAV,DDSORD,DDSRNAV) ;
  1.  ;Input:
  1.  ;  DDSREFS = Global ref
  1.  ;Output:
  1.  ;  DDSSCR
  1.  ;  DDSNAV
  1.  ;  DDSORD
  1.  ;  DDSRNAV
  1.  ;
  1.  N Y
  1.  S:$G(DDSTP)="" DDSTP="e"
  1.  I DDSTP'="h",$G(DDSBO),$D(DDSORD(DDSBO))[0 D
  1.  . S DDSORD(DDSBO)=DDSBK
  1.  . S:$G(DDSREP)>1 $P(DDSORD(DDSBO),U,2)=$S($P(DDSREP,U,5)]"":$P($$GETFLD^DDSLIB($P(DDSREP,U,5),"","","","",DDSBK),","),1:"FIRST")
  1.  ;
  1.  S DDSF=0
  1.  F  S DDSF=$O(^DIST(.404,DDSBK,40,DDSF)) Q:DDSF'=+DDSF  D FLD
  1.  ;
  1. KILL K DDSC1,DDSC2,DDSCAP,DDSCLN,DDSD1,DDSD2,DDSD3
  1.  K DDSDDL0,DDSF,DDSFLD,DDSKEY,DDSL0,DDSL01,DDSL2,DDSL4,DDSN
  1.  Q
  1.  ;
  1. FLD ;Set up
  1.  ;  @DDSREFS@(pg,bk,ddo,
  1.  ;    "D")       = data $Y^data $X^data $L^field#
  1.  ;                  ^xcap $Y^xcap $X^xcap colon^xcap req
  1.  ;                  ^1 if computed field^1 if right justified
  1.  ;    "COMPE")   = M code that sets X
  1.  ;    "COMPE",1) = array sets DDSE(n)
  1.  ;
  1.  ;  @DDSREFS@("Ffile#",field#,"L",pg,bk,ddo)=""
  1.  ;
  1.  ;  DDSSCR(row)     = captions on that row
  1.  ;  DDSSCR(row,col) = final columns underlined
  1.  ;  DDSNAV(row,col) = ddo,bk for editable fields
  1.  ;  DDSORD(bo,fo)   = ddo for editable fields
  1.  ;
  1.  ;Get field properties
  1.  S:'$P(^DIST(.404,DDSBK,40,DDSF,0),U,3) $P(^(0),U,3)=3
  1.  S DDSL0=$G(^DIST(.404,DDSBK,40,DDSF,0)),DDSL01=$G(^(.1)),DDSFLD=$S($P(DDSL0,U,3)=2:DDSF_","_DDSBK,1:+$G(^(1))),DDSL2=$G(^(2)),DDSL4=$G(^(4))
  1.  K:$P(DDSL0,U,3)=3!'$P(DDSL0,U,3) DDSNDD
  1.  S DDSDDL0=$G(^DD(DDP,DDSFLD,0)) Q:DDSL0?."^"!(DDSL2?."^")
  1.  S DDSKEY=DDSFLD'[","&($D(^DD("KEY","F",DDP,DDSFLD))>1)
  1.  S DDSD1=$P($P(DDSL2,U),",")+DDSBY-1
  1.  S DDSD2=$P($P(DDSL2,U),",",2)+DDSBX-1
  1.  S DDSD3=$P(DDSL2,U,2)
  1.  S DDSC1=$P($P(DDSL2,U,3),",")+DDSBY-1
  1.  S DDSC2=$P($P(DDSL2,U,3),",",2)+DDSBX-1
  1.  S DDSCAP=$TR($P(DDSL0,U,2)," ",$C(0))
  1.  S DDSCLN=$S(DDSCAP="":"",$P(DDSL0,U,3)=1:"",$P(DDSL2,U,4):"",1:":")
  1.  ;
  1.  I DDSC1'<0,DDSC2'<0,$L(DDSCAP)>0,DDSCAP'="!M" D
  1.  . ;Set CAP xref for ^-jumping
  1.  . I DDSTP="e","^2^3^"[(U_$P(DDSL0,U,3)_U)!'$P(DDSL0,U,3) D
  1.  .. N C,I,L
  1.  .. S I=0 F  S I=$O(DDSPGRP(I)) Q:'I  Q:U_DDSPGRP(I)_U[(U_DDSPG_U)
  1.  .. Q:'I
  1.  .. S C=$P(DDSL0,U,2)
  1.  .. S:C?1"Select ".E C=$P(C,"Select ",2,999)
  1.  .. S C=$E($TR(C,"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ"),1,40)
  1.  .. S L=$L(DDSREFS)+$L(C)+$L(DDSPGRP(I))+$L(DDSPG)+$L(DDSBK)+$L(DDSF)+30
  1.  .. S:L>127 C=$E(C,1,$L(C)-(L-127))
  1.  .. S:C]"" @DDSREFS@("CAP",C,DDSPGRP(I),DDSPG,DDSBK,DDSF)=""
  1.  . ;
  1.  . ;Set DDSSCR
  1.  . I DDSC1'<0,DDSC2'<0,$L(DDSCAP)>0,DDSCAP'="!M" D
  1.  .. N DDSI,DDSX
  1.  .. S DDSX=DDSCAP_DDSCLN
  1.  .. F DDSI=1:1:+DDSREP D
  1.  ... S $E(DDSSCR(DDSC1+DDSI),DDSC2+1,DDSC2+$L(DDSX))=DDSX
  1.  ... S:$S($P(DDSL4,U)]"":+DDSL4,1:$P(DDSDDL0,U,2)["R")!DDSKEY DDSSCR(DDSC1+DDSI,DDSC2+1)=DDSC2+$L(DDSCAP)
  1.  ;
  1.  ;Set "D", "L" nodes, DDSNAV, and DDSORD
  1.  I DDSD1'<0,DDSD2'<0,DDSD3>0 D
  1.  . S @DDSREFS@(DDSPG,DDSBK,DDSF,"D")=DDSD1_U_DDSD2_U_DDSD3_U_DDSFLD
  1.  . S @DDSREFS@("F"_$S(DDSFLD[",":0,1:DDP),DDSFLD,"L",DDSPG,DDSBK,DDSF)=""
  1.  I DDSCAP="!M",DDSC1'<0,DDSC2'<0 S $P(@DDSREFS@(DDSPG,DDSBK,DDSF,"D"),U,5,8)=DDSC1_U_DDSC2_U_DDSCLN_U_($P(DDSDDL0,U,2)["R"!+DDSL4!DDSKEY)
  1.  S:$P(DDSL4,U,3) $P(@DDSREFS@(DDSPG,DDSBK,DDSF,"D"),U,10)=1
  1.  ;
  1.  ;Computed fields
  1.  I $P(DDSL0,U,3)=4 D  K DDSCOMP,DDSAR,DDSEXP,DDSFD Q
  1.  . S DDSCOMP=$G(^DIST(.404,DDSBK,40,DDSF,30)) Q:DDSCOMP?."^"
  1.  . D PARSE^DDSCOMP(DDP,DDSCOMP,DDSBK,.DDSEXP,.DDSAR,.DDSFD)
  1.  . Q:DDSEXP=""!$G(DIERR)
  1.  . S @DDSREFS@("COMPE",DDSBK,DDSF)=DDSEXP
  1.  . F DDSAR=1:1:DDSAR D
  1.  .. S:DDSAR(DDSAR)["*DDSREFC*" DDSAR(DDSAR)=$P(DDSAR(DDSAR),"*DDSREFC*")_$E(DDSREFS,1,$L(DDSREFS)-1)_",""COMPE"","_DDSBK_","_DDSF_","_DDSAR_$P(DDSAR(DDSAR),"*DDSREFC*",2,999)
  1.  .. S @DDSREFS@("COMPE",DDSBK,DDSF,DDSAR)=DDSAR(DDSAR)
  1.  .. I $D(DDSAR(DDSAR))>9 N I F I=1:1 Q:$D(DDSAR(DDSAR,I))[0  D
  1.  ... S @DDSREFS@("COMPE",DDSBK,DDSF,DDSAR,I)=DDSAR(DDSAR,I)
  1.  . S $P(@DDSREFS@(DDSPG,DDSBK,DDSF,"D"),U,9)=1
  1.  . I $G(DDSFD)]"" F DDSAR=1:1:$L(DDSFD,U) D
  1.  .. N F S F=$P(DDSFD,U,DDSAR) Q:F=""
  1.  .. S @DDSREFS@("COMP",$P(F,","),$P($P(F,",",2,99),";"),DDSPG,DDSBK,DDSF)=""
  1.  ;
  1.  Q:DDSD1<0!(DDSD2<0)!(DDSD3'>0)!(DDSL2?."^")
  1.  Q:$P(DDSDDL0,U,4)=" ; "  Q:DDSTP="h"  Q:DDSFLD=.001
  1.  I '$P(DDSDDL0,U,2),DDSTP'="e" Q
  1.  ;
  1.  S DDSORD(DDSBO,+DDSL0)=DDSF
  1.  S DDSNAV(DDSD1,DDSD2)=DDSF_","_DDSBK
  1.  S:$P(DDSDDL0,U,2) DDSMUL(DDSBK,DDSF)=""
  1.  ;
  1.  I $G(DDSREP)>1 D
  1.  . S $P(DDSNAV(DDSD1,DDSD2),",",3)=DDSBO
  1.  . S DDSRNAV(DDSBO,DDSD1)=DDSBK
  1.  . S DDSRNAV(DDSBO,DDSD1,DDSD2)=DDSF
  1.  . S DDSRNAV(DDSBO,DDSD1-1,DDSD2)=DDSF_",-1"
  1.  . S DDSRNAV(DDSBO,DDSD1+1,DDSD2)=DDSF_",+1"
  1.  Q