Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMRCP5D

GMRCP5D.m

Go to the documentation of this file. 
  1. GMRCP5D ;SLC/DCM,RJS,JFR,WAT - Print Consult form 513 (Gather Data - Addendums, Headers, Service reports and Comments) ;09/10/08
  1.  ;;3.0;CONSULT/REQUEST TRACKING;**4,12,15,22,29,35,38,61,65**;Dec 27, 1997;Build 7
  1.  ;
  1.  ;This routine invokes the following ICR(s):
  1.  ;2056 $$GET1^DIQ, 2541 $$KSP^XUPARAM, 10103 $$FMTE^XLFDT, 10104 $$UP^XLFSTR, 10061 VADPT API
  1.  ;10040 ^SC(, 4156 $$CVEDT^DGCV, 10060 ^VA(200
  1.  ;
  1. FORMAT(GMRCIFN,GMRCRD,PAGEWID) ;
  1.  ;
  1.  I $L($P(GMRCRD,U,15)) D
  1.  .I $O(^TMP("GMRCR",$J,"MCAR",0)) D
  1.  ..N GMRCSVC
  1.  ..S GMRCSVC=$P($G(^GMR(123.5,+$P(GMRCRD,U,5),0)),U,1)
  1.  ..S:$L(GMRCSVC) GMRCSVC=GMRCSVC_" "
  1.  ..;
  1.  ..; Medicine Results?
  1.  ..S GMRCR0=0 F  S GMRCR0=$O(^TMP("GMRCR",$J,"MCAR",GMRCR0)) Q:'GMRCR0  D
  1.  ...D SUB("H","SREP",GMRCR0,$$CENTER(GMRCSVC_"Service Report #"_GMRCR0_" continued."))
  1.  ...D SUB("H","SREP",GMRCR0," ")
  1.  ...D BLD("SREP",GMRCR0,1,0,$$CENTER("Medicine Package Report"))
  1.  ...D BLD("SREP",GMRCR0,1,0,"")
  1.  ...N LN
  1.  ...S LN=0 F  S LN=$O(^TMP("GMRCR",$J,"MCAR",GMRCR0,LN)) Q:'LN  D
  1.  ....D BLD("SREP",GMRCR0,1,0,$G(^TMP("GMRCR",$J,"MCAR",GMRCR0,LN,0)))
  1.  ;
  1.  ; Build Processing Activities
  1.  S GMRCR0=0 F  S GMRCR0=$O(^GMR(123,GMRCIFN,40,GMRCR0)) Q:'GMRCR0  D
  1.  .N GMRCR1,GMRC400,CMT,USER,GMRCDT,RPRV,GMRC402,GMRCISIT
  1.  .S GMRCR1=+$O(^GMR(123,GMRCIFN,40,GMRCR0,0)) Q:GMRCR1'=1
  1.  .S GMRC400=$G(^GMR(123,GMRCIFN,40,GMRCR0,0))
  1.  .S GMRC402=$G(^GMR(123,GMRCIFN,40,GMRCR0,2))
  1.  .S CMT=$$PRCMT^GMRCP5B(+$P(GMRC400,U,2)) Q:'$L(CMT)
  1.  .S GMRCDT=$P(GMRC400,U,3) S:'GMRCDT GMRCDT=$P(GMRC400,U,1)
  1.  .S GMRCDT=$$EXDT(GMRCDT)_" "_$P(GMRC402,U,3)
  1.  .;Following lines modified in patch *38
  1.  .;I $P(^GMR(123,GMRCIFN,0),U,23) D  ;commented out
  1.  .;.S GMRCISIT=$$GET1^DIQ(4,$P(^GMR(123,GMRCIFN,0),U,23),.01)  ;commented out
  1.  .;.S GMRCISIT="Entered at: "_GMRCISIT  ;commented out
  1.  .I $L(GMRC402) D  ;ADDED
  1.  ..S GMRCISIT=$$GET1^DIQ(123,GMRCIFN,.07)  ;ADDED
  1.  .I '$D(GMRCISIT) D  ;ADDED
  1.  ..S GMRCISIT=$$KSP^XUPARAM("INST")  ;ADDED
  1.  ..I GMRCISIT'="" S GMRCISIT=$$GET1^DIQ(4,GMRCISIT,.01)  ;ADDED
  1.  ..I GMRCISIT="" S GMRCISIT=$$GET1^DIQ(123,GMRCIFN,.05)  ;ADDED
  1.  .S GMRCISIT="Entered at: "_GMRCISIT  ;ADDED
  1.  .;End of modifications for patch *38
  1.  .S RPRV=$$GET1^DIQ(200,+$P(GMRC400,U,4),.01)
  1.  .I '$L(RPRV) S RPRV=$P(GMRC402,U,2)
  1.  .S:($L(RPRV)) RPRV="Responsible Person: "_RPRV
  1.  .S USER=$$GET1^DIQ(200,+$P(GMRC400,U,5),.01)
  1.  .I '$L(USER) S USER=$P(GMRC402,U)
  1.  .S USER="Entered by: "_USER_" - "_GMRCDT
  1.  .D SUB("H","COM",GMRCR0,CMT_" Comment ("_USER_") continued.")
  1.  .D SUB("H","COM",GMRCR0," ")
  1.  .D BLD("COM",GMRCR0,1,0,"")
  1.  .D BLD("COM",GMRCR0,1,0,$$CENTER("("_CMT_" Comment)"))
  1.  .I $P(GMRC400,U,2)=17!($P(GMRC400,U,2)=25) D
  1.  .. N FWDLN,FWDRS
  1.  .. S FWDLN="Forwarded from: "
  1.  .. S FWDRS=$P($G(^GMR(123,GMRCIFN,40,GMRCR0,3)),U)
  1.  .. I $L(FWDRS) S FWDLN=FWDLN_FWDRS
  1.  .. I '$L(FWDRS) S FWDLN=FWDLN_$$GET1^DIQ(123.5,+$P(GMRC400,U,6),.01)
  1.  .. D BLD("COM",GMRCR0,1,5,FWDLN)
  1.  .D BLD("COM",GMRCR0,1,5,USER)
  1.  .D:($L(RPRV)) BLD("COM",GMRCR0,1,5,RPRV)
  1.  .D:($L($G(GMRCISIT))) BLD("COM",GMRCR0,1,5,GMRCISIT)
  1.  .;
  1.  .N GMRCR2 S GMRCR2=0
  1.  .F  S GMRCR2=$O(^GMR(123,GMRCIFN,40,GMRCR0,GMRCR1,GMRCR2)) Q:'GMRCR2  D
  1.  ..D BLD("COM",GMRCR0,1,0,$G(^GMR(123,GMRCIFN,40,GMRCR0,GMRCR1,GMRCR2,0)))
  1.  ;
  1.  Q
  1.  ;
  1. ADDEND(GMRCIFN,GMRCR0,GMRCNDX,GMRCRD,PAGEWID) ;
  1.  ;
  1.  N GMRCADD,GMRCNDX,GMRCR1,GMRCV,TEXT,GMRCX
  1.  ;
  1.  S GMRCADD=0 F  S GMRCADD=$O(^TMP("GMRCR",$J,"RES",GMRCR0,"ADD",GMRCADD)) Q:'GMRCADD  D
  1.  .N GMRCSGNM,GMRCNMDT,GMRCTIT,GMRCMODE,GMRCCSDT,GMRCCTIT,GMRCCSGM
  1.  .;
  1.  .F GMRCV="GMRCSGNM","GMRCNMDT","GMRCTIT","GMRCMODE" D
  1.  ..S @GMRCV=$G(^TMP("GMRCR",$J,"RES",GMRCR0,"ADD",GMRCADD,GMRCV))
  1.  .;
  1.  . F GMRCV="GMRCCSDT","GMRCCTIT","GMRCCSGM","GMRCCSIG" D
  1.  .. S @GMRCV=$G(^TMP("GMRCR",$J,"RES",GMRCR0,"ADD",GMRCADD,GMRCV))
  1.  .S GMRCNDX=$O(^TMP("GMRC",$J,"OUTPUT","RES"," "),-1)+1
  1.  .I $L($G(GMRCRPT)) D SUB("H","RES",GMRCNDX,"Addendum #"_GMRCADD_" To Consult Note #"_GMRCR0_" for "_GMRCRPT_" continued.")
  1.  .I '$L($G(GMRCRPT)) D SUB("H","RES",GMRCNDX,"Addendum #"_GMRCADD_" To Consult Note #"_GMRCR0_" continued.")
  1.  .D SUB("H","RES",GMRCNDX," ")
  1.  .I $L($G(GMRCSGNM)) D
  1.  ..D SUB("F","RES",GMRCNDX," ")
  1.  ..I (GMRCMODE="electronic") S GMRCX=" Addendum Signature: "_GMRCSGNM_" /es/ "_$$EXDT($G(GMRCNMDT))
  1.  ..I '(GMRCMODE="electronic") S GMRCX=" Addendum Author: "_GMRCSGNM S:$L($G(GMRCNMDT)) GMRCX=GMRCX_" Last edited: "_$$EXDT(GMRCNMDT)
  1.  ..D SUB("F","RES",GMRCNDX,GMRCX)
  1.  ..D:$L($G(GMRCTIT)) SUB("F","RES",GMRCNDX,"                     "_GMRCTIT)
  1.  .I $L($G(GMRCCSDT)) D
  1.  ..D SUB("F","RES",GMRCNDX," ")
  1.  ..I (GMRCCSGM="electronic") S GMRCX=" Addendum CoSignature: "_GMRCCSIG_" /es/ "_$$EXDT(GMRCCSDT)
  1.  ..I '(GMRCCSGM="electronic") S GMRCX=" Addendum CoSignature: "_GMRCCSIG_" /chart/ "_$$EXDT(GMRCCSDT)
  1.  ..D SUB("F","RES",GMRCNDX,GMRCX)
  1.  ..D:$L($G(GMRCCTIT)) SUB("F","RES",GMRCNDX,"                       "_GMRCCTIT)
  1.  .D BLD("RES",GMRCNDX,1,0," ")
  1.  .I $L($G(GMRCRPT)) D BLD("RES",GMRCNDX,1,0,$$CENTER("ADDENDUM #"_GMRCADD_" TO CONSULT NOTE #"_GMRCR0_" FOR "_GMRCRPT))
  1.  .I '$L($G(GMRCRPT)) D BLD("RES",GMRCNDX,1,0,$$CENTER("ADDENDUM #"_GMRCADD_" TO CONSULT NOTE #"_GMRCR0))
  1.  .D BLD("RES",GMRCNDX,1,0," ")
  1.  .S GMRCR1=0 F  S GMRCR1=$O(^TMP("GMRCR",$J,"RES",GMRCR0,"ADD",GMRCADD,GMRCR1)) Q:'GMRCR1  D
  1.  ..D BLD("RES",GMRCNDX,1,0,$G(^TMP("GMRCR",$J,"RES",GMRCR0,"ADD",GMRCADD,GMRCR1,0)))
  1.  Q
  1.  ;
  1. HDR ; Header code for form 513
  1.  ;
  1.  ;get and format eligibility info
  1.  N VAEL,VAPA,GMRCPEL,SUB,GMRCFROM
  1.  N CVELIG,CVMARKER ;WAT
  1.  D ELIG^VADPT
  1.  D ADD^VADPT
  1.  S GMRCPEL=$P(VAEL(1),U,2)
  1.  ;
  1.  F SUB=0,1 D
  1.  .N GMRCFLN
  1.  .S GMRCFLN=$P($G(^DPT(GMRCDFN,0)),U,1)
  1.  .S CVELIG=$$CVEDT^DGCV(GMRCDFN) S:$P($G(CVELIG),U,3) CVELIG="CV ELIGIBLE" ;WAT
  1.  .D BLD("HDR",SUB,1,0,GMRCDVL)
  1.  .D BLD("HDR",SUB,1,6,"MEDICAL RECORD")
  1.  .D BLD("HDR",SUB,0,39,"|")
  1.  .D BLD("HDR",SUB,0,45,"CONSULTATION SHEET")
  1.  .D BLD("HDR",SUB,1,0,GMRCDVL)
  1.  .D BLD("HDR",SUB,1,0,GMRCFLN)
  1.  .D BLD("HDR",SUB,0,45,GMRCPEL)
  1.  .D BLD("HDR",SUB,1,0,GMRCSN)
  1.  .D BLD("HDR",SUB,0,16,$$EXDT(GMRCDOB))
  1.  .D BLD("HDR",SUB,0,45,GMRCELIG)
  1.  .D:$G(CVELIG)["CV" BLD("HDR",SUB,1,45,CVELIG)
  1.  ;
  1.  ;                                  ADDRESS LINES 1-3
  1.  F GMRCX=1,2,3 D:$L(VAPA(GMRCX))
  1.  .D BLD("HDR",0,1,0,VAPA(GMRCX))
  1.  .;I GMRCX=1 D BLD("HDR",0,0,51,"Standard Form 513 (Rev 9-77)")
  1.  ;
  1.  ;         CITY              STATE                ZIP CODE
  1.  S GMRCX=VAPA(4)_"   "_$P(VAPA(5),U,2)_"      "_VAPA(6)
  1.  ;
  1.  I $L(VAPA(8)) S GMRCX=GMRCX_"      Phone: "_VAPA(8)   ; TELEPHONE (IF AVAILABLE)
  1.  ;
  1.  D BLD("HDR",0,1,0,GMRCX)
  1.  D BLD("HDR",0,1,0,GMRCDVL)
  1.  D BLD("HDR",0,1,0,"Consult Request: "_$$CONSRQ(GMRCIFN))
  1.  D BLD("HDR",0,1,55,"|Consult No.: "_GMRCIFN)
  1.  ;
  1.  D BLD("HDR",1,1,0,GMRCEQL)
  1.  D BLD("HDR",0,1,0,GMRCDVL)
  1.  ;
  1.  I $G(CMT) D BLD("HDR",0,1,27,"("_$$PRCMT^GMRCP5B(CMT)_")") Q
  1.  ;
  1.  S GMRCFROM=$P($G(^SC(+$P(GMRCRD,U,6),0)),U,1)
  1.  ;
  1.  I '$L(GMRCFROM) D
  1.  .N VAIN
  1.  .D INP^VADPT
  1.  .S GMRCFROM=$P($G(VAIN(4)),U,2)
  1.  .I $L($G(VAIN(5))) S GMRCFROM=GMRCFROM_" (Rm/Bd: "_$G(VAIN(5))_" )"
  1.  ;No location, IFC - consulting site
  1.  I '$L(GMRCFROM),$P(GMRCRD,U,23),$P($G(GMRCRD(12)),U,5)="F" D
  1.  .I $P(GMRCRD,U,21) S GMRCFROM=$$GET1^DIQ(4,$P(GMRCRD,U,21),.01)
  1.  .E  S GMRCFROM=$$GET1^DIQ(4,$P(GMRCRD,U,23),.01)
  1.  ;
  1.  D BLD("HDR",0,1,0,"To: "_$P($G(^GMR(123.5,+$P(GMRCRD,U,5),0)),U,1))
  1.  D BLD("HDR",0,1,5,"From: "_GMRCFROM)
  1.  D BLD("HDR",0,0,49,"|Requested: "_$$EXDT($P(GMRCRD,U,7)))
  1.  ;
  1.  D BLD("HDR",0,1,0,GMRCDVL)
  1.  D BLD("HDR",0,1,0,"Requesting Facility: "_$E(GMRCFAC,1,22))
  1.  I $P(GMRCRD,U,11) D BLD("HDR",0,0,45,"|ATTENTION: "_$E($$GET1^DIQ(200,+$P(GMRCRD,U,11),.01),1,21))
  1.  I $P(GMRCRD,U,23) D
  1.  . D BLD("HDR",0,1,0,"Remote Consult No.: "_GMRCINO)
  1.  . D BLD("HDR",0,1,0,"Role: "_GMRCIRL)
  1.  D BLD("HDR",0,1,0,GMRCEQL)
  1.  ;
  1.  Q
  1.  ;
  1. CENTER(X) ;
  1.  ;
  1.  N TEXT,COL
  1.  S COL=35-($L(X)\2) Q:(COL<1) X
  1.  S $E(TEXT,COL)=X
  1.  Q TEXT
  1.  ;
  1. BLD(SUB,NDX,LINE,TAB,TEXT,RUNTIME) ;
  1.  ;
  1.  Q:'$L($G(SUB))
  1.  N LINECNT
  1.  ;
  1.  F LINECNT=1:1:+LINE S ^TMP("GMRC",$J,"OUTPUT",SUB,NDX,$$LASTLN(SUB,NDX)+1,0)=""
  1.  ;
  1.  S $E(^TMP("GMRC",$J,"OUTPUT",SUB,NDX,$$LASTLN(SUB,NDX),0),TAB+1)=TEXT
  1.  I $L($G(RUNTIME)) S ^TMP("GMRC",$J,"OUTPUT",SUB,NDX,$$LASTLN(SUB,NDX),1)=RUNTIME
  1.  ;
  1.  S GMRCLAST=SUB
  1.  Q
  1.  ;
  1. SUB(ZONE,SUB,NDX,TEXT) ;
  1.  ;
  1.  N NEXT
  1.  S NEXT=$O(^TMP("GMRC",$J,"OUTPUT",SUB,NDX,ZONE," "),-1)+1
  1.  S ^TMP("GMRC",$J,"OUTPUT",SUB,NDX,ZONE,NEXT,0)=TEXT
  1.  Q
  1.  ;
  1. LASTLN(SUB,NDX) ;
  1.  Q +$O(^TMP("GMRC",$J,"OUTPUT",SUB,NDX," "),-1)
  1.  ;
  1. CONSRQ(IFN) ;
  1.  ;
  1.  N PTR,LINK,REF,GMRCRQ
  1.  I +$P(^GMR(123,+IFN,0),U,8) D
  1.  . S GMRCRQ=$P(^GMR(123,+IFN,0),U,8)
  1.  . S GMRCRQ=$$GET1^DIQ(123.3,+GMRCRQ,.01)
  1.  . I '$L(GMRCRQ) S GMRCRQ="Procedure"
  1.  I $L($G(GMRCRQ)) Q GMRCRQ
  1.  I $L($G(^GMR(123,IFN,1.11))) D
  1.  . N SERV,TYPE
  1.  . S SERV=$$UP^XLFSTR($$GET1^DIQ(123.5,$P(^GMR(123,IFN,0),U,5),.01))
  1.  . S TYPE=$$UP^XLFSTR(^GMR(123,IFN,1.11)) I TYPE'=SERV D
  1.  . I TYPE'=SERV S GMRCRQ=$E(^GMR(123,IFN,1.11),1,36)
  1.  Q:$L($G(GMRCRQ)) GMRCRQ Q "Consult"
  1.  ;
  1. EXDT(X) ;EXTERNAL DATE FORMAT
  1.  ;
  1.  N DATE,TIME,HR,MN,PD,Y,%DT
  1.  Q:'$L(X) ""
  1.  I '(X?7N.1".".6N) S %DT="PTS" D ^%DT S X=Y
  1.  Q $$FMTE^XLFDT(X,"5PMZ")
  1.  ;