Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGPFLF4

DGPFLF4.m

Go to the documentation of this file. 
  1. DGPFLF4 ;ALB/RBS - PRF FLAG MANAGEMENT LM PROTOCOL ACTIONS CONT. ; 4/15/04 12:15pm
  1.  ;;5.3;Registration;**425,554,650,1015**;Aug 13, 1993 ;Build 21
  1.  ;
  1.  ;no direct entry
  1.  QUIT
  1.  ;
  1. EF ;Entry point for DGPF EDIT FLAG action protocol.
  1.  ;
  1.  ;  Input: DGCAT - flag category (1=National, 2=Local)
  1.  ;
  1.  ; Output: Edit File entry in PRF LOCAL FLAG FILE (#26.11)
  1.  ;         New File entry in PRF LOCAL FLAG HISTORY FILE (#26.12)
  1.  ;         Set variable VALMBCK to 'R' = refresh screen
  1.  ;
  1.  N X,Y,DIRUT,DTOUT,DUOUT,DIROUT       ;input/output vars for ^DIR
  1.  N DGIDXIEN ;ien of flag record from the "IDX" 
  1.  N DGPFLF   ;array containing flag record field values
  1.  N DGPFLH   ;array containing flag history record field values
  1.  N DGPFORIG ;save original array containing flag record field values
  1.  N DGABORT  ;abort flag
  1.  N DGRESULT ;result of $$STOALL^DGPFALF1 api call
  1.  N DGERR    ;if error returned
  1.  N DGOK     ;ok flag to enter record flag entry & flag description
  1.  N DGLOCK   ;lock var for flag file edit
  1.  N DGSEL    ;user selection (list item)
  1.  N VALMY    ;output of EN^VALM2 call, array of user selected entries
  1.  N DGMSG    ;user message
  1.  N DGQ,DGSUB ;counters and quit flag
  1.  ;
  1.  ;init vars
  1.  S (DGABORT,DGLOCK,DGRESULT,DGQ,DGSUB)=0
  1.  S DGOK=1,(DGSEL,DGIDXIEN)=""
  1.  ;
  1.  ;set screen to full scrolling region
  1.  D FULL^VALM1
  1.  W !
  1.  ;
  1.  ;check flag category (only Category II flags can be edited)
  1.  I DGCAT=1 D
  1.  . D BLD^DIALOG(261129,"Can not edit 'Category I' flags.","","DGERR","F")
  1.  . D MSG^DIALOG("WE","","","","DGERR") W *7
  1.  . D PAUSE^VALM1
  1.  . S DGOK=0
  1.  ;
  1.  ;init flag record and history arrays
  1.  ; The DGPFLF array will contain 2 "^" pieces (internal^external)
  1.  ; for a final full screen display before filing.
  1.  K DGPFLF,DGPFLH,DGPFORIG
  1.  ;
  1.  ;allow user to select a single flag for editing
  1.  D:DGOK
  1.  . S DGOK=0,VALMBCK=""
  1.  . D EN^VALM2($G(XQORNOD(0)),"S")
  1.  . Q:'$D(VALMY)
  1.  . S DGSEL=$O(VALMY(""))
  1.  . Q:DGSEL']""
  1.  . Q:'$D(@VALMAR@("IDX",DGSEL))
  1.  . S DGIDXIEN=$G(@VALMAR@("IDX",DGSEL))
  1.  . ; lock flag record
  1.  . S DGLOCK=$$LOCKLF^DGPFALF1(DGIDXIEN)
  1.  . I 'DGLOCK D  Q
  1.  . . X DGMSG
  1.  . . W !?7,"Unable to Lock Flag, another User is Editing this Flag.",*7
  1.  . . D PAUSE^VALM1
  1.  . ;
  1.  . ; call api to get record back in array DGPFLF
  1.  . I '$$GETLF^DGPFALF($P(DGIDXIEN,";"),.DGPFLF) D  Q
  1.  . . X DGMSG
  1.  . . W !?7,"No Local Flag record data found.  Please check your selection.",*7
  1.  . . D PAUSE^VALM1
  1.  . ;
  1.  . M DGPFORIG=DGPFLF  ;save original array to compare for edits later
  1.  . S DGOK=1
  1.  ;
  1.  ;Call DGPFLF5 for user prompts to edit fields
  1.  ;   - split from this one due to size
  1.  I DGOK D
  1.  . D EFCONT^DGPFLF5(.DGPFLF,.DGPFLH,.DGPFORIG,.DGABORT,DGIDXIEN)
  1.  . Q:DGABORT
  1.  . ;
  1.  . ;check to see if user changed anything
  1.  . S DGSUB="",DGQ=0
  1.  . I $G(DGPFLF("OLDFLAG"))]""  S DGQ=1  ;flag name has changed
  1.  . I 'DGQ D
  1.  . . F DGSUB="STAT","TYPE","REVFREQ","NOTIDAYS","REVGRP","TIUTITLE" D  Q:DGQ
  1.  . . . I DGPFLF(DGSUB)'=DGPFORIG(DGSUB) S DGQ=1
  1.  . . Q:DGQ
  1.  . . ;
  1.  . . ;was description modified?
  1.  . . I $O(DGPFLF("DESC",""),-1)'=$O(DGPFORIG("DESC",""),-1) S DGQ=1
  1.  . . Q:DGQ
  1.  . . ;
  1.  . . S DGSUB=0
  1.  . . F  S DGSUB=$O(DGPFLF("DESC",DGSUB)) Q:DGSUB=""  D  Q:DGQ
  1.  . . . I DGPFLF("DESC",DGSUB,0)'=$G(DGPFORIG("DESC",DGSUB,0)) S DGQ=1
  1.  . . Q:DGQ
  1.  . . ;
  1.  . . S DGSUB=0
  1.  . . F  S DGSUB=$O(DGPFLF("PRININV",DGSUB)) Q:DGSUB=""  D  Q:DGQ
  1.  . . . I DGPFLF("PRININV",DGSUB,0)'=$G(DGPFORIG("PRININV",DGSUB,0)) S DGQ=1
  1.  . ;
  1.  . I 'DGQ D  Q
  1.  . . W !!,"   >>> No edits to "_$P(DGPFLF("FLAG"),U,2)_" were found."
  1.  . . S DGABORT=1
  1.  . ;
  1.  . K DGPFORIG  ;kill array - no longer needed
  1.  . ;
  1.  . ;re-display user's answers on full screen
  1.  . D REVIEW^DGPFUT3(.DGPFLF,.DGPFLH,"",XQY0,XQORNOD(0))
  1.  . ;
  1.  . ;file the edits
  1.  . W !,*7
  1.  . I $$ANSWER^DGPFUT("Would you like to file the local record flag changes","YES","Y")'>0 S DGABORT=1 Q
  1.  . ;
  1.  . W !,"Updating the local record flag..."
  1.  . ;
  1.  . ;setup remaining flag history array nodes for filing
  1.  . ;note, the DGPFLH("FLAG") will be setup in $$STOALL^DGPFALF1
  1.  . S DGPFLH("ENTERDT")=$$NOW^XLFDT()   ;current date/time
  1.  . S DGPFLH("ENTERBY")=DUZ             ;current user
  1.  . ;
  1.  . ;file both the (#26.11) & (#26.12) entries
  1.  . S DGRESULT=$$STOALL^DGPFALF1(.DGPFLF,.DGPFLH,.DGERR)
  1.  . ;
  1.  . W !!,"   >>> Local record flag was "_$S(+DGRESULT:"filed successfully.",1:"not filed successfully."),*7
  1.  . ;
  1.  . D PAUSE^VALM1
  1.  ;
  1.  I DGLOCK,$$UNLOCK^DGPFALF1(DGIDXIEN)
  1.  ;
  1.  I DGABORT D
  1.  . W !!,"   >>> The '"_$P($G(XQORNOD(0)),U,3)_"' action is aborting, nothing has been filed.",*7
  1.  . I $$ANSWER^DGPFUT("Enter RETURN to continue","","E")  ;pause
  1.  ;
  1.  ;re-build list of local record flags
  1.  D BLD^DGPFLF
  1.  ;
  1.  ;return to LM (refresh screen)
  1.  S VALMBCK="R"
  1.  Q
  1.  ;