Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DIC0

DIC0.m

Go to the documentation of this file. 
  1. DIC0 ;SFISC/TKW-Lookup routine utilities called by DIC ;12/10/99  12:10 [ 04/02/2003   8:25 AM ]
  1.  ;;22.0;VA FileMan;**1001**;APR 1, 2003
  1.  ;;22.0;VA FileMan;**4,20**;Mar 30, 1999
  1.  ;Per VHA Directive 10-93-142, this routine should not be modified.
  1.  ;
  1. D ; Reset back to starting index for lookup.
  1.  S D=DINDEX("START") K DINDEX S (DINDEX,DINDEX("START"))=D,DINDEX("WAY")=1
  1.  S:$D(DID(1)) DID(1)=2
  1.  N DIFLAGS S DIFLAGS="4l"_$P("M^",U,DIC(0)["M")
  1.  D INDEX^DICUIX(.DIFILEI,DIFLAGS,.DINDEX,"",.DIVAL)
  1.  Q
  1.  ;
  1. SETVAL ; If custom lookup routine (like MTLU) comes in to entry point after ASK, we need to set up the lookup values.
  1.  K DIVAL,DIALLVAL D CHKVAL
  1.  I DIVAL(0) D CHKVAL1(DINDEX("#"),.DIVAL,DIC(0),DIC(0),.DIALLVAL)
  1.  Q
  1.  ;
  1. INIT ; Initialize variables at all entry points in ^DIC.
  1.  I '$D(DIFILEI)#2 D GETFILE(.DIC,.DIFILEI,.DIENS) Q:DIFILEI=""
  1.  I '$D(@(DIC_"0)")),'$D(DIC("P")),$E(DIC,1,6)'="^DOPT(" S DIC("P")=$$GETP^DIC0(DIFILEI) I DIC("P")="" S Y=-1 D Q^DIC2 Q
  1.  I $G(DO)="" K DO D GETFA^DIC1(.DIC,.DO)
  1.  S (DINDEX,DINDEX("START"))=D,DINDEX("WAY")=1
  1.  D INDEX^DICUIX(.DIFILEI,"4l",.DINDEX,"",.DIVAL)
  1.  I DIC(0)["V" S DIASKOK=1
  1.  S Y=-1 I DIC(0)["Z" K Y(0)
  1.  Q
  1.  ;
  1. CHKVAL ; Check lookup values input by user.
  1.  N I I $G(X)="" S X=$G(X(1))
  1.  S DIVAL(0)=0,DIVAL(1)=X F I=2:1:DINDEX("#") S DIVAL(I)=$G(X(I))
  1.  N J,DIOUT S DIOUT=0
  1.  F I=1:1:DINDEX("#") S J=$G(DIVAL(I)) I J]"" D  Q:DIOUT
  1.  . I DINDEX("#")>1 S X(I)=J
  1.  . I J["^" S (DUOUT,DIOUT)=1,DIVAL(0)=0 Q
  1.  . I J?1."?" K DIVAL S DIVAL(0)=0,X=$E(J,1,2),DIOUT=1 Q
  1.  . S DIVAL(0)=DIVAL(0)+1 Q
  1.  Q
  1.  ;
  1. CHKVAL1(DIXNO,DIVAL,DIFLAGS,DIC0,DIALLVAL) ; Check for errors with values, flags,index.
  1.  N DIERROR,I S DIALLVAL=1 D
  1.  . I '$D(DIC0),DIFLAGS'["l" D  Q:$G(DIERROR)
  1.  . . S I=$O(DIVAL(99999),-1) I I>DIXNO S DIERROR=8093 Q
  1.  . . S:DIXNO>1&(DIFLAGS["M") DIERROR=8095 Q
  1.  . F I=1:1:DIXNO S DIVAL(I)=$G(DIVAL(I)) D:DIVAL(I)=""
  1.  . . I DIFLAGS["X",DIFLAGS'["l" S DIERROR=8094 Q
  1.  . . S DIALLVAL=0 Q
  1.  . Q
  1.  I $D(DIERROR) D
  1.  . I '$D(DIC0) D ERR^DICF4(DIERROR) Q
  1.  . K DIVAL S DIVAL(0)=0 Q:DIC0'["E"  W $C(7),!,$$EZBLD^DIALOG(DIERROR) Q
  1.  Q
  1.  ;
  1. CHKVAL2(DIXNO,DIVAL,DIC0,DDS) ; Check lookup values for control characters or too long.
  1.  N I,J,DIER S DIER=""
  1.  F I=1:1:DIXNO S J=$G(DIVAL(I)) D:J]""  Q:DIER
  1.  . I J'?.ANP S DIER=204 Q
  1.  . I J?1.N.1".".N,($L($P(J,"."))>25!($L($P(J,".",2))>25)) S DIER=208 Q
  1.  . I ($L(J)-255)>0 S DIER=209
  1.  . Q
  1.  Q:'DIER
  1.  D:DIC0["Q"
  1.  . W $C(7) Q:DIC(0)'["E"
  1.  . I '$D(DDS) W !,$$EZBLD^DIALOG(DIER) Q
  1.  . N DDH S DDH=1,DDH(1,"T")="  **  "_$$EZBLD^DIALOG(DIER)
  1.  . S DDC=7,DDD=1 D LIST^DDSU
  1.  . Q
  1.  K DIVAL S DIVAL(0)=0
  1.  Q
  1.  ;
  1. KILL2 K DIVAL,DIALLVAL
  1. KILL1 K DIFILEI,DINDEX,DIMAXLEN,DIENS Q
  1.  ;
  1. GETFILE(DIC,DIFILE,DIENS) ; Return file number, global references, IEN string and KEY fields data.
  1.  S DIFILE="" I $G(DIC)="" Q
  1.  I +$P(DIC,"E")'=DIC N DIDIC M DIDIC=DIC N DIC S DIDIC=$$CREF^DILF(DIDIC),DIDIC=$NA(@DIDIC),DIDIC=$$OREF^DILF(DIDIC) M DIC=DIDIC K DIDIC
  1.  N DA
  1.  I +$P(DIC,"E")=DIC D
  1.  . S DIFILE=DIC,DIC=$G(^DIC(DIC,0,"GL")) Q:DIC]""
  1.  . S DIC=DIFILE,DIFILE="" Q
  1.  E  D
  1.  . S DIFILE=$G(@(DIC_"0)")) I DIFILE]"" S DIFILE=+$P(DIFILE,U,2) Q
  1.  . S DIFILE=+$G(DIC("P")) Q:DIFILE
  1.  . S DIFILE=$$FILENUM^DILIBF(DIC) Q
  1.  Q:DIFILE=""
  1.  S DIENS=","
  1.  I DIC(0)'["p" D SETIEN(DIC,DIFILE,.DIENS) Q:DIFILE=""
  1.  S DIFILE(DIFILE,"O")=DIC
  1.  S DIFILE(DIFILE)=$$CREF^DILF(DIC)
  1.  N I S I=$O(^DD("KEY","AP",DIFILE,"P",0)) Q:'I
  1.  S DIFILE(DIFILE,"KEY","IEN")=DIENS
  1.  N F,X F F=0:0 S F=$O(^DD("KEY",I,2,F)) Q:'F  S X=$G(^(F,0)) D
  1.  . S DIFILE(DIFILE,"KEY",+$P(X,U,2),+$P(X,U,3),+X)="" Q
  1.  Q
  1.  ;
  1. SETIEN(DIC,DIFILE,DIENS) ; Set DIENS from global root
  1.  N F,G,I,J,K,DIDA
  1.  S F=$$FNO^DILIBF(DIFILE) I F="" S DIFILE="" Q
  1.  S G=$G(^DIC(F,0,"GL")) I G="" S DIFILE="" Q
  1.  S F=$P(DIC,G,2)
  1.  S K=0 F I=1:2 S J=$P(F,",",I) Q:J=""  S K=K+1,J(K)=J
  1.  S DIDA="" F J=1:1:K S DIDA(K+1-J)=J(J)
  1.  S DIENS=$$IENS^DILF(.DIDA) Q
  1.  ;
  1. GETP(DISUB) ; Return DIC("P") for a subfile DIFILE.
  1.  N DIFILE S DIFILE=$G(^DD(DISUB,0,"UP")) Q:'DIFILE ""
  1.  N DIFIELD S DIFIELD=$O(^DD(DIFILE,"SB",DISUB,0)) Q:'DIFIELD ""
  1.  Q $P($G(^DD(DIFILE,DIFIELD,0)),U,2)
  1.  ;
  1. DSPH ; Display name of indexed fields when DIC(0)["T" (called from DICF2)
  1.  Q:$G(DS(0,"HDRDSP",DIFILEI))  S DS(0,"HDRDSP",DIFILEI)=1
  1.  W ! N I S I=($G(DICR))*2 W:I ?I
  1.  W "  Lookup: "
  1.  I $G(DICR) S I=$G(@(DIC_"0)")) I I]"" W $P(I,U)_"  "
  1.  F I=1:1:DINDEX("#") W DINDEX(I,"PROMPT")_$P(",  ^",U,I<DINDEX("#"))
  1.  Q
  1.  ;
  1.  ; Error messages:
  1.  ; 204  The input value contains control character
  1.  ; 349  String too long by |1| character(s)!
  1.  ; 8093 Too many lookup values for this index.
  1.  ; 8094 Not enough lookup values provided for an e
  1.  ; 8095 Only one compound index allowed on a looku
  1.  ;