Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGPFLMU1

DGPFLMU1.m

Go to the documentation of this file. 
  1. DGPFLMU1 ;ALB/KCL - PRF DISPLAY FLAG DETAIL LM UTILITIES CONT ; 10/12/05 10:26am
  1.  ;;5.3;Registration;**425,554,650,1015**;Aug 13, 1993;Build 21
  1.  ;
  1.  ;no direct entry
  1.  QUIT
  1.  ;
  1. EN(DGARY,DGIEN,DGDFN,DGCNT) ;Entry point to build flag assignment detail list area.
  1.  ;
  1.  ;  Input:
  1.  ;    DGARY - global array subscript
  1.  ;    DGIEN - ien of PATIENT ASSIGNMENT (#26.13) file
  1.  ;    DGDFN - ien of PATIENT (#2) file
  1.  ;
  1.  ; Output:
  1.  ;    DGCNT - number of lines in the list, pass by reference
  1.  ;
  1.  N DGHIEN   ;assignment history ien
  1.  N DGHIENS  ;contains assignment history ien's 
  1.  N DGHISCNT ;count of history records
  1.  N DGLINE   ;line counter
  1.  N DGPFA    ;assignment array
  1.  N DGPFAH   ;assignment history array
  1.  N DGPFF    ;flag array
  1.  N DGSUB    ;subscript of history ien's array
  1.  ;
  1.  ;init variables
  1.  S DGCNT=0
  1.  S (DGLINE,VALMBEG)=1
  1.  K DGPFA
  1.  K DGPFAH
  1.  K DGPFF
  1.  K DGHIENS
  1.  ;
  1.  Q:'$G(DGIEN)
  1.  ;
  1.  ;get assignment into DGPFA array
  1.  Q:'$$GETASGN^DGPFAA(DGIEN,.DGPFA)
  1.  S DGPFA("INITASSIGN")=$$GETADT^DGPFAAH(DGIEN)  ;initial assign date
  1.  ;
  1.  ;get most recent assignment history and place in DGPFAH array
  1.  Q:'$$GETHIST^DGPFAAH($$GETLAST^DGPFAAH(DGIEN),.DGPFAH)
  1.  ;
  1.  ;get record flag into DGPFF array
  1.  Q:'$$GETFLAG^DGPFUT1($P($G(DGPFA("FLAG")),U),.DGPFF)
  1.  ;
  1.  ;build Assignment Details area
  1.  D ASGN(DGARY,.DGPFA,.DGPFAH,.DGPFF,.DGLINE,.DGCNT)
  1.  ;
  1.  ;build Assignment History heading
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,$TR($J("",80)," ","="),1,,,.DGCNT)
  1.  D SET(DGARY,DGLINE,"<Assignment History>",30,IORVON,IORVOFF,.DGCNT)
  1.  ;
  1.  ;get all history ien's associated with the assignment
  1.  Q:'$$GETALLDT^DGPFAAH(DGIEN,.DGHIENS)
  1.  ;
  1.  ;reverse loop through each assignment history ien
  1.  ;and get record into DGPFAH array
  1.  S DGHISCNT=0,DGSUB=9999999.999999
  1.  F  S DGSUB=$O(DGHIENS(DGSUB),-1) Q:DGSUB=""  D
  1.  . S DGHIEN=+$G(DGHIENS(DGSUB))
  1.  . K DGPFAH
  1.  . I $$GETHIST^DGPFAAH(DGHIEN,.DGPFAH) D
  1.  . . ;
  1.  . . ;-history record counter
  1.  . . S DGHISCNT=DGHISCNT+1
  1.  . . ;
  1.  . . ;-build assignment history area
  1.  . . D HIST(DGARY,.DGPFAH,.DGPFA,.DGLINE,DGHISCNT,.DGCNT)
  1.  Q
  1.  ;
  1.  ;
  1. ASGN(DGARY,DGPFA,DGPFAH,DGPFF,DGLINE,DGCNT) ;This procedure will build the lines of FLAG ASSIGNMENT details.
  1.  ;
  1.  ;  Input:
  1.  ;    DGARY - global array subscript
  1.  ;    DGPFF - flag array, pass by reference
  1.  ;    DGPFA - assignment array, pass by reference
  1.  ;   DGPFAH - assignment history array, pass by reference
  1.  ;   DGLINE - line counter
  1.  ;
  1.  ; Output:
  1.  ;    DGCNT - number of lines in the list, pass by reference
  1.  ;
  1.  ;temporary variables used
  1.  N DGSUB
  1.  N DGTMP
  1.  ;
  1.  ;set flag name
  1.  D SET(DGARY,DGLINE,"Flag Name: "_$P($G(DGPFA("FLAG")),U,2),12,,,.DGCNT)
  1.  ;
  1.  ;set flag type
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"Flag Type: "_$P($G(DGPFF("TYPE")),U,2),12,,,.DGCNT)
  1.  ;
  1.  ;set flag category
  1.  S DGLINE=DGLINE+1
  1.  S DGTMP=$S($P($G(DGPFA("FLAG")),U)["26.11":"II (LOCAL)",1:"I (NATIONAL)")
  1.  D SET(DGARY,DGLINE,"Flag Category: "_DGTMP,8,,,.DGCNT)
  1.  ;
  1.  ;set flag assignment status
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"Assignment Status: "_$P($G(DGPFA("STATUS")),U,2),4,,,.DGCNT)
  1.  ;
  1.  ;set initial assignment date
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"Initial Assignment: "_$$FDTTM^VALM1($P(+$G(DGPFA("INITASSIGN")),U)),3,,,.DGCNT)
  1.  ;
  1.  ;set last review date (do not set if only initial assignment)
  1.  S DGLINE=DGLINE+1
  1.  I (+$G(DGPFAH("ASSIGNDT")))=(+$G(DGPFA("INITASSIGN"))) D
  1.  . S DGTMP="N/A"
  1.  E  S DGTMP=$$FDATE^VALM1(+$G(DGPFAH("ASSIGNDT")))
  1.  D SET(DGARY,DGLINE,"Last Review Date: "_DGTMP,5,,,.DGCNT)
  1.  ;
  1.  ;set next review date
  1.  S DGLINE=DGLINE+1
  1.  S DGTMP=+$G(DGPFA("REVIEWDT"))
  1.  S DGTMP=$S(DGTMP:$$FDATE^VALM1(DGTMP),1:"N/A")
  1.  D SET(DGARY,DGLINE,"Next Review Date: "_DGTMP,5,,,.DGCNT)
  1.  ;
  1.  ;set owner site
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"Owner Site: "_$P($G(DGPFA("OWNER")),U,2)_"  "_$$FMTPRNT^DGPFUT1($P($G(DGPFA("OWNER")),U)),11,,,.DGCNT)
  1.  ;
  1.  ;set originating site
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"Originating Site: "_$P($G(DGPFA("ORIGSITE")),U,2)_"  "_$$FMTPRNT^DGPFUT1($P($G(DGPFA("ORIGSITE")),U)),5,,,.DGCNT)
  1.  ;
  1.  ;set assignment narrative
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"",1,,,.DGCNT)
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"Record Flag Assignment Narrative:",1,IORVON,IORVOFF,.DGCNT)
  1.  I '$D(DGPFA("NARR",1,0)) D  Q
  1.  . S DGLINE=DGLINE+1
  1.  . D SET(DGARY,DGLINE,"No Narrative Text",1,,,.DGCNT)
  1.  S (DGSUB,DGTMP)=""
  1.  F  S DGSUB=$O(DGPFA("NARR",DGSUB)) Q:'DGSUB  D
  1.  . S DGTMP=$G(DGPFA("NARR",DGSUB,0))
  1.  . S DGLINE=DGLINE+1
  1.  . D SET(DGARY,DGLINE,DGTMP,1,,,.DGCNT)
  1.  ;
  1.  ;set blank lines
  1.  S DGLINE=DGLINE+2
  1.  D SET(DGARY,DGLINE,"",1,,,.DGCNT)
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. HIST(DGARY,DGPFAH,DGPFA,DGLINE,DGHISCNT,DGCNT) ;This procedure will build the lines of FLAG ASSIGNMENT HISTORY details.
  1.  ;
  1.  ;  Input:
  1.  ;    DGARY - global array subscript
  1.  ;   DGPFAH - assignment history array, pass by reference
  1.  ;    DGPFA - assignment array, pass by reference
  1.  ;   DGLINE - line counter
  1.  ; DGHISCNT - counter of history record
  1.  ;
  1.  ; Output:
  1.  ;    DGCNT - number of lines in the list, pass by reference
  1.  ;
  1.  ;temporary variables used
  1.  N DGTMP
  1.  N DGSUB
  1.  ;
  1.  ;set blank line
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"",1,,,.DGCNT)
  1.  ;
  1.  ;add an additional blank line except on the first history
  1.  I DGHISCNT>1 D
  1.  . S DGLINE=DGLINE+1
  1.  . D SET(DGARY,DGLINE,"",1,,,.DGCNT)
  1.  ;
  1.  ;set action
  1.  S DGLINE=DGLINE+1
  1.  S DGTMP=DGHISCNT_"."
  1.  D SET(DGARY,DGLINE,DGTMP,1,IORVON,IORVOFF,.DGCNT)
  1.  D SET(DGARY,DGLINE,"Action: "_$P($G(DGPFAH("ACTION")),U,2),10,IORVON,IORVOFF,.DGCNT)
  1.  ;
  1.  ;set assignment date
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"Action Date: "_$$FDTTM^VALM1($P($G(DGPFAH("ASSIGNDT")),U)),5,,,.DGCNT)
  1.  ;
  1.  ;set entered by
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"Entered By: "_$P($G(DGPFAH("ENTERBY")),U,2),6,,,.DGCNT)
  1.  ;
  1.  ;set approved by
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"Approved By: "_$P($G(DGPFAH("APPRVBY")),U,2),5,,,.DGCNT)
  1.  ;
  1.  ;set progress note linked
  1.  I $D(^DG(40.8,"AD",+$P($G(DGPFA("OWNER")),U))) D
  1.  . Q:+$G(DGPFAH("ACTION"))=5  ;don't display ENTERED IN ERROR action
  1.  . S DGLINE=DGLINE+1
  1.  . D SET(DGARY,DGLINE,"Progress Note: "_$P($G(DGPFAH("TIULINK")),U,2),3,,,.DGCNT)
  1.  ;
  1.  ;set history comments
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"Action Comments:",1,,,.DGCNT)
  1.  S DGLINE=DGLINE+1
  1.  D SET(DGARY,DGLINE,"----------------",1,,,.DGCNT)
  1.  I $D(DGPFAH("COMMENT",1,0)) D
  1.  . S (DGSUB,DGTMP)=""
  1.  . F  S DGSUB=$O(DGPFAH("COMMENT",DGSUB)) Q:'DGSUB  D
  1.  .. S DGTMP=$G(DGPFAH("COMMENT",DGSUB,0))
  1.  .. S DGLINE=DGLINE+1
  1.  .. D SET(DGARY,DGLINE,DGTMP,1,,,.DGCNT)
  1.  E  D
  1.  . S DGLINE=DGLINE+1
  1.  . D SET(DGARY,DGLINE,"No Comments on file.",1,,,.DGCNT)
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. SET(DGARY,DGLINE,DGTEXT,DGCOL,DGON,DGOFF,DGCNT) ;This procedure will set the lines of flag assignment details into the LM display area.
  1.  ;
  1.  ;  Input:
  1.  ;    DGARY - global array subscript
  1.  ;   DGLINE - line number
  1.  ;   DGTEXT - text
  1.  ;    DGCOL - starting column
  1.  ;     DGON - highlighting on
  1.  ;    DGOFF - highlighting off
  1.  ;
  1.  ; Output:
  1.  ;    DGCNT - number of lines in the list, pass by reference
  1.  ;
  1.  N DGX  ;temp variable for line of display text
  1.  ;
  1.  S DGCNT=DGLINE
  1.  S DGX=$S($D(^TMP(DGARY,$J,DGLINE,0)):^(0),1:"")
  1.  S ^TMP(DGARY,$J,DGLINE,0)=$$SETSTR^VALM1(DGTEXT,DGX,DGCOL,$L(DGTEXT))
  1.  D:$G(DGON)]""!($G(DGOFF)]"") CNTRL^VALM10(DGLINE,DGCOL,$L(DGTEXT),$G(DGON),$G(DGOFF))
  1.  Q