Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DGPTICD

DGPTICD.m

Go to the documentation of this file. 
  1. DGPTICD ;ALB/MTC - PTF DRG Grouper Utility ; 2/19/02 3:08pm
  1.  ;;5.3;PIMS;**375,441,510,559,599,606,775,785,1015,1016**;JUN 30, 2012;Build 20
  1.  ;variables to pass in:
  1.  ;  DGDX <- format: DX CODE1^DX CODE2^DX CODE3^...                      (REQUIRED)
  1.  ;  DGSURG <- format: SURGERY CODE1^SURGERY CODE2^SURGERY CODE3^...       (OPTIONAL)
  1.  ;  DGPROC <- format: PROCEDURE CODE1^PROCEDURE CODE2^PROCEDURE CODE3^... (OPTIONAL)
  1.  ;  DGTRS  <- 1 if patient transferred to acute care facility             (REQUIRED)
  1.  ;  DGEXP  <- 1 if patient died during this episode                       (REQUIRED)
  1.  ;  DGDMS  <- 1 if patient was discharged with an Irregular discharge (discharged against medical advice) (REQUIRED)
  1.  ;  AGE,SEX     (REQUIRED)
  1.  ;values of variables listed above are left unchanged by this routine
  1.  ;variable passed back: DRG(0) <- zero node of DRG in DRG file
  1.  ;                    : DRG <- IFN of DRG in DRG file
  1.  ;  DGDAT  <- Effective date to be used in calculating DRG
  1.  ;
  1.  ;-- check for required variables
  1.  Q:'$D(DGDX)!'$D(DGTRS)!'$D(DGEXP)!'$D(DGDMS)
  1.  N DGI
  1.  ;-- build ICDDX array
  1.  K ICDDX
  1.  S DGI=0 F  S DGI=DGI+1 Q:$P(DGDX,U,DGI)=""  D
  1.  . S DGPTTMP=$$ICDDX^ICDCODE(+$P(DGDX,U,DGI),+$G(DGDAT))
  1.  . I +DGPTTMP>0,($P(DGPTTMP,U,10)) S ICDDX(DGI)=$P(DGDX,U,DGI)
  1.  G Q:'$D(ICDDX)
  1.  ;
  1.  ;-- build ICDPRC array
  1.  K ICDPRC
  1.  ;I $D(DGPROC) S DGSURG=$S('$D(DGSURG):DGPROC,1:DGSURG_DGPROC)
  1.  ;I $D(DGSURG) S DGI=0 F  S DGI=DGI+1 Q:$P(DGSURG,U,DGI)=""  D
  1.  ;. I $D(^ICD0($P(DGSURG,U,DGI),0)) S ICDPRC(DGI)=$P(DGSURG,U,DGI)
  1.  ;-- build ICDPRC array eliminating dupes as we go
  1.  K ICDPRC
  1.  N I,J,X,Y,FLG,SUB S SUB=0
  1.  I $D(DGPROC) F I=2:1 S X=$P(DGPROC,U,I) Q:X=""  D
  1.  . S DGPTTMP=$$ICDOP^ICDCODE(X,+$G(DGDAT))
  1.  . I +DGPTTMP>0,($P(DGPTTMP,U,10)) S SUB=SUB+1,ICDPRC(SUB)=X
  1.  I $D(DGSURG) F I=2:1 S X=$P(DGSURG,U,I) Q:X=""  D
  1.  .S J=0 F  S J=$O(ICDPRC(J)) Q:'J
  1.  .;I X=$G(ICDPRC(J)) S FLG=1 Q
  1.  .;I FLG Q
  1.  . S DGPTTMP=$$ICDOP^ICDCODE(X,+$G(DGDAT))
  1.  . I +DGPTTMP>0,($P(DGPTTMP,U,10)) S SUB=SUB+1,ICDPRC(SUB)=X
  1.  . S ICDSURG(SUB)=$P(DGPTTMP,U,2)
  1.  ;
  1.  ;-- set other required variables
  1.  S ICDTRS=DGTRS,ICDEXP=DGEXP,ICDDMS=DGDMS
  1.  S ICDDATE=$S($D(DGDAT):DGDAT,1:DT),DGDAT=ICDDATE  ;Ensure that DGDAT is defined prior to executing PRT
  1.  ;
  1.  ;-- calculate DRG
  1.  D ^ICDDRG S DRG=ICDDRG I '$D(DGDRGPRT) G Q
  1.  ;
  1. PRT ;print DRG and national HCFA values
  1.  I (ICDDATE<3071001)&(DRG=468!(DRG=469)!(DRG=470)) W *7
  1.  I DRG=998!(DRG=999) W *7
  1.  S Y=ICDDATE D DD^%DT ; Y=external representation of effective date
  1.  W !!?9,"Effective Date:","  ",Y
  1.  S DRG(0)=$$DRG^ICDGTDRG(DRG,DGDAT) W !!,"Diagnosis Related Group: ",$J(DRG,6),?36,"Average Length of Stay(ALOS): ",$J($P(DRG(0),"^",8),6)
  1.  W !?17,"Weight: ",$J($P(DRG(0),"^",2),6)  ;,?40,"Local Breakeven: ",$J($P(DRG(0),"^",12),6)
  1.  W !?12," Low Day(s): ",$J($P(DRG(0),"^",3),6)  ;,?39,"Local Low Day(s): ",$J($P(DRG(0),"^",9),6)
  1.  W !?13," High Days: ",$J($P(DRG(0),"^",4),6)  ;,?40,"Local High Days: ",$J($P(DRG(0),"^",10),6)
  1.  N DXD,DGDX
  1.  S DXD=$$DRGD^ICDGTDRG(DRG,"DGDX",,DGDAT),DGI=0
  1.  W !!,"DRG: ",DRG,"-" F  S DGI=$O(DGDX(DGI)) Q:'+DGI  Q:DGDX(DGI)=" "  W ?10,DGDX(DGI),!
  1. Q K ICDDMS,ICDDRG,ICDDX,ICDEXP,ICDMDC,ICDPRC,ICDRTC,ICDTRS,ICDDATE Q