Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMRAY21

GMRAY21.m

Go to the documentation of this file. 
  1. GMRAY21 ;SLC/DAN Post-init for patch 21 ;12/23/04  12:17
  1.  ;;4.0;Adverse Reaction Tracking;**21**;Mar 29, 1996
  1.  ;
  1.  ;DBIA SECTION
  1.  ;10063 - %ZTLOAD
  1.  ;3744  - $$TESTPAT^VADPT
  1.  ;10013 - DIK
  1.  ;10103 - XLFDT
  1.  ;10070 - XMD
  1.  ;10141 - XPDUTL
  1.  ;
  1. PRE ;Pre-install converts IODINE to allergy type of drug
  1.  N DIE,DA,DR
  1.  S DIE="^GMRD(120.82,",DA=$O(^GMRD(120.82,"B","IODINE",0)),DR="1////D"
  1.  I DA D ^DIE
  1.  Q
  1.  ;
  1. Q ;Entry point to queue process during install
  1.  N ZTRTN,ZTDESC,ZTIO,ZTDTH,ZTSK
  1.  S ZTRTN="DQ^GMRAY21",ZTDESC="GMRA*4*21 POST INSTALL ROUTINE",ZTIO="",ZTDTH=$H
  1.  D ^%ZTLOAD I '$G(ZTSK) D BMES^XPDUTL("POST INSTALL NOT QUEUED - RUN DQ^GMRA21 AFTER INSTALL FINISHES") Q
  1.  D BMES^XPDUTL("Post-install queued as task # "_$G(ZTSK))
  1.  Q
  1.  ;
  1. DQ ;Dequeue
  1.  N PROB,GMRAIOD
  1.  D POST,IODINE,ADDB,MAIL
  1.  Q
  1.  ;
  1. POST ;Post-init entry point
  1.  N DA,GMRAI,GMRA0,LCV,DIK
  1.  ;Check assessment level in 120.86 and make sure it makes the patient's actual assessment level
  1.  S GMRAI=0 F  S GMRAI=$O(^GMR(120.86,GMRAI)) Q:'+GMRAI  I $P(^(GMRAI,0),U,2),$$NKASCR^GMRANKA(GMRAI) S DIK="^GMR(120.86,",DA=GMRAI D ^DIK ;Delete assessment if patient doesn't have allergies and assessment is set to "has allergies"
  1.  ;Find entries in 120.8 that are missing the reactant or are missing additional required data and take appropriate action.
  1.  S GMRAI=0 F  S GMRAI=$O(^GMR(120.8,GMRAI)) Q:'+GMRAI  D
  1.  .S GMRA0=$G(^GMR(120.8,GMRAI,0))
  1.  .I GMRA0=""!($L(GMRA0,"^")=1)!($P(GMRA0,"^",2,3)="^") S DIK="^GMR(120.8,",DA=GMRAI D ^DIK Q  ;Delete entry if no zero node or only 1 piece on zero node or missing reactant data
  1.  .I $P(GMRA0,U,6)="o" D CHECKOBS
  1.  ;Check observed data to make sure it's matched to the right patient
  1.  S LCV=0 F  S LCV=$O(^GMR(120.85,LCV)) Q:'+LCV  D
  1.  .S GMRA0=$G(^GMR(120.85,LCV,0)) Q:GMRA0=""
  1.  .I $P(GMRA0,U,2)'=$P($G(^GMR(120.8,$P(GMRA0,U,15),0)),U) S DIK="^GMR(120.85,",DA=LCV D ^DIK
  1.  Q
  1.  ;
  1.  ;
  1. CHECKOBS ;Check observation data to make sure it's present and accurate
  1.  N J
  1.  Q:$D(^GMR(120.8,GMRAI,"ER"))!($$TESTPAT^VADPT($P(GMRA0,U)))!($$DECEASED^GMRAFX($P(GMRA0,U)))  ;Stop if allergy entered in error, test patient or deceased patient
  1.  I $P(GMRA0,U,12)=1 D
  1.  .I '$D(^GMR(120.85,"C",GMRAI)) S PROB($P(GMRA0,U),GMRAI)="OBS" Q  ;Marked as observed but no data
  1.  .S J=0 F  S J=$O(^GMR(120.85,"C",GMRAI,J)) Q:'+J  I '$O(^GMR(120.85,J,2,0)) S PROB($P(GMRA0,U),GMRAI)="SS" ;Has observed data but no sign/symptoms
  1.  Q
  1.  ;
  1. MAIL ;Send message indicating post install is finished
  1.  N XMSUB,XMTEXT,XMDUZ,XMY,XMZ,GMRATXT,DFN,PCNT,VADM,CNT,IEN
  1.  S XMDUZ="PATCH GMRA*4*21 POST-INSTALL",XMY(.5)="" S:$G(DUZ) XMY(DUZ)=""
  1.  S GMRATXT(1)="The post-install routine for patch GMRA*4*21"
  1.  S GMRATXT(2)="finished on "_$$FMTE^XLFDT($$NOW^XLFDT)_"."
  1.  S GMRATXT(3)=""
  1.  S CNT=3 I $D(PROB) D
  1.  .S CNT=CNT+1,GMRATXT(CNT)="The following patients have observed allergy entries that are"
  1.  .S CNT=CNT+1,GMRATXT(CNT)="signed off (accepted) but are missing required data.  Please review each"
  1.  .S CNT=CNT+1,GMRATXT(CNT)="entry and update (if data is known), mark it as entered in error,"
  1.  .S CNT=CNT+1,GMRATXT(CNT)="or leave it alone."
  1.  .S CNT=CNT+1,GMRATXT(CNT)=""
  1.  .S PCNT=0
  1.  .F  S PCNT=$O(PROB(PCNT)) Q:'+PCNT  D
  1.  ..S DFN=PCNT D DEM^VADPT
  1.  ..S IEN=0 F  S IEN=$O(PROB(PCNT,IEN)) Q:'+IEN  D
  1.  ...S CNT=CNT+1
  1.  ...S GMRATXT(CNT)=VADM(1)_"  "_VA("BID")_"  "_$P(^GMR(120.8,IEN,0),U,2)_" missing "_$S(PROB(PCNT,IEN)="OBS":"observation date",1:"sign/symptoms")
  1.  ..S CNT=CNT+1,GMRATXT(CNT)=""
  1.  I $D(GMRAIOD) D
  1.  .S CNT=CNT+1,GMRATXT(CNT)=$$REPEAT^XLFSTR("*",75),CNT=CNT+1,GMRATXT(CNT)=""
  1.  .S CNT=CNT+1,GMRATXT(CNT)="The following patients have had their IODINE allergies updated.",CNT=CNT+1,GMRATXT(CNT)="You should review them for accuracy.",CNT=CNT+1,GMRATXT(CNT)=""
  1.  .S DFN=0 F  S DFN=$O(GMRAIOD(DFN)) Q:'+DFN  K VADM D DEM^VADPT S CNT=CNT+1,GMRATXT(CNT)=VADM(1)_"  "_VA("BID")
  1.  S XMTEXT="GMRATXT(",XMSUB="PATCH GMRA*4*21 Post Install COMPLETED"
  1.  D ^XMD
  1.  Q
  1.  ;
  1. IODINE ;Find existing IODINE allergies and update them
  1.  N GMRAIODN,GMRAI,PAT,GMRAPA,GMRAAR
  1.  S GMRAIODN=$O(^GMRD(120.82,"B","IODINE",0)) Q:'+GMRAIODN  ;No IODINE entry
  1.  S (GMRAAR,GMRAIODN)=GMRAIODN_";GMRD(120.82,"
  1.  S GMRAI=0 F  S GMRAI=$O(^GMR(120.8,"C","IODINE",GMRAI)) Q:'+GMRAI  D
  1.  .S PAT=$P($G(^GMR(120.8,GMRAI,0)),U) Q:'+PAT  ;No patient
  1.  .Q:$P($G(^GMR(120.8,GMRAI,0)),U,3)'=GMRAIODN  ;Not the one we're looking for
  1.  .Q:$D(^GMR(120.8,GMRAI,"ER"))!($$DECEASED^GMRAFX(PAT))  ;Stop if entered in error or patient has expired
  1.  .S GMRAPA=GMRAI
  1.  .S DIE="^GMR(120.8,",DA=GMRAPA,DR="3.1////D" D ^DIE ;Update allergy type to drug
  1.  .D DELMUL^GMRAFX3(2),DELMUL^GMRAFX3(3) ;Delete any existing ingredients and drug classes for this allergy
  1.  .D UPDATE^GMRAPES1 ;add ingredients and drug classes from IODINE entry
  1.  .S GMRAIOD(PAT)=""
  1.  .Q
  1.  Q
  1.  ;
  1. ADDB ;Add B xref to reactions multiple in 120.85
  1.  N IEN,DA,DIK
  1.  S IEN=0 F  S IEN=$O(^GMR(120.85,IEN)) Q:'+IEN  I $D(^GMR(120.85,IEN,2)) D
  1.  .S $P(^GMR(120.85,IEN,2,0),U,2)="120.8502P"
  1.  .S DA(1)=IEN,DIK="^GMR(120.85,DA(1),2," D IXALL^DIK
  1.  Q