Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGNTAPI

DGNTAPI.m

Go to the documentation of this file. 
  1. DGNTAPI ;ALB/RPM - API's for N/T Radium Treatments ; 8/24/01 3:49pm
  1.  ;;5.3;Registration;**397,423,1015**;Aug 13, 1993;Build 21
  1.  Q
  1.  ;
  1.  ;
  1. GETPRIM(DFN) ; Used to get the patient's primary record in the (#28.11) file.
  1.  ;
  1.  ;  Input:
  1.  ;   DFN - IEN of patient in the PATIENT (#2) file
  1.  ;
  1.  ; Output:
  1.  ;   Function Value - If successful, returns IEN of record in (#28.11) file, otherwise returns null on failure.
  1.  ;
  1.  Q:'$G(DFN) ""
  1.  Q $O(^DGNT(28.11,"APR",DFN,1,0))
  1.  ;
  1.  ;
  1. GETREC(DGIEN,DGNTAPA) ;  Used to obtain a record in the (#28.11) file.
  1.  ;
  1.  ;  Input:
  1.  ;   DGIEN - IEN of record in the (#28.11) file
  1.  ;   DGNTAPA - Array name of return values [Optional - Default DGNTARR]
  1.  ;
  1.  ; Output:
  1.  ;  Function Value: Returns 1 on success, 0 on failure.
  1.  ;  DGNTAPA() array, passed by reference.  If the function is successful
  1.  ;  this array will contain the record.
  1.  ;
  1.  ;    subscript   field name
  1.  ;    ---------   ----------
  1.  ;    "DFN"       Patient
  1.  ;    "IND"       NTR Indicator - internal^external
  1.  ;    "STAT"      Screening Status - internal^external
  1.  ;    "NTR"       NTR Treatment - internal^external
  1.  ;    "AVI"       Military Aviator Pre 1/31/1955 - internal^external
  1.  ;    "SUB"       Submarine Training Pre 1/1/65 - internal^external
  1.  ;    "EDT"       Date/Time NTR Entered
  1.  ;    "EUSR"      NTR Entered By
  1.  ;    "PRIM"      NTR Primary Entry
  1.  ;    "SUPER"     Date/Time Superseded
  1.  ;    "VER"       Verification Method - internal^external
  1.  ;    "VDT"       Date/Time Verified
  1.  ;    "VUSR"      Verified By
  1.  ;    "VSIT"      Site Verifying Documentation
  1.  ;    "HNC"       Head/Neck CA DX - internal^external
  1.  ;    "HDT"       Date/Time DX Verified
  1.  ;    "HUSR"      DX Verified By
  1.  ;    "HSIT"      Site Verifying DX
  1.  ;
  1.  N DGFDA,DGMSG
  1.  ;
  1.  I '$G(DGIEN) Q 0
  1.  I '$D(^DGNT(28.11,DGIEN,0)) Q 0
  1.  ;
  1.  S DGNTAPA=$G(DGNTAPA)
  1.  I DGNTAPA']"" S DGNTAPA="DGNTARR"
  1.  ;
  1.  ; Obtain record
  1.  D GETS^DIQ(28.11,DGIEN_",","*","IE","DGFDA","DGMSG")
  1.  S @DGNTAPA@("DFN")=$G(DGFDA(28.11,+DGIEN_",",.01,"I"))
  1.  S @DGNTAPA@("IND")=$G(DGFDA(28.11,+DGIEN_",",.02,"I"))_"^"_$G(DGFDA(28.11,+DGIEN_",",.02,"E"))
  1.  S @DGNTAPA@("STAT")=$G(DGFDA(28.11,+DGIEN_",",.03,"I"))_"^"_$G(DGFDA(28.11,+DGIEN_",",.03,"E"))
  1.  S @DGNTAPA@("NTR")=$G(DGFDA(28.11,+DGIEN_",",.04,"I"))_"^"_$G(DGFDA(28.11,+DGIEN_",",.04,"E"))
  1.  S @DGNTAPA@("AVI")=$G(DGFDA(28.11,+DGIEN_",",.05,"I"))_"^"_$G(DGFDA(28.11,+DGIEN_",",.05,"E"))
  1.  S @DGNTAPA@("SUB")=$G(DGFDA(28.11,+DGIEN_",",.06,"I"))_"^"_$G(DGFDA(28.11,+DGIEN_",",.06,"E"))
  1.  S @DGNTAPA@("EDT")=$G(DGFDA(28.11,+DGIEN_",",.07,"I"))
  1.  S @DGNTAPA@("EUSR")=$G(DGFDA(28.11,+DGIEN_",",.08,"I"))
  1.  S @DGNTAPA@("PRIM")=$G(DGFDA(28.11,+DGIEN_",",.09,"I"))
  1.  S @DGNTAPA@("SUPER")=$G(DGFDA(28.11,+DGIEN_",",.1,"I"))
  1.  S @DGNTAPA@("VER")=$G(DGFDA(28.11,+DGIEN_",",1.01,"I"))_"^"_$G(DGFDA(28.11,+DGIEN_",",1.01,"E"))
  1.  S @DGNTAPA@("VDT")=$G(DGFDA(28.11,+DGIEN_",",1.02,"I"))
  1.  S @DGNTAPA@("VUSR")=$G(DGFDA(28.11,+DGIEN_",",1.03,"I"))
  1.  S @DGNTAPA@("VSIT")=$G(DGFDA(28.11,+DGIEN_",",1.04,"I"))
  1.  S @DGNTAPA@("HNC")=$G(DGFDA(28.11,+DGIEN_",",2.01,"I"))_"^"_$G(DGFDA(28.11,+DGIEN_",",2.01,"E"))
  1.  S @DGNTAPA@("HDT")=$G(DGFDA(28.11,+DGIEN_",",2.02,"I"))
  1.  S @DGNTAPA@("HUSR")=$G(DGFDA(28.11,+DGIEN_",",2.03,"I"))
  1.  S @DGNTAPA@("HSIT")=$G(DGFDA(28.11,+DGIEN_",",2.04,"I"))
  1.  ;
  1.  Q 1
  1.  ;
  1. GETCUR(DGDFN,DGNTAPIA) ; Retrieve current record
  1.  ;This is a supported API (DBIA #3457)
  1.  ;  Input:
  1.  ;   DGDFN - IEN of patient in the PATIENT (#2) file
  1.  ;   DGNTAPIA - Array name of return values [Optional - Default DGNTARR]
  1.  ;
  1.  ;  Output:
  1.  ;    function result - IEN of current NTR HISTORY file (#28.11) record.
  1.  ;    DGNTAPIA - Array of current NTR HISTORY file record field values.
  1.  ;            See $$GETREC for documentation.
  1.  ;            The node, "INTRP", a calculated free text intrepretation
  1.  ;            is added to the array.
  1.  ;
  1.  N DGIEN
  1.  ;
  1.  I '$G(DGDFN) Q 0
  1.  ;
  1.  S DGNTAPIA=$G(DGNTAPIA)
  1.  I DGNTAPIA']"" S DGNTAPIA="DGNTARR"
  1.  ;
  1.  S DGIEN=+$$GETPRIM(DGDFN)
  1.  I $$GETREC(DGIEN,DGNTAPIA) D
  1.  . S @DGNTAPIA@("INTRP")=$$INTERP^DGNTUT(DGNTAPIA)
  1.  Q DGIEN
  1.  ;
  1. FILENTR(DFN,DGNUPD,DGXMIT) ; NTR HISTORY (#28.11) filer
  1.  ; Callpoint to create a new NTR HISTORY FILE (#28.11) entry.
  1.  ; Will also queue HL7 message for HEC database updates.
  1.  ;
  1.  ;  Input
  1.  ;    DFN    - Patients DFN
  1.  ;    DGNUPD - question response array
  1.  ;      "NTR"  - NTR exposure code
  1.  ;      "AVI"  - Military Aviator prior to 1/31/55
  1.  ;      "SUB"  - Submarine Training prior to 1/1/65
  1.  ;      "EDT"  - Date/Time entered
  1.  ;      "EUSR" - Entered by
  1.  ;      "VER"  - verification method
  1.  ;      "VDT"  - Date/Time verified
  1.  ;      "VUSR" - verified by
  1.  ;      "VSIT" - Site verifying Documentation
  1.  ;      "HNC"  - Head/Neck Cancer DX
  1.  ;      "HDT"  - Date/Time diagnosis verified
  1.  ;      "HUSR" - diagnosis verified by
  1.  ;      "HSIT" - Site verifying DX
  1.  ;    DGXMIT - flag to transmit update to the HEC
  1.  ;             "0" - don't transmit, "1" - transmit [default]
  1.  ;
  1.  ;  Output
  1.  ;    DGRSLT - Returns IEN of file (#28.11) entry if successful
  1.  ;
  1.  ;    If an error occurred during parameter validation, then:
  1.  ;       DGRSLT = 0^Error Description
  1.  ;
  1.  ;    If an error occured during filing, then:
  1.  ;       DGRSLT = 0^Error Code IEN
  1.  ;                   (returned by UPDATE^DIE call)
  1.  ;
  1.  N DGRSLT,DGFDA,DGNERR
  1.  S DFN=+$G(DFN)
  1.  S DGXMIT=$S($G(DGXMIT)=0:0,1:1)
  1.  S DGRSLT=0
  1.  ;
  1.  I DFN>0,$D(DGNUPD) D
  1.  . S DGNUPD("DFN")=DFN
  1.  . ;validate the input array parameter
  1.  . I '$$VALID^DGNTAPI1(.DGNUPD,.DGNERR) D  Q
  1.  . . S DGRSLT="0^"_$G(DGNERR)
  1.  . I $$BLDFDA(DFN,.DGNUPD,.DGFDA) S DGRSLT=$$NEWNTR(.DGFDA)
  1.  . Q:'DGRSLT
  1.  . ;queue message to the HEC
  1.  . I DGXMIT D AUTOUPD^DGENA2(DFN)
  1.  ;
  1.  Q DGRSLT
  1.  ;
  1. BLDFDA(DFN,DGNTUPD,DGBFDA) ;
  1.  ;Build the field desription array
  1.  ;  Input
  1.  ;    DFN    - Patients DFN
  1.  ;    DGNTUPD - question response array - refer to $$FILENTR
  1.  ;    DGBFDA  - FDA name passed by reference
  1.  ;
  1.  ;  Output
  1.  ;    DGBFDA - field array built by reference
  1.  ;    DGRSLT - function return
  1.  ;               1 - successful build
  1.  ;               0 - nothing built
  1.  ;
  1.  N DGSTAT  ;screening status internal code
  1.  N DGIENS  ;IENS string
  1.  N DGRSLT  ;did anything get built
  1.  ;
  1.  S DGIENS="+1,"
  1.  S DGRSLT=0
  1.  S DGBFDA(28.11,DGIENS,.01)=DFN
  1.  S DGBFDA(28.11,DGIENS,.04)=$P(DGNTUPD("NTR"),"^")
  1.  S DGBFDA(28.11,DGIENS,.05)=$P(DGNTUPD("AVI"),"^")
  1.  S DGBFDA(28.11,DGIENS,.06)=$P(DGNTUPD("SUB"),"^")
  1.  S DGBFDA(28.11,DGIENS,.07)=$G(DGNTUPD("EDT"))
  1.  S DGBFDA(28.11,DGIENS,.08)=$G(DGNTUPD("EUSR"))
  1.  S DGBFDA(28.11,DGIENS,1.01)=$P(DGNTUPD("VER"),"^")
  1.  S DGBFDA(28.11,DGIENS,1.02)=$G(DGNTUPD("VDT"))
  1.  S DGBFDA(28.11,DGIENS,1.03)=$G(DGNTUPD("VUSR"))
  1.  S DGBFDA(28.11,DGIENS,1.04)=$G(DGNTUPD("VSIT"))
  1.  S DGBFDA(28.11,DGIENS,2.01)=$P(DGNTUPD("HNC"),"^")
  1.  S DGBFDA(28.11,DGIENS,2.02)=$G(DGNTUPD("HDT"))
  1.  S DGBFDA(28.11,DGIENS,2.03)=$G(DGNTUPD("HUSR"))
  1.  S DGBFDA(28.11,DGIENS,2.04)=$G(DGNTUPD("HSIT"))
  1.  ;indicator and status
  1.  S DGSTAT=$$STATUS^DGNTUT(.DGNTUPD)  ;determine pending/verified status
  1.  S DGBFDA(28.11,DGIENS,.02)=$S(DGSTAT=4!(DGSTAT=5):"Y",1:"N")
  1.  S DGBFDA(28.11,DGIENS,.03)=DGSTAT
  1.  S DGBFDA(28.11,DGIENS,.09)=1
  1.  Q 1
  1.  ;
  1. NEWNTR(DGNFDA) ;Create new record
  1.  ;  Input
  1.  ;    DGNFDA - Field description array
  1.  ;
  1.  ;  Output
  1.  ;    DGRSLT - 1=success
  1.  ;             0=failed
  1.  ;
  1.  N DGERR,DGRSLT,DGNTIEN
  1.  D UPDATE^DIE("","DGNFDA","DGNTIEN","DGERR")
  1.  S DGRSLT=+$G(DGNTIEN(1))
  1.  I $D(DGERR) D
  1.  . S DGRSLT="0^"_$G(DGERR("DIERR",1))
  1.  Q DGRSLT
  1.  ;
  1.  ;
  1. UPDNTR(DGUFDA) ;Update existing record
  1.  ;  Input
  1.  ;    DGUFDA - Field description array
  1.  ;
  1.  ;  Output
  1.  ;    DGRSLT - 1=success
  1.  ;             0=failed
  1.  ;
  1.  N DGERR,DGRSLT
  1.  S DGRSLT=0
  1.  D FILE^DIE("K","DGUFDA","DGERR")
  1.  I '$D(DGERR) S DGRSLT=1
  1.  Q DGRSLT