Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DG53653U

DG53653U.m

Go to the documentation of this file. 
  1. DG53653U ;TDM - Patch DG*5.3*653 Install Utility Routine ; 11/28/05 4:58pm
  1.  ;;5.3;Registration;**653,1015**;AUG 13, 1993;Build 21
  1.  Q
  1.  ;
  1. EP ; Add new entries to the INCONSISTENT DATA ELEMENTS file (#38.6)
  1.  N BRNG,ERNG,DGKRTN,KEYREQ
  1.  D ADDINC(301,312,"DG53653V",0) Q:$G(XPDABORT)=2
  1.  D ADDINC(401,413,"DG53653W",0) Q:$G(XPDABORT)=2
  1.  D ADDINC(501,517,"DG53653X",0) Q:$G(XPDABORT)=2
  1.  D ADDINC(701,726,"DG53653Y",0) Q:$G(XPDABORT)=2
  1.  Q
  1.  ;
  1. ADDINC(BRNG,ERNG,DGKRTN,KEYREQ) ; add new entries to the INCONSISTENT DATA ELEMENTS file (#38.6)
  1.  ;-----------------------------------------------------------------
  1.  ; Input:    BRNG = Beginning Number
  1.  ;           ERNG = Ending Number
  1.  ;         DGKRTN = Routine Name for the Range
  1.  ;         KEYREQ = Key Required
  1.  ;                    0=No Key Required
  1.  ;                    1=Eligibility Verified
  1.  ;                    2=Money Verified
  1.  ;                    3=Service Verified
  1.  ;                    4=Key Always Required
  1.  ;-----------------------------------------------------------------
  1.  N DGK,DGKSUB,DGWP,ROOT,DGFDA,DGWP,DGERR,DGIEN,DGTITL
  1.  K XPDABORT
  1.  D BMES^XPDUTL("  >> Adding entries "_BRNG_"-"_ERNG_" into the INCONSISTENT DATA ELEMENTS file (#38.6)")
  1.  F DGK=BRNG:1:ERNG Q:$G(XPDABORT)=2  D
  1.  .I $D(^DGIN(38.6,DGK)) D  Q
  1.  ..D BMES^XPDUTL("     Internal Entry # "_DGK_" already exists in file #38.6")
  1.  ..S ROOT="DGFDA(38.6,"""_DGK_","")" S DGKSUB=DGK_U_DGKRTN D @DGKSUB
  1.  ..I $P($G(^DGIN(38.6,DGK,0)),"^")=$G(@ROOT@(.01)) D MES^XPDUTL("Entry "_DGK_" matches incoming entry - OK") Q
  1.  ..D MES^XPDUTL("     >>> ERROR: Entry # "_DGK_" needs to be reviewed by NVS! <<<")
  1.  ..D MES^XPDUTL("           Existing entry: "_$P($G(^DGIN(38.6,DGK,0)),"^"))
  1.  ..D MES^XPDUTL("           Incoming entry: "_$G(@ROOT@(.01)))
  1.  ..D BMES^XPDUTL("                        <<<< INSTALLATION ABORTED >>>>")
  1.  ..S XPDABORT=2
  1.  .K DGFDA,ROOT,DGWP
  1.  .S ROOT="DGFDA(38.6,""?+1,"")"
  1.  .S DGKSUB=DGK_U_DGKRTN D @DGKSUB Q:'$D(DGFDA)
  1.  .S DGIEN(1)=DGK,DGTITL=@ROOT@(.01),@ROOT@(3)=KEYREQ,@ROOT@(4)=0,@ROOT@(5)=0,@ROOT@(6)=1,@ROOT@(50)="DGWP"
  1.  .D UPDATE^DIE("","DGFDA","DGIEN","DGERR")
  1.  .I $D(DGERR) D  Q
  1.  ..D BMES^XPDUTL("   >>> ERROR! "_DGTITL_" not added to file #38.6")
  1.  ..D MES^XPDUTL("     "_DGERR("DIERR",1)_": "_DGERR("DIERR",1,"TEXT",1))
  1.  ..D BMES^XPDUTL("                        <<<< INSTALLATION ABORTED >>>>")
  1.  ..S XPDABORT=2
  1.  .D BMES^XPDUTL("      "_DGTITL_" successfully added.")
  1.  Q