Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGPFLF1

DGPFLF1.m

Go to the documentation of this file. 
  1. DGPFLF1 ;ALB/KCL - PRF FLAG MANAGEMENT BUILD LIST AREA ; 3/11/03
  1.  ;;5.3;Registration;**425,1015**;Aug 13, 1993;Build 21
  1.  ;
  1.  ;no direct entry
  1.  QUIT
  1.  ;
  1. EN(DGARY,DGCAT,DGSRTBY,DGCNT) ;Entry point to build list area for PRF Flags.
  1.  ;
  1.  ; The following variables are 'system wide variables' in the
  1.  ; DGPF RECORD FLAG MANAGEMENT List Manager application:
  1.  ;   Input:
  1.  ;       DGARY - global array subscript
  1.  ;       DGCAT - flag category (1=National, 2=Local)
  1.  ;     DGSRTBY - list sort by criteria (N=Flag Name, T=Flage Type)
  1.  ;
  1.  ;  Output:
  1.  ;       DGCNT - number of lines in the list
  1.  ;
  1.  ;display wait msg
  1.  D WAIT^DICD
  1.  ;
  1.  ;retrieve all flags for the category specified
  1.  D GET(DGARY,DGCAT,DGSRTBY)
  1.  ;
  1.  ;build list area for flag screen
  1.  D BLD(DGSRTBY,.DGCNT)
  1.  ;
  1.  ;if no entries in list, display message in list area
  1.  I 'DGCNT D
  1.  . D SET^DGPFLMU1(DGARY,1,"",1,,,.DGCNT)
  1.  . D SET^DGPFLMU1(DGARY,2,"There are currently no flags on file to display.",4,$G(IOINHI),$G(IOINORM),.DGCNT)
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. GET(DGARY,DGCAT,DGSRTBY) ;Get flag entries for display.
  1.  ;
  1.  ;  Input:
  1.  ;      DGARY - global array subscript
  1.  ;      DGCAT - flag category (1=National, 2=Local)
  1.  ;    DGSRTBY - list sort by criteria (N=Flag Name, T=Flage Type)
  1.  ;
  1.  ; Output: None
  1.  ;
  1.  N DGFILE  ;file root of LOCAL or NATIONAL flag file
  1.  N DGFLAG  ;local array used to hold flag record
  1.  N DGIEN   ;ien of record in LOCAL or NATIONAL flag file
  1.  N DGVPTR  ;IEN of record in PRF NATIONAL FLAG or PRF LOCAL FLAG file
  1.  N DGRSULT
  1.  ;
  1.  ;determine LOCAL or NATIONAL flag file
  1.  S DGFILE=$S(DGCAT=1:"^DGPF(26.15)",DGCAT=2:"^DGPF(26.11)",1:0)
  1.  ;
  1.  ;loop through each ien of flag file determined by value of DGFILE
  1.  S DGIEN=0 F  S DGIEN=$O(@DGFILE@(DGIEN)) Q:'DGIEN  D
  1.  . K DGFLAG
  1.  . ;- if national, get flag into DGFLAG array
  1.  . I DGCAT=1 D  Q:'$G(DGRSULT)
  1.  . . S DGRSULT=$$GETNF^DGPFANF(DGIEN,.DGFLAG)
  1.  . . S:DGRSULT DGVPTR=DGIEN_";DGPF(26.15,"
  1.  . ;
  1.  . ;- if local, get flag into DGFLAG array
  1.  . I DGCAT=2 D  Q:'$G(DGRSULT)
  1.  . . S DGRSULT=$$GETLF^DGPFALF(DGIEN,.DGFLAG)
  1.  . . S:DGRSULT DGVPTR=DGIEN_";DGPF(26.11,"
  1.  . ;
  1.  . ;- set flag entry into sorted output array
  1.  . D SORT(DGVPTR,DGSRTBY,DGIEN,.DGFLAG)
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. SORT(DGVPTR,DGSRTBY,DGIEN,DGFLAG) ;Set flag data into sorted output array based on the sort criteria passed.
  1.  ;
  1.  ;  Input:
  1.  ;    DGVPTR - IEN of record in PRF NATIONAL FLAG or PRF LOCAL FLAG file
  1.  ;             [ex: "1;DGPF(26.15,"]
  1.  ;   DGSRTBY - list sort by criteria (N=Flag Name, T=Flage Type)
  1.  ;     DGIEN - ien of record in LOCAL or NATIONAL flag file
  1.  ;    DGFLAG - local array containing flag record
  1.  ;
  1.  ; Output: 
  1.  ;  Temporary global with following structure -
  1.  ;   Flag list sorted by flag name:
  1.  ;     ^TMP("DGPFSORT",$J,<status>,<flag name>,<ien>)=<var pointer>^<flag name>^<flag type>^<flag status>
  1.  ;   OR
  1.  ;   Flag list sorted by flag type:
  1.  ;      ^TMP("DGPFSORT",$J,<status>,<flag type>,<ien>)=<var pointer>^<flag name>^<flag type>^<flag status>
  1.  ;
  1.  I DGSRTBY="N" D  ;flag name
  1.  . S ^TMP("DGPFSORT",$J,$P($G(DGFLAG("STAT")),U),$P($G(DGFLAG("FLAG")),U,2),DGIEN)=DGVPTR_U_$P($G(DGFLAG("FLAG")),U,2)_U_$P($G(DGFLAG("TYPE")),U,2)_U_$P($G(DGFLAG("STAT")),U,2)
  1.  E  D  ;else flag type
  1.  . S ^TMP("DGPFSORT",$J,$P($G(DGFLAG("STAT")),U),$P($G(DGFLAG("TYPE")),U,2),DGIEN)=DGVPTR_U_$P($G(DGFLAG("FLAG")),U,2)_U_$P($G(DGFLAG("TYPE")),U,2)_U_$P($G(DGFLAG("STAT")),U,2)
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. BLD(DGSRTBY,DGCNT) ;Build list area for flag screen.
  1.  ;
  1.  ;  Input:
  1.  ;   DGSRTBY - list sort by criteria (N=Flag Name, T=Flage Type)
  1.  ;
  1.  ; Output:
  1.  ;     DGCNT - number of lines in the list
  1.  ;
  1.  N DGFIEN  ;^tmp global subscript (flag ien)
  1.  N DGLINE  ;line counter
  1.  N DGNAME  ;flag name
  1.  N DGNUM   ;list selction number
  1.  N DGSI    ;flag status internal value
  1.  N DGSTAT  ;flag status
  1.  N DGSUB   ;^tmp global subscript (flag name or type)
  1.  N DGTYPE  ;flag type
  1.  N DGVPTR  ;IEN of record in PRF NATIONAL FLAG or PRF LOCAL FLAG file
  1.  ;          [ex: "1;DGPF(26.15,"]
  1.  N DGTEMP  ;sort array root
  1.  ;
  1.  ;init line counter and selection number
  1.  S (DGLINE,DGNUM)=0
  1.  ;- loop through ^TMP global by status, active (1) then inactive (0)
  1.  F DGSI=1,0 D
  1.  . ;- loop through sort selection by flag name or flag type
  1.  . S DGSUB=$S(DGSRTBY="N":"",1:0)
  1.  . F  S DGSUB=$O(^TMP("DGPFSORT",$J,DGSI,DGSUB)) Q:DGSUB=""  D
  1.  . . ;- loop through flag file ien's
  1.  . . S DGFIEN=0
  1.  . . F  S DGFIEN=$O(^TMP("DGPFSORT",$J,DGSI,DGSUB,DGFIEN)) Q:'DGFIEN  D
  1.  . . . ;-- get flag data fields from entry in ^TMP global
  1.  . . . S DGTEMP=$NA(^TMP("DGPFSORT",$J))
  1.  . . . S DGVPTR=$P($G(@DGTEMP@(DGSI,DGSUB,DGFIEN)),U)    ;flag IEN
  1.  . . . S DGNAME=$P($G(@DGTEMP@(DGSI,DGSUB,DGFIEN)),U,2)  ;flag name
  1.  . . . S DGTYPE=$P($G(@DGTEMP@(DGSI,DGSUB,DGFIEN)),U,3)  ;flag type
  1.  . . . S DGSTAT=$P($G(@DGTEMP@(DGSI,DGSUB,DGFIEN)),U,4)  ;flag status
  1.  . . . ;
  1.  . . . ;-- increment selection number
  1.  . . . S DGNUM=DGNUM+1
  1.  . . . ;
  1.  . . . ;-- increment line counter
  1.  . . . S DGLINE=DGLINE+1
  1.  . . . ;
  1.  . . . ;-- set line into list area
  1.  . . . D SET(DGARY,DGLINE,DGNUM,1,,,DGVPTR,DGNUM,.DGCNT)
  1.  . . . D SET(DGARY,DGLINE,DGNAME,6,,,DGVPTR,DGNUM,.DGCNT)
  1.  . . . D SET(DGARY,DGLINE,DGTYPE,38,,,DGVPTR,DGNUM,.DGCNT)
  1.  . . . D SET(DGARY,DGLINE,DGSTAT,65,,,DGVPTR,DGNUM,.DGCNT)
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. SET(DGARY,DGLINE,DGTEXT,DGCOL,DGON,DGOFF,DGVPTR,DGNUM,DGCNT) ;This procedure will set the lines of flag details in the LM display area.
  1.  ;
  1.  ;  Input:
  1.  ;    DGARY - global array subscript
  1.  ;   DGLINE - line number
  1.  ;   DGTEXT - text
  1.  ;   DGVPTR - (optional) IEN of record in PRF NATIONAL FLAG or PRF LOCAL
  1.  ;            FLAG file [ex: "1;DGPF(26.15,"]
  1.  ;    DGNUM - (optional) selection number
  1.  ;    DGCOL - starting column
  1.  ;     DGON - highlighting on
  1.  ;    DGOFF - highlighting off
  1.  ;
  1.  ; Output:
  1.  ;   DGCNT - number of lines in the list, pass by reference
  1.  ;
  1.  N DGX
  1.  S:DGLINE>DGCNT DGCNT=DGLINE
  1.  S DGX=$S($D(^TMP(DGARY,$J,DGLINE,0)):^(0),1:"")
  1.  S ^TMP(DGARY,$J,DGLINE,0)=$$SETSTR^VALM1(DGTEXT,DGX,DGCOL,$L(DGTEXT))
  1.  D:$G(DGON)]""!($G(DGOFF)]"") CNTRL^VALM10(DGLINE,DGCOL,$L(DGTEXT),$G(DGON),$G(DGOFF))
  1.  ;
  1.  ;associate flag ien with list item for flag selection
  1.  S:($G(DGVPTR)]"")&($G(DGNUM)) ^TMP(DGARY,$J,"IDX",DGLINE,DGNUM)=""
  1.  S:($G(DGVPTR)]"")&($G(DGNUM)) ^TMP(DGARY,$J,"IDX",DGNUM)=DGVPTR
  1.  Q