Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMRVED2

GMRVED2.m

Go to the documentation of this file. 
  1. GMRVED2 ;HIOFO/RM,YH,FT-VITAL SIGNS EDIT SHORT FORM ;11/15/04  10:30
  1.  ;;5.0;GEN. MED. REC. - VITALS;**2**;Oct 31, 2002
  1.  ;
  1.  ; This routine uses the following IAs:
  1.  ; #10035 - ^DPT( references       (supported)
  1.  ; #10061 - ^VADPT calls           (supported)
  1.  ; #10103 - ^XLFDT calls           (supported)
  1.  ; #10104 - ^XLFSTR calls          (supported)
  1.  ; 
  1. EN1 ; SORT PATIENTS ON WARD
  1.  K ^TMP($J)
  1. WSA1 ; SET ^TMP($J, FOR SORT
  1.  D DEM^VADPT,INP^VADPT S GMRRMBD=$S(VAIN(5)'="":VAIN(5),1:"  BLANK"),GMRNAM=$S(VADM(1)'="":VADM(1),1:"  BLANK") D KVAR^VADPT K VA
  1.  S:$S("Aa"[GMREDB:1,$D(GMRROOM($P(GMRRMBD,"-"))):1,1:0) ^TMP($J,GMRRMBD,GMRNAM,DFN)=""
  1.  S DFN=$O(^DPT("CN",GMRWARD(1),DFN))
  1.  Q:DFN=""  G WSA1
  1. EN2 ; BEGIN EDITING WARD VITALS
  1.  I $O(^TMP($J,0))="" S GMROUT=1 Q
  1.  W !,"Begin entering patient vitals." S GMRDT0=GMRVIDT
  1.  S GMRRMBD="" F GMRI=0:0 S GMRRMBD=$O(^TMP($J,GMRRMBD)) Q:GMRRMBD=""!GMROUT  S GMRNAM="" F GMRI=0:0 S GMRNAM=$O(^TMP($J,GMRRMBD,GMRNAM)) Q:GMRNAM=""!GMROUT  F DFN=0:0 S DFN=$O(^TMP($J,GMRRMBD,GMRNAM,DFN)) Q:DFN'>0  D V1 Q:GMROUT
  1.  W !,"Enter return to continue" R X:DTIME Q
  1. V1 ;
  1.  W !!,$S(GMRNAM'="  BLANK":GMRNAM,1:DFN),?$X+10,$S(GMRRMBD'="  BLANK":GMRRMBD,1:""),"  OK? YES// " R GMRX:DTIME
  1.  I GMRX="^"!('$T) S GMROUT=1 Q
  1.  S GMRX=$$UP^XLFSTR(GMRX) I ((GMRX="")!($E(GMRX)="Y")) K GMRTO S GDT=GMRVIDT D EN1^GMRVADM G:GMROUT&'$D(GMRTO) V2 D EN2^GMRVED3 G:GMROUT&'$D(GMRTO) V2 Q
  1.  G:GMRX?1"N".E V2
  1.  W !,"ANSWER YES OR NO" G V1
  1. V2 ;
  1.  W !!,"Do you wish to stop looping through names? YES//" R GMRX:DTIME
  1.  S GMRX=$$UP^XLFSTR(GMRX) I (('$T)!(GMRX="")!($E(GMRX)="Y")!(GMRX="^")) S GMROUT=1 Q
  1.  I GMRX?1"N".E S GMROUT=0 Q
  1.  W !,"ANSWER YES OR NO" G V2
  1. EN4 ; ENTRY FROM GMRVED0 TO ADD THE PATIENT DATA TO THE 120.5 FILE
  1.  D NOW^%DTC S GMRDATE=%
  1.  F GMRX=2:1:$L(GMRSTR(0),";")-1 S GMRVITY=$P(GMRSTR(0),";",GMRX) D
  1.  . S GMRVIT=$S(GMRVITY="T":"TEMPERATURE",GMRVITY="P":"PULSE",GMRVITY="R":"RESPIRATION",GMRVITY="BP":"BLOOD PRESSURE",GMRVITY="HT":"HEIGHT",GMRVITY="CG":"CIRCUMFERENCE/GIRTH",1:"")
  1.  . S:GMRVIT="" GMRVIT=$S(GMRVITY="WT":"WEIGHT",GMRVITY="CVP":"CENTRAL VENOUS PRESSURE",GMRVITY="PO2":"PULSE OXIMETRY",GMRVITY="PN":"PAIN",1:"")
  1.  . D:$G(GMRDAT(GMRVITY))'=""&(GMRVIT'="") ADDNODE
  1.  Q
  1. ADDNODE ; add data to the 120.5 file
  1.  N GMVDTDUN,GMVFDA,GMVIEN
  1.  S GMVDTDUN=GMRVIDT
  1.  S GMRVIT(1)=$O(^GMRD(120.51,"B",GMRVIT,0))
  1.  S GMVDTDUN=$$CHKDT(GMRVIDT,GMRVIT(1))
  1.  S GMVFDA(120.5,"+1,",.01)=GMVDTDUN ;Date/Time
  1.  S GMVFDA(120.5,"+1,",.02)=DFN ;Patient
  1.  S GMVFDA(120.5,"+1,",.03)=GMRVIT(1) ;Vital Type
  1.  S GMVFDA(120.5,"+1,",.04)=GMRDATE ;Date Time entered
  1.  S GMVFDA(120.5,"+1,",.05)=GMRVHLOC ;Hospital
  1.  S GMVFDA(120.5,"+1,",.06)=DUZ ;Entered by (DUZ)
  1.  S GMVFDA(120.5,"+1,",1.2)=GMRDAT(GMRVITY) ;Rate
  1.  S GMVFDA(120.5,"+1,",1.4)=$G(GMRO2(GMRVITY)) ;Sup 02
  1.  S GMVIEN=""
  1.  D UPDATE^DIE("","GMVFDA","GMVIEN")
  1.  ;file any qualifiers
  1.  I $D(GMRSITE(GMRVITY))!$D(GMRINF(GMRVITY)) D
  1.  .I $G(GMRSITE(GMRVITY))'="" D
  1.  ..S GDATA=+$P(GMRSITE(GMRVITY),U,2)
  1.  ..Q:'GDATA
  1.  ..D ADDQUAL(GMVIEN(1)_"^"_GDATA)
  1.  ..Q
  1.  .I $D(GMRINF(GMRVITY)) D
  1.  ..S I=0
  1.  ..F  S I=$O(GMRINF(GMRVITY,I)) Q:I'>0  D
  1.  ...S I(1)=""
  1.  ...F  S I(1)=$O(GMRINF(GMRVITY,I,I(1))) Q:I(1)=""  D
  1.  ....S GDATA=+$P(GMRINF(GMRVITY,I,I(1)),"^")
  1.  ....Q:'GDATA
  1.  ....D ADDQUAL(GMVIEN(1)_"^"_GDATA)
  1.  ....Q
  1.  ...Q
  1.  ..Q
  1.  .Q
  1.  S DA=+GMVIEN(1)
  1.  I GMREDB="P1" S GMRVIEN(GMRVITY)=DA_"^"_GMRDAT(GMRVITY)_"^"_$G(GMRSITE(GMRVITY))
  1.  S:GMRENTY>4 GLAST=GMRVIDT,GLAST(1)=$G(GLAST(1))+1
  1.  Q
  1. XREF(DA) ; Set cross-references for FILE 120.5 entry
  1.  ; Execute SET logic only.  Set's all cross-references for this entry.
  1.  ; DA is the record number
  1.  N DIC,DIK,X,Y
  1.  Q:'DA
  1.  S DIK="^GMR(120.5,"
  1.  D IX1^DIK
  1.  Q
  1. XREF1(DA) ; Set cross-references for FILE 120.5 entry
  1.  ; Execute SET logic only.  Set's all cross-references for this entry.
  1.  ; DA is the record number
  1.  N DIC,DIK,GMRVDA,GMRVIEN,X,Y
  1.  Q:'DA
  1.  S GMRVIEN=0,GMRVDA=DA
  1.  F  S GMRVIEN=$O(^GMR(120.5,GMRVDA,5,GMRVIEN)) Q:'GMRVIEN  D
  1.  .S DA(1)=GMRVDA,DA=GMRVIEN
  1.  .S DIK="^GMR(120.5,DA(1),5,"
  1.  .D IX1^DIK
  1.  .Q
  1.  Q
  1. SETPRMT ; SET VITAL TYPE PATTERN MATCH
  1.  S G=$P(GMRSTR(0),";",GMRX)
  1.  S GMRHELP=GMRHELP_$S(G="P":"PPP",G="WT":"WWW.WW",G="R":"RR",G="CG":"NNN.NN",G="CVP":"NN",G="PO2":"NNN",G="HT":"HH",G="BP":"BBB/BBB/BBB (or BBB/BBB)",G="T":"TTT.T",G="PN":"NN",1:"")_$S(GMRX'=($L(GMRSTR(0),";")-1):"-",1:"")
  1.  S GMRHELP(1)=GMRHELP(1)_$S(GMRHELP(1)'="":",",1:"")_$P(GMRSTR(0),";",GMRX)_"^GMRVUT1"
  1.  S GMRPRMT=GMRPRMT_$S(G="T":"Temp",G="P":"Pulse",G="WT":"Wt.",G="R":"Resp",G="HT":"Ht.",G="BP":"BP",G="CG":"Circumference/Girth",G="CVP":"CVP",G="PO2":"PO2",G="PN":"Pain",1:"")_$S(GMRX'=($L(GMRSTR(0),";")-1):"-",1:"")
  1.  Q
  1. CHKDT(GMVDT,GMVSAV) ;Check if there is an entry for that date & time
  1.  N GMVA,GMVTY
  1.  S GMVA=0
  1.  F  S GMVA=$O(^GMR(120.5,"B",GMVDT,GMVA)) Q:'GMVA  D
  1.  .I DFN'=$P($G(^GMR(120.5,GMVA,0)),U,2) Q
  1.  .S GMVTY=$P($G(^GMR(120.5,GMVA,0)),"^",3)
  1.  .I GMVTY=GMVSAV D
  1.  ..S GMVDT=$$FMADD^XLFDT(GMVDT,"","","",1)
  1.  ..Q
  1.  .Q
  1.  Q GMVDT
  1.  ;
  1. ADDQUAL(GMRVDATA) ; Add qualifiers to FILE 120.5 entry
  1.  ; ADD QUALIFIER TO 120.505 SUBFILE
  1.  ; Input:
  1.  ;    GMRVDATA=120.5 IEN^QUALIFIER (120.52) IEN
  1.  ;
  1.  N GMVCNT,GMVERR,GMVFDA,GMVOKAY,GMRVIEN,GMRVQUAL
  1.  S GMRVIEN=+$P(GMRVDATA,"^",1) ;File 120.5 ien
  1.  S GMRVQUAL=+$P(GMRVDATA,"^",2) ;File 120.52 ien
  1.  ; Does File 120.5 entry exist?
  1.  I '$D(^GMR(120.5,GMRVIEN,0)) Q
  1.  ; Is the qualifier already stored?
  1.  I $O(^GMR(120.5,GMRVIEN,5,"B",GMRVQUAL,0))>0 Q
  1.  ; Legitimate Qualifier?
  1.  I '$D(^GMRD(120.52,GMRVQUAL,0)) Q
  1.  S GMVCNT=0 ;counter for number of tries to lock an entry
  1. B2 ; Lock the entry
  1.  I GMVCNT>3 Q  ;4 strikes and you're out
  1.  L +^GMR(120.5,GMRVIEN,0):1
  1.  S GMVCNT=GMVCNT+1
  1.  I '$T L -^GMR(120.5,GMRVIEN,0) G B2
  1.  ; Store the  qualifier
  1.  S GMVFDA(120.505,"+1,"_GMRVIEN_",",.01)=GMRVQUAL
  1.  D UPDATE^DIE("","GMVFDA","GMVOKAY","GMVERR")
  1.  L -^GMR(120.5,GMRVIEN,0)
  1.  Q