Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMVDCVAM

GMVDCVAM.m

Go to the documentation of this file.
  1. GMVDCVAM ;HOIFO/DAD,FT-VITALS COMPONENT: VALIDATE DATA (CONT.) ;9/26/00 15:31
  1. ;;5.0;GEN. MED. REC. - VITALS;;Oct 31, 2002
  1. ;
  1. ; This routine uses the following IAs:
  1. ; #10104 - ^XLFSTR calls (supported)
  1. ;
  1. DUPCHK ; *** Check for duplicate records ***
  1. N GMVD0,GMVDATA,GMVDUP
  1. S (GMVD0,GMVDUP)=0
  1. D DUPCH
  1. F S GMVD0=$O(^GMR(120.5,"AA",GMVDFN,GMVVD0,9999999-GMVDTDUN,GMVD0)) Q:(GMVD0'>0)!(GMVDUP>0) I $P($G(^GMR(120.5,GMVD0,2)),U)'>0 D
  1. . S GMVDATA=$G(^GMR(120.5,GMVD0,0))
  1. . I $P(GMVDATA,U,5,6)=(GMVHOSPL_U_GMVENTBY),$P(GMVDATA,U,8)=$P(GMVVMEAS,";") D DUPCH
  1. . Q
  1. S ^TMP($J,"GMVXREF",GMVVABBR,GMVQARRY)=""
  1. Q
  1. ;
  1. DUPCH ; *** Get qualifier lists for duplicate check ***
  1. I "^BP^CG^P^R^"[(U_GMVVABBR_U) D ; Vital types allowed to have dups
  1. . N GMVFLAG,GMVQD0,GMVSUB,GMVSUP
  1. . I GMVD0>0 D
  1. .. S GMVQD0=0,GMVQARRY(0)=U
  1. .. S GMVDUP(0)=$S($O(^GMR(120.5,GMVD0,5,"B",GMVQD0))>0:1,1:0)
  1. .. F S GMVQD0=$O(^GMR(120.5,GMVD0,5,"B",GMVQD0)) Q:GMVQD0'>0 D
  1. ... S GMVQARRY(0)=GMVQARRY(0)_GMVQD0_U
  1. ... Q
  1. .. S GMVDUP(0)=$$DUPC(GMVQARRY(0),GMVQARRY,GMVDUP(0))
  1. .. Q
  1. . E D
  1. .. S GMVQARRY(0)=""
  1. .. S GMVDUP(0)=$S($O(^TMP($J,"GMVXREF",GMVVABBR,GMVQARRY(0)))]"":1,1:0)
  1. .. F S GMVQARRY(0)=$O(^TMP($J,"GMVXREF",GMVVABBR,GMVQARRY(0))) Q:(GMVQARRY(0)="")!(GMVDUP(0)'>0) S GMVDUP(0)=$$DUPC(GMVQARRY(0),GMVQARRY,GMVDUP(0))
  1. .. Q
  1. . I GMVDUP(0)>0 D DUPMSG
  1. . Q
  1. E D
  1. . I GMVD0>0 D
  1. .. D DUPMSG
  1. .. Q
  1. . E D
  1. .. I $D(^TMP($J,"GMVXREF",GMVVABBR)) D DUPMSG
  1. .. Q
  1. . Q
  1. Q
  1. ;
  1. DUPC(GMVQ1,GMVQ2,GMVDUP) ;
  1. ; *** Compare qualifiers look for duplicates ***
  1. N GMV,GMVSUB,GMVSUP
  1. S GMVSUP=$S($L(GMVQ1,U)>$L(GMVQ2,U):GMVQ1,1:GMVQ2)
  1. S GMVSUB=$S($L(GMVQ1,U)<$L(GMVQ2,U):GMVQ1,1:GMVQ2)
  1. I $L(GMVQ1,U)=$L(GMVQ2,U) S GMVSUP=GMVQ1,GMVSUB=GMVQ2
  1. F GMV=2:1:$L(GMVSUB,U)-1 I GMVSUP'[(U_$P(GMVSUB,U,GMV)_U) S GMVDUP=0 Q
  1. Q GMVDUP
  1. ;
  1. DUPMSG ; *** Duplicate message ***
  1. S GMVDUP=1
  1. D MSG^GMVDCVAL("ERROR: Duplicate Vital Measurement data found (V^"_GMVVNUM_"="_GMVVHOLD_")")
  1. Q
  1. ;
  1. BP ; *** Validate Systolic only Blood Pressure data ***
  1. I GMVVABBR'="BP" Q
  1. I $P(GMVVMEAS,";")?1.N S GMVSYSBP=1
  1. Q
  1. ;
  1. PO2 ; *** Validate Supplemental O2 data ***
  1. S GMVVMEAS("PO2")=""
  1. I GMVVABBR'="PO2" Q
  1. I $$OMIT(GMVVMEAS),($P(GMVVMEAS,";",2)]"")!($P(GMVVMEAS,";",3)]"") D
  1. . D MSG^GMVDCVAL("ERROR: Supplemental O2 data not allowed if Pulse Oximetry is omitted (V^"_GMVVNUM_"="_GMVVHOLD_")")
  1. . Q
  1. I $P(GMVVMEAS,";",2)]"" D
  1. . I ($P(GMVVMEAS,";",2)'<.5)&($P(GMVVMEAS,";",2)'>20) D
  1. .. S GMVVMEAS("PO2")=$P(GMVVMEAS,";",2)_"L/min"
  1. .. Q
  1. . E D
  1. .. D MSG^GMVDCVAL("ERROR: O2 Flow Rate must be in the range 0.5-20 (V^"_GMVVNUM_"="_GMVVHOLD_")")
  1. .. Q
  1. . Q
  1. I $P(GMVVMEAS,";",3)]"" D
  1. . I ($P(GMVVMEAS,";",3)'<0)&($P(GMVVMEAS,";",3)'>100) D
  1. .. S GMVVMEAS("PO2")=GMVVMEAS("PO2")_$S(GMVVMEAS("PO2")]"":" ",1:"")_$P(GMVVMEAS,";",3)_"%"
  1. .. Q
  1. . E D
  1. .. D MSG^GMVDCVAL("ERROR: Percent O2 Concentration must be in the range 0-100 (V^"_GMVVNUM_"="_GMVVHOLD_")")
  1. .. Q
  1. . Q
  1. S GMVVMEAS=$P(GMVVMEAS,";")
  1. Q
  1. ;
  1. OMIT(GMVVMEAS) ;
  1. ; *** Determine if measurement was omitted ***
  1. ; Input:
  1. ; GMVVMEAS = A vital measurement
  1. ; Output:
  1. ; 1 - Measurement was omitted, 0 - Measurement was not omitted
  1. Q "^UNAVAILABLE^PASS^REFUSED^"[(U_$$UP^XLFSTR($P(GMVVMEAS,";"))_U)
  1. ;