Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGMSTR3

DGMSTR3.m

Go to the documentation of this file. 
  1. DGMSTR3 ;ALB/GRR - GENERATE AND PRINT MST STATISTICAL REPORT ; 1/30/01 10:45am
  1.  ;;5.3;Registration;**195,319,1015**; Aug 13, 1993;Build 21
  1.  ;^TMP("DGMSTR3,JOB... - Array to hold ICD codes
  1.  ;DGPCDT - Current date in print format
  1.  ;DGSDAT - Start Date of selection range
  1.  ;DGEDAT - End Date of selection range
  1.  ;DGDX - ICD Code
  1.  ;DGDLOS - Length of Stay
  1.  ;DGPDAYS - Pass days
  1.  ;DGMST("N") - Number of new cases of MST
  1.  ;DGMST("O","R") - Number of outpatient visits related to MST
  1.  ;DGMST("O","NR") - Number of outpatient visits not related to MST
  1.  ;DGMST("O","U") - Number of unique outpatients treated for MST
  1.  ;DGMST("O","AR") - Average number of outpatient visits related to MST
  1.  ;DGMST("O","ANR") - Average number of outpatient visits not related to MST
  1.  ;DGMST("I",  -  Same totals as above except for inpatient
  1.  ;DGMST("LOS") - Total Length of Stay related to MST
  1. EN ;ENTRY POINT FOR ROUTINE
  1.  N TJOB
  1.  S TJOB=$J
  1.  K ^TMP("DGMSTR3",$J)
  1.  N DGMST,DGPCDT,DGSUB,DGSTAT,DGPSDT,DGPEDT,DTOUT,DUOUT,ZTSAVE,X,Y
  1.  N DTOUT,DUOUT,ZTSAVE
  1.  K DGMST
  1.  D DT^DICRW
  1.  S Y=DT D DD^%DT S DGPCDT=Y
  1.  F DGSTAT="O","I" F DGSUB="R","NR","U","AR","ANR","T" S DGMST(DGSTAT,DGSUB)=0
  1.  S DGMST("N")=0,DGMST("LOS")=0,DGMST("ALOS")=0
  1.  ;GET DATE RANGE
  1. SDAT S DIR(0)="D^:"_DT_":EX",DIR("A")="Start Date"
  1.  D ^DIR K DIR
  1.  Q:$D(DTOUT)!($D(DUOUT))
  1.  S DGSDAT=+Y,Y=+Y D DD^%DT S DGPSDT=Y
  1. TDAT S DIR(0)="D^"_DGSDAT_":"_DT_":EX",DIR("A")="End Date"
  1.  D ^DIR K DIR
  1.  Q:$D(DTOUT)!($D(DUOUT))
  1.  S DGEDAT=+Y_.9999,Y=+Y D DD^%DT S DGPEDT=Y
  1. DEVICE F X="DGMST(","DGSDAT","DGPSDT","DGEDAT","DGPEDT","DGPCDT" S ZTSAVE(X)=""
  1.  W !!,"This may take long to print, queue the report to free-up your terminal!",!
  1.  D EN^XUTMDEVQ("RPT^DGMSTR3","MST Statistical Summary",.ZTSAVE)
  1.  D HOME^%ZIS
  1.  Q
  1. RPT ;LOOP THROUGH AND CALCULATE NEW MST CASES
  1.  N DFN,SEX,DGSEDT,DGDATE,DGEIEN,DGAPST,DGCALC,DGTYP,DGGEN,DGIEN,DA,X,Y,DTOUT,DUOUT,VADM
  1.  N DGCSTAT,DGDA,DGCC,DGCLIEN,DGDX,DGMIEN,DGPTFIEN,DGLOS,DGPDAYS
  1.  N DGDXERR,DGLOS,DGOCIEN
  1.  S DGDATE=DGSDAT F  S DGDATE=$O(^DGMS(29.11,"B",DGDATE)) Q:DGDATE'>0!(DGDATE>DGEDAT)  S DGIEN=0 F  S DGIEN=$O(^DGMS(29.11,"B",DGDATE,DGIEN)) Q:DGIEN'>0   S:$P($G(^DGMS(29.11,DGIEN,0)),"^",3)="Y" DGMST("N")=DGMST("N")+1
  1.  ;GET IEN FOR MST CLASSIFICATION TYPE
  1.  S DIC=409.41,DIC(0)="X",X="MILITARY SEXUAL TRAUMA"
  1.  D ^DIC K DIC
  1.  I Y'>0 W !!,"Military Sexual Trauma entry missing from Outpatient Classification Type (409.41) file" Q
  1.  S DGOCIEN=+Y K DFN S DFN=""
  1.  ;CALCULATE OUTPATIENT TOTALS
  1.  S DGDATE=DGSDAT F  S DGDATE=$O(^SCE("B",DGDATE)) Q:DGDATE'>0!(DGDATE>DGEDAT)  D
  1.  .S DGEIEN=0 F  S DGEIEN=$O(^SCE("B",DGDATE,DGEIEN)) Q:DGEIEN'>0  D
  1.  ..S Y(0)=$G(^SCE(DGEIEN,0)) Q:Y(0)=""
  1.  ..S DFN=$P(Y(0),"^",2),DGAPST=$P(Y(0),"^",12) Q:DGAPST=8  ;DGAPST=8 MEANS INPATIENT, DONT COUNT
  1.  ..I DFN="" Q
  1.  ..S DGCSTAT=$$GETSTAT^DGMSTAPI(DFN,DGEDAT)
  1.  ..S DGCC=$P(DGCSTAT,"^",2)
  1.  ..I DGCC'="Y"&(DGCC'="N")&(DGCC'="D")&(DGCC'="U") Q
  1.  ..S DGCLIEN=$O(^SDD(409.42,"AO",DGEIEN,DGOCIEN,0)),DGMST("O","T")=DGMST("O","T")+1 I DGCLIEN]"" D
  1.  ...I $P($G(^SDD(409.42,DGCLIEN,0)),"^",3)'=1 S DGMST("O","NR")=DGMST("O","NR")+1
  1.  ...E  S DGMST("O","R")=DGMST("O","R")+1 I '$D(DFN(DFN,"O")) S DFN(DFN,"O")="",DGMST("O","U")=DGMST("O","U")+1
  1.  ..D DEM^VADPT S SEX=$P(VADM(5),"^")
  1.  ..I SEX="M"!(SEX="F") D
  1.  ...S DGDX=$$GETPDX^SDOE(DGEIEN,.DGDXERR) ;; CHANGED 4.16.99 SCK CORRECT FOR API
  1.  ...I DGDX'="" S DGDX=$P($G(^ICD9(DGDX,0)),"^") I DGDX'="" D
  1.  ....I '$D(^TMP("DGMSTR3",$J,DGDX)) F DGGEN="M","F" F DGTYP="I","O" S ^TMP("DGMSTR3",$J,DGDX,DGGEN,DGTYP)=0
  1.  ....S ^TMP("DGMSTR3",$J,DGDX,SEX,"O")=^TMP("DGMSTR3",$J,DGDX,SEX,"O")+1
  1.  ;LOOP FOR INPATIENT CALCULATIONS
  1.  S DGDATE=DGSDAT F  S DGDATE=$O(^DGPM("B",DGDATE)) Q:DGDATE'>0!(DGDATE>DGEDAT)  S DGDA=0 F  S DGDA=$O(^DGPM("B",DGDATE,DGDA)) Q:DGDA'>0  S DGPTFIEN=$P($G(^DGPM(DGDA,0)),"^",16) I DGPTFIEN'="" D
  1.  .S DGMIEN=0,DGPDAYS=0,DGCALC=0 F  S DGMIEN=$O(^DGPT(DGPTFIEN,"M",DGMIEN)) Q:DGMIEN'>0  D
  1.  ..S Y(0)=$G(^(DGMIEN,0)),DGPDAYS=DGPDAYS+(+$P(Y(0),"^",4)),DGMST("I","T")=DGMST("I","T")+1
  1.  ..I $P(Y(0),"^",29)="Y" D
  1.  ...S DGMST("I","R")=DGMST("I","R")+1,DGCALC=1
  1.  ...S DFN=$P(^DGPT(DGPTFIEN,0),"^")
  1.  ...Q:DFN=""
  1.  ...I '$D(DFN(DFN,"I")) S DFN(DFN,"I")="",DGMST("I","U")=DGMST("I","U")+1
  1.  ...S DGDX=$P(Y(0),"^",5) D DEM^VADPT S SEX=$P(VADM(5),"^")
  1.  ...I DGDX'="",SEX="M"!(SEX="F") S DGDX=$P($G(^ICD9(DGDX,0)),"^") I DGDX'="" D
  1.  ....I '$D(^TMP("DGMSTR3",$J,DGDX)) F DGGEN="M","F" F DGTYP="I","O" S ^TMP("DGMSTR3",$J,DGDX,DGGEN,DGTYP)=0
  1.  ....S ^TMP("DGMSTR3",$J,DGDX,SEX,"I")=^TMP("DGMSTR3",$J,DGDX,SEX,"I")+1
  1.  ..E  S DGMST("I","NR")=DGMST("I","NR")+1
  1.  .I +$G(DGCALC)>0,$P($G(^DGPT(DGPTFIEN,70)),"^")]"" D
  1.  ..S DGLOS=$$CALCLOS(DGPTFIEN,DGPDAYS),DGMST("LOS")=DGMST("LOS")+DGLOS
  1. PRT ;LAST CALCULATIONS AND PRINT
  1.  I DGMST("LOS")>0 S DGMST("ALOS")=DGMST("LOS")/DGMST("I","R")
  1.  I DGMST("O","T")>0 S DGMST("O","AR")=$J(DGMST("O","R")/DGMST("O","T"),7,2),DGMST("O","ANR")=$J(DGMST("O","NR")/DGMST("O","T"),7,2)
  1.  I DGMST("I","T")>0 S DGMST("I","AR")=$J(DGMST("I","R")/DGMST("I","T"),7,2),DGMST("I","ANR")=$J(DGMST("I","NR")/DGMST("I","T"),7,2)
  1.  D NOFF
  1.  W !!,"# OF NEW CASES IDENTIFIED FOR MST",?78-$L(DGMST("N")),DGMST("N")
  1.  W !!,"-------------OUTPATIENT STATISTICS-------------"
  1.  W !!,"# OF OUTPATIENT ENCOUNTERS RELATED TO MST",?78-$L(DGMST("O","R")),DGMST("O","R")
  1.  W !,"# OF OUTPATIENT ENCOUNTERS NOT RELATED TO MST",?78-$L(DGMST("O","NR")),DGMST("O","NR")
  1.  W !,"# OF UNIQUE OUTPATIENTS TREATED FOR MST",?78-$L(DGMST("O","U")),DGMST("O","U")
  1.  W !,"AVERAGE # OF ENCOUNTERS RELATED TO MST",?78-$L(DGMST("O","AR")),DGMST("O","AR")
  1.  W !,"AVERAGE # OF ENCOUNTERS NOT RELATED TO MST",?78-$L(DGMST("O","ANR")),DGMST("O","ANR")
  1.  W !!,"-------------INPATIENT STATISTICS---------------"
  1.  W !!,"# OF INPATIENT EPISODES RELATED TO MST",?78-$L(DGMST("I","R")),DGMST("I","R")
  1.  W !,"# OF INPATIENT EPISODES NOT RELATED TO MST",?78-$L(DGMST("I","NR")),DGMST("I","NR")
  1.  W !,"# OF UNIQUE INPATIENTS TREATED FOR MST",?78-$L(DGMST("I","U")),DGMST("I","U")
  1.  W !,"AVERAGE # OF INPATIENT EPISODES TREATED FOR MST",?78-$L(DGMST("I","AR")),DGMST("I","AR")
  1.  W !,"AVERAGE # OF INPATIENT EPISODES NOT TREATED FOR MST",?78-$L(DGMST("I","ANR")),DGMST("I","ANR")
  1.  W !,"TOTAL LENGTH OF STAY OF INPATIENTS TREATED FOR MST",?78-$L(DGMST("LOS")),DGMST("LOS")
  1.  W !,"AVERAGE LENGTH OF STAY OF INPATIENTS TREATED FOR MST",?78-$L(DGMST("ALOS")),DGMST("ALOS")
  1.  I $Y+3>$G(IOSL) D  Q:$D(DTOUT)!($D(DUOUT))
  1.  .I $E(IOST,1,2)="C-" S DIR(0)="E" D ^DIR K DIR Q:$D(DTOUT)!($D(DUOUT))
  1.  .;I IO=IO(0) S DIR(0)="E" D ^DIR K DIR Q:$D(DTOUT)!($D(DUOUT))
  1.  .D HED
  1.  G:$O(^TMP("DGMSTR3",$J,0))="" END1 ;;CHANGED BY SCK 4.16.99 CHECK ON ERROR
  1.  W !!,"ICD-9 CODE",?24,"NUMBER OF MALE",?54,"NUMBER OF FEMALE"
  1.  W !,?22,"OUTPATIENT",?35,"INPATIENT",?52,"OUTPATIENT",?65,"INPATIENT"
  1.  S DGDX="" F  S DGDX=$O(^TMP("DGMSTR3",$J,DGDX)) Q:DGDX=""  D  Q:$D(DTOUT)!($D(DUOUT))
  1.  .I $Y+3>IOSL D  Q:$D(DTOUT)!($D(DUOUT))
  1.  ..I $E(IOST,1,2)="C-" S DIR(0)="E" D ^DIR K DIR Q:$D(DTOUT)!($D(DUOUT))
  1.  ..;I IO=IO(0) S DIR(0)="E" D ^DIR K DIR Q:$D(DTOUT)!($D(DUOUT))
  1.  ..D HED W !!,"ICD-9 CODE",?24,"NUMBER OF MALE",?54,"NUMBER OF FEMALE",!,?22,"OUTPATIENT",?35,"INPATIENT",?52,"OUTPATIENT",?65,"INPATIENT"
  1.  .W !,?2,DGDX,?28-$L(^TMP("DGMSTR3",$J,DGDX,"M","O"))
  1.  .W ^TMP("DGMSTR3",$J,DGDX,"M","O")
  1.  .W ?40-$L(^TMP("DGMSTR3",$J,DGDX,"M","I"))
  1.  .W ^TMP("DGMSTR3",$J,DGDX,"M","I")
  1.  .W ?58-$L(^TMP("DGMSTR3",$J,DGDX,"F","O")),^TMP("DGMSTR3",$J,DGDX,"F","O")
  1.  .W ?70-$L(^TMP("DGMSTR3",$J,DGDX,"F","I"))
  1.  .W ^TMP("DGMSTR3",$J,DGDX,"F","I")
  1.  I $E(IOST,1,2)="C-" S DIR="E" D ^DIR K DIR
  1. END1 K DA,DGSDAT,DGEDAT,DGMST,DGPCDT,DGPEDT,DGPSDT,X,Y
  1.  K ^TMP("DGMSTAPI",$J)
  1.  K TJOB
  1.  Q
  1.  ;
  1. CALCLOS(DGPTFIEN,DGPDAYS) ;CALCULATE LOS FOR EPISODE
  1.  N DGADT,DGDDT,DGLDAYS,DGDAYS,Y,X1,X2
  1.  S Y(70)=$G(^DGPT(DGPTFIEN,70)) Q:Y(70)="" 0
  1.  S DGDDT=$P(Y(70),"^")\1,DGADT=$P(^DGPT(DGPTFIEN,0),"^",2)\1,DGLDAYS=$P(Y(70),"^",8)
  1.  S X1=DGDDT,X2=DGADT D ^%DTC
  1.  S DGDAYS=X-(DGLDAYS+DGPDAYS)
  1.  Q DGDAYS
  1.  ;
  1. HED ;PRINT HEADER INFO
  1.  W @IOF
  1. NOFF W !,?20,"MST Statistical Report"
  1.  W !,?20,"Date Range: ",DGPSDT," - ",DGPEDT
  1.  W !,?20,"Date Report Printed: ",DGPCDT
  1.  Q
  1.  ;