Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMRCMED

GMRCMED.m

Go to the documentation of this file. 
  1. GMRCMED ;SLC/JFR - MEDICINE INTERFACE ROUTINES; 2/20/01 13:32
  1.  ;;3.0;CONSULT/REQUEST TRACKING;**15,47**;DEC 27, 1997
  1.  ;
  1.  ; This routine invokes IA #147,#2757,#3160,#3171
  1.  ;
  1. SET(NUM) ; set selected med result into GMRCMEDR
  1.  I NUM<1!(NUM>VALMCNT) D  Q
  1.  . W !,$C(7),NUM_" is not a valid selection. "
  1.  . W !,"Choose a number between 1 and "_VALMCNT
  1.  I '$D(^TMP("GMRCR",$J,"DT",NUM,1)) D  Q
  1.  . D EXAC^GMRCADC("The displayed item is not selectable")
  1.  I $D(GMRCMEDR) D RESETIT(GMRCMEDR)
  1.  S GMRCMEDR=NUM
  1.  D CNTRL^VALM10(NUM,1,80,IORVON,IORVOFF)
  1.  D WRITE^VALM10(NUM)
  1.  S VALMBCK=""
  1.  Q
  1. RESETIT(NUM) ;return prev. selected number to normal video 
  1.  D CNTRL^VALM10(NUM,1,80,IOINORM,IOINORM)
  1.  D WRITE^VALM10(NUM)
  1.  S VALMBCK="" K GMRCSEL
  1.  Q
  1. RESULTS(ROOT,GMRCDFN) ;get list of results from Medicine
  1.  ; ROOT = "MCAR(691","MCAR(691.5" etc. (global root w/o comma)
  1.  ; return list formatted in ^TMP("GMRCMC",$J
  1.  N S5,CNT,REC
  1.  K ^TMP("GMRCMC",$J)
  1.  S S5=ROOT D EN^MCARPS2(GMRCDFN)
  1.  I '$D(^TMP("OR",$J,"MCAR")) D  Q
  1.  . ;D EXAC^GMRCADC("No results found for"_$P(ROOT,U,2))
  1.  S CNT=1,REC=0
  1.  F  S REC=$O(^TMP("OR",$J,"MCAR","OT",REC)) Q:'REC  D
  1.  . N MCDATA,DATA,ONEDATA
  1.  . S MCDATA=^TMP("OR",$J,"MCAR","OT",REC),DATA=""
  1.  . Q:$D(^GMR(123,"R",$P(MCDATA,U,2)_";"_ROOT_","))
  1.  . Q:$$SCRNDRFT($P(MCDATA,U,2),$P(ROOT,"(",2))
  1.  . S DATA=$$SETSTR^VALM1(CNT,DATA,2,$L(REC))
  1.  . S DATA=$$SETSTR^VALM1($P(MCDATA,U),DATA,6,23)
  1.  . S DATA=$$SETSTR^VALM1($P(MCDATA,U,6),DATA,30,$L($P(MCDATA,U,6)))
  1.  . S DATA=$$SETSTR^VALM1($P(MCDATA,U,7),DATA,50,$L($P(MCDATA,U,7)))
  1.  . S ^TMP("GMRCR",$J,"DT",CNT,0)=DATA
  1.  . ;S ONEDATA=REC_U_$P(MCDATA,U,2)_";"_ROOT_","_U_$P(MCDATA,U,3,5)
  1.  . ;S ONEDATA=ONEDATA_U_$P(MCDATA,U,11)
  1.  . S ONEDATA=$P(MCDATA,U,2)_";"_ROOT_","
  1.  . S ^TMP("GMRCR",$J,"DT",CNT,1)=ONEDATA
  1.  . S CNT=CNT+1
  1.  K ^TMP("OR",$J,"MCAR")
  1.  Q 
  1. PHDR ;set protocols into actions
  1.  S VALMSG=$$CJ^XLFSTR("Select action or item number    ?? for help",80)
  1.  S XQORM("M")=3
  1.  D SHOW^VALM
  1.  S XQORM("#")=$O(^ORD(101,"B","GMRCACT SELECT MED RESULT",0))_"^1:"_VALMCNT
  1.  S XQORM("KEY","EX")=$O(^ORD(101,"B","GMRCACT QUIT",0))_"^1"
  1.  S XQORM("KEY","Q")=$O(^ORD(101,"B","GMRCACT QUIT",0))_"^1"
  1.  S XQORM("KEY","CLOSE")=$O(^ORD(101,"B","GMRCACT QUIT",0))_"^1"
  1.  S XQORM("KEY","NX")=$O(^ORD(101,"B","GMRCACT NEXT SCREEN",0))_"^1"
  1.  S XQORM("KEY","AR")=$O(^ORD(101,"B","GMRCACT ASSOCIATE RESULTS",0))_"^1"
  1.  S XQORM("KEY","DR")=$O(^ORD(101,"B","GMRCACT DISPLAY MED RESULT",0))_"^1"
  1.  Q
  1.  ;
  1. SELECT(CNT) ;grab an item from list
  1.  N DIR,DUOUT,DTOUT,DIRUT,X,Y
  1.  S DIR(0)="NO^1:"_CNT,DIR("A")="Select item"
  1.  D ^DIR I $D(DIRUT) Q 0
  1.  Q +Y
  1.  ;
  1. DISPRES(ITEM) ;
  1.  I '+$G(^TMP("GMRCR",$J,"DT",1,1)) D  Q  ; no result there
  1.  . D EXAC^GMRCADC("There are no results to display")
  1.  N GMRCDFN
  1.  I '$G(ITEM),'$G(GMRCMEDR) D  Q:'ITEM
  1.  . S ITEM=$$SELECT(VALMCNT)
  1.  . D SET(ITEM)
  1.  I $G(GMRCMEDR) S ITEM=GMRCMEDR
  1.  N I,GMRCRES,GMRCDFN,GMRCVTIT
  1.  S GMRCRES=$G(^TMP("GMRCR",$J,"DT",ITEM,1))
  1.  Q:'$L(GMRCRES)
  1.  M ^TMP("GMRCR",$J,"DTSV")=^TMP("GMRCR",$J,"DT")
  1.  K ^TMP("GMRCR",$J,"DT")
  1.  S GMRCDFN=$G(DFN)
  1.  D START^ORWRP(80,"EN^MCAPI(GMRCRES)")
  1.  I '$D(^TMP("ORDATA",$J,1)) D  Q
  1.  . S ^TMP("GMRCR",$J,"DTLIST",1,0)="Unable to locate result"
  1.  S I=0 F  S I=$O(^TMP("ORDATA",$J,1,I)) Q:'I  D
  1.  . S ^TMP("GMRCR",$J,"DTLIST",I,0)=^TMP("ORDATA",$J,1,I)
  1.  K ^TMP("ORDATA",$J) ; clean up from OR WORKSTATION
  1.  S DFN=$S(+GMRCDFN:GMRCDFN,$G(ORVP):+ORVP,1:0)
  1.  S GMRCVTIT="Medicine Result Display"
  1.  S VALMCNT=$O(^TMP("GMRCR",$J,"DTLIST",999999),-1)
  1.  D EN^VALM("GMRC DETAILED DISPLAY")
  1.  M ^TMP("GMRCR",$J,"DT")=^TMP("GMRCR",$J,"DTSV")
  1.  K ^TMP("GMRCR",$J,"DTSV")
  1.  S VALMBCK="R",VALMCNT=$O(^TMP("GMRCR",$J,"DT",999999),-1)
  1.  Q
  1.  ;
  1. AR(ITEM) ;associate specific result and complete consult
  1.  I '+$G(^TMP("GMRCR",$J,"DT",1,1)) D  Q  ; no result there
  1.  . D EXAC^GMRCADC("There are no results to associate")
  1.  N DIR,X,Y,RESTXT,RESULT
  1.  I '$G(ITEM),'$G(GMRCMEDR) D  Q:'ITEM
  1.  . S ITEM=$$SELECT(VALMCNT)
  1.  . D SET(ITEM)
  1.  I $G(GMRCMEDR) S ITEM=GMRCMEDR
  1.  D FULL^VALM1
  1.  S RESTXT=$E(^TMP("GMRCR",$J,"DT",ITEM,0),6,80)
  1.  S RESULT=^TMP("GMRCR",$J,"DT",ITEM,1) Q:'+RESULT
  1.  I $D(^GMR(123,"R",RESULT)) D  Q
  1.  . D EXAC^GMRCADC("This result is already associated with a procedure.")
  1.  S DIR(0)="YA",DIR("B")="NO"
  1.  S DIR("A",1)="",DIR("A",2)="   "_RESTXT,DIR("A",3)=""
  1.  S DIR("A")="Are you sure you want to associate this result? "
  1.  D ^DIR I Y<1 Q
  1.  D MEDCOMP(GMRCO,RESULT,$$NOW^XLFDT,DUZ)
  1.  Q
  1. MEDCOMP(GMRCDA,GMRCRSLT,GMRCAD,GMRCORNP,GMRCALRT) ;add medicine result
  1.  ; update status and send alerts
  1.  ;  Input:
  1.  ;   GMRCDA - ien from file 123
  1.  ;   GMRCRSLT - medicine result in var ptr form (e.g. "19;MCAR(691.5,")
  1.  ;   GMRCAD   - FM date/time of action (optional)
  1.  ;   GMRCORNP - DUZ of person taking action
  1.  ;   GMRCALRT - array of users to receive alert  (optional)
  1.  ;
  1.  I '$D(GMRCDA)!'$D(GMRCRSLT) Q
  1.  N GMRCO,GMRCSTS,GMRCA,GMRCDR,GMRCTYP,MSG
  1.  S GMRCO=GMRCDA,GMRCA=10,GMRCSTS=2
  1.  S GMRCDR="8////^S X=GMRCSTS;9////^S X=GMRCA;11////^S X=GMRCRSLT"
  1.  D STATUS^GMRCP
  1.  I $D(GMRCAD) D AUDIT^GMRCP
  1.  I '$D(GMRCAD) D AUDIT0^GMRCP
  1.  D ADDRSLT^GMRCTIUA(GMRCDA,GMRCRSLT)
  1.  S MSG="NEW RESULT ASSOCIATED",GMRCDFN=$P(^GMR(123,GMRCO,0),U,2)
  1.  D MSG^GMRCP(GMRCDFN,MSG,GMRCDA,23,.GMRCALRT,0)
  1.  S GMRCTYP=$P(^GMR(123,+GMRCDA,0),U,17)
  1.  D EN^GMRCHL7(GMRCDFN,GMRCDA,GMRCTYP,"","RE",$G(GMRCORNP),"")
  1.  Q
  1. REFRESH(GMRCIEN) ;update list of available results
  1.  N MCROOT,MCPROC,GMRCPROC
  1.  I $G(GMRCMEDR) D RESETIT(GMRCMEDR)
  1.  K ^TMP("GMRCR",$J,"DT"),GMRCMEDR
  1.  S GMRCPROC=$P(^GMR(123,GMRCIEN,0),"^",8)
  1.  S MCROOT=$$GET1^DIQ(697.2,+$P(^GMR(123.3,+GMRCPROC,0),U,5),1)
  1.  D RESULTS^GMRCMED(MCROOT,$P(^GMR(123,+GMRCIEN,0),U,2))
  1.  I '$O(^TMP("GMRCR",$J,"DT",0)) D
  1.  . S ^TMP("GMRCR",$J,"DT",1,0)="No further results to associate"
  1.  S VALMCNT=$O(^TMP("GMRCR",$J,"DT",""),-1)
  1.  S VALMBCK="R"
  1.  Q
  1.  ;
  1. SCRNDRFT(GMRCMCDA,GMRCMCFL) ;screen out draft or marked for del med results
  1.  ; Input:
  1.  ;   GMRCDA   - ien from a MEDICINE file
  1.  ;   GMRCMCFL - file # from MEDICINE  (e.g. 691, 691.5, 699 etc.)
  1.  ; Output: Boolean 1=screen it out 0=include it
  1.  ;
  1.  N GMRCMCST,GMRCMFD
  1.  I '$D(GMRCMCDA)!('$D(GMRCMCFL)) Q 0
  1.  S GMRCMCST=$$GET1^DIQ(GMRCMCFL,GMRCMCDA,1506,"I") ;get release code
  1.  S GMRCMCST=$S(GMRCMCST="D":0,GMRCMCST="PD":0,1:1) ;no D or PD
  1.  S GMRCMFD=$$GET1^DIQ(GMRCMCFL,GMRCMCDA,1511,"I") ;marked for del?
  1.  I GMRCMFD=1 Q 1 ;marked for del
  1.  I GMRCMCST=0 Q 1 ;screen out draft or prob draft
  1.  Q 0