Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: HLEVSRV2

HLEVSRV2.m

Go to the documentation of this file. 
  1. HLEVSRV2 ;O-OIFO/LJA - Event Monitor SERVER ;02/04/2004 14:42
  1.  ;;1.6;HEALTH LEVEL SEVEN;**109**;Oct 13, 1995
  1.  ;
  1. QUERYSTR ; Generate $QUERY strings...
  1.  N IOINHI,IOINORM,STRING,X
  1.  ;
  1.  S X="IOINHI;IOINORM" D ENDR^%ZISS
  1.  ;
  1.  D HD,EX,TELL^HLEVMST0("","0^0^999","Press RETURN to continue... ")
  1.  ;
  1.  F  S STRING=$$STRING QUIT:STRING']""  D
  1.  .  S STRING(STRING)=""
  1.  .  W !!,"Search string = ",IOINHI,STRING,IOINORM
  1.  ;
  1.  QUIT:$O(STRING(""))']""  ;->
  1.  W !!,IOINHI,"Paste the following ""search strings"" into an email message and send to the"
  1.  W !,"S.HLEV-INFORMATION-SERVER@REMOTE-SITE.",IOINORM
  1.  W !!
  1.  ;
  1.  S STRING=""
  1.  F  S STRING=$O(STRING(STRING)) Q:STRING']""  D
  1.  .  W !,STRING
  1.  ;
  1.  Q
  1.  ;
  1. STRING() ; Ask user to input values to be built into a search string
  1.  N FILTER,LIMIT,ROOT,STOP
  1.  S ROOT=$$QUERYRT QUIT:ROOT']"" "" ;->
  1.  S STOP=$$QUERYST(ROOT) QUIT:STOP']"" "" ;->
  1.  S LIMIT=$$QUERYLM
  1.  S FILTER=$$QUERYFL
  1.  Q ROOT_U_STOP_U_LIMIT_U_FILTER
  1.  ;
  1. QUERYRT() ;
  1.  N VAL
  1.  D TAG("$QUERY ROOT")
  1.  D EXRT
  1.  W !
  1.  S VAL=$$FT("Enter $QUERY ROOT") QUIT:VAL']""!(VAL=U) "" ;->
  1.  Q VAL
  1.  ;
  1. EXRT N I,T F I=1:1 S T=$T(EXRT+I) QUIT:T'[";;"  W !,$P(T,";;",2,99)
  1.  ;;Enter the $QUERY root now.  For example...
  1.  ;;
  1.  ;; - If you want to see all data for ^HL(772,25132), including the zero node
  1.  ;;   and all data, enter "HL(772,25132)".
  1.  ;; - If you want to see all data for HLMA(9132), including the zero node and
  1.  ;;   all data, enter "^HLMA(9132)".
  1.  ;;
  1.  ;;NOTE:  Do not enter the leading up-arrow before a global reference.
  1.  Q
  1.  ;
  1. QUERYST(ROOT) ;
  1.  N VAL
  1.  D TAG("$QUERY Stop Value")
  1.  D EXST
  1.  S VAL=$E(ROOT,$L(ROOT)),VAL=$S(VAL=")":$E(ROOT,1,$L(ROOT)-1)_",",1:ROOT)
  1.  W !
  1.  S VAL=$$FT("Enter $QUERY STOP VALUE",VAL) QUIT:VAL']""!(VAL=U) "" ;->
  1.  Q VAL
  1.  ;
  1. EXST N I,T F I=1:1 S T=$T(EXST+I) QUIT:T'[";;"  W !,$P(T,";;",2,99)
  1.  ;;Enter the $QUERY stop value now.  For example...
  1.  ;;
  1.  ;; - Assuming you entered "HL(772,25132)" (see helps under root entry above),
  1.  ;;   you would enter a stop value of "HL(772,25132,".
  1.  ;; - Assuming you entered "HLMA(9132)", enter a stop value of "HLMA(9132,".
  1.  Q
  1.  ;
  1. QUERYLM() ;
  1.  N VAL
  1.  D TAG("Data Node Limit")
  1.  D EXLM
  1.  R !!,"Enter LIMIT: ",VAL:60 Q:VAL'>0 "" ;->
  1.  QUIT:VAL>1000 1000 ;->
  1.  Q VAL
  1.  ;
  1. EXLM N I,T F I=1:1 S T=$T(EXLM+I) QUIT:T'[";;"  W !,$P(T,";;",2,99)
  1.  ;;You can limit the number of nodes that are returned.  This is especially 
  1.  ;;helpful when you don't know how many data nodes exist and will be returned by
  1.  ;;your request.  (You don't want to send a request, thinking you'll get around
  1.  ;;20 data nodes back, when 20,000 data nodes exist!)
  1.  ;;
  1.  ;;Enter the maximum number of nodes you want returned.
  1.  ;;
  1.  ;;NOTE:  The maximum number of data nodes returnable by each $QUERY search 
  1.  ;;       string is 1000.  So, there is no point entering any limit above 1000!
  1.  Q
  1.  ;
  1. QUERYFL() ;
  1.  N VAL
  1.  D TAG("Filter Reference")
  1.  D EXFL
  1.  W !
  1.  S VAL=$$FT("Enter FILTER REFERENCE","","O") QUIT:VAL']""!(VAL=U) "" ;->
  1.  Q VAL
  1.  ;
  1. EXFL N I,T F I=1:1 S T=$T(EXFL+I) QUIT:T'[";;"  W !,$P(T,";;",2,99)
  1.  ;;$QUERY returns all data nodes no matter the structure of the subscripts.  At
  1.  ;;times you might want to filter out the data nodes whose subscripting does not
  1.  ;;follow a specific format.  You can define such a filter now.  Some filter
  1.  ;;examples are shown below.
  1.  ;;
  1.  ;; - If you only want to see ^HL(772,IEN,"IN",1,0) enter a filter of "HL(772,#,"IN",1,0)".
  1.  ;; - If you want to see the message text in a file 772 entry, enter a filter of
  1.  ;;   "HL(772,#,"IN",#,0)".
  1.  ;;
  1.  ;;You probably noticed that the "#" symbol must be placed at every subscript
  1.  ;;location where you want "any IEN" to be included.
  1.  Q
  1.  ;
  1. TAG(TXT) W !!,$$CJ^XLFSTR("----------- "_IOINHI_TXT_IOINORM_"-----------",IOM+$L(IOINHI)+$L(IOINORM))
  1.  Q
  1.  ;
  1. HD W @IOF,$$CJ^XLFSTR("$QUERY String Generator",IOM)
  1.  W !,$$REPEAT^XLFSTR("=",IOM)
  1.  QUIT
  1.  ;
  1. EX N I,T F I=1:1 S T=$T(EX+I) QUIT:T'[";;"  W !,$P(T,";;",2,99)
  1.  ;;$QUERY-based search strings can be sent to the S.HLEV-INFORMATION-SERVER at
  1.  ;;remote sites requesting data to be returned to the HL7SystemMonitoring mail
  1.  ;;group.  Structuring $QUERY search strings can be complicated.  This utility
  1.  ;;will assist you in creating these search strings.
  1.  ;;
  1.  ;;The search string(s) created should be pasted into the mail message sent to
  1.  ;;the remote site.
  1.  ;;
  1.  ;;The parts of the $QUERY search string are listed below.
  1.  ;;
  1.  ;;  - $QUERY root
  1.  ;;  - $QUERY stop value
  1.  ;;  - # nodes to return
  1.  ;;  - Node filter format
  1.  QUIT
  1.  ;
  1. MONITOR(TXT) ; User requested that a monitor be run...
  1.  ; XTMP -- req
  1.  N HLEVIENE,MONM,PCE,QTIME,RECIP,VAL
  1.  ;
  1.  ; Email data request format: MONITOR^monitor-name^queue-time^recip's
  1.  ;
  1.  S MONM=$P(TXT,U) QUIT:MONM']""  ;->
  1.  S HLEVIENE=$O(^HLEV(776.1,"B",MONM,0)) QUIT:HLEVIENE'>0  ;->
  1.  QUIT:$P($G(^HLEV(776.1,+HLEVIENE,0)),U,5)'=1  ;-> Not remote requestable
  1.  S QTIME=$P(TXT,U,2) I QTIME'?7N1"."1.N S QTIME=$$NOW^XLFDT
  1.  ;
  1.  D ADDREQHD^HLEVSRV ; Initial header
  1.  D ADDREQ^HLEVSRV("Monitor: "_MONM_" [#"_HLEVIENE_"]")
  1.  ;
  1.  S ^XTMP(XTMP,"MONREQ","MON",HLEVIENE)=MONM
  1.  ;
  1.  S VAL=$P(TXT,U,2,999) Q:VAL']""  ;->
  1.  F PCE=1:1:$L(VAL,U) D
  1.  .  S RECIP=$P(VAL,U,PCE) QUIT:RECIP']""  ;->
  1.  .  S ^XTMP(XTMP,"MONREQ","MON",+HLEVIENE,RECIP)=""
  1.  .  D ADDREQ^HLEVSRV("         recipient = "_RECIP)
  1.  ;
  1.  S ^XTMP(XTMP,"MONREQ","TASK")=$$Q1TIME^HLEVAPI0(HLEVIENE,1,QTIME,XTMP)
  1.  ;
  1.  Q
  1.  ;
  1. FT(PMT,DEF,WAY) ; Return user-input text...
  1.  N DIR,DIRUT,DTOUT,DUOUT,X,Y
  1.  S DIR(0)="F"_$G(WAY)
  1.  S DIR("A")=PMT
  1.  I $G(DEF)]"" S DIR("B")=DEF
  1.  D ^DIR
  1.  I Y?1"^"1.E&($L(Y,U)=2) QUIT $P(Y,U,2) ;->
  1.  QUIT:$D(DIRUT)!($D(DTOUT))!($D(DUOUT)) U ;->
  1.  Q Y
  1.  ;
  1. ADDMAIL(TXT) ; Add TXT, but be sure it is on or after NUM
  1.  N SNO
  1.  QUIT:$G(HLEVOVER)  ;-> Over 5000 line limit...
  1.  S SNO=$O(^XTMP(XTMP,"HLMAIL",":"),-1)+1
  1.  I SNO<100 S SNO=100 ; Leave room at the top for messages
  1.  I SNO>5100 D  QUIT  ;->
  1.  .  S HLEVOVER=1
  1.  .  S TXT="     ***** 5000 Line Limit Reached!  Some text not included. *****"
  1.  .  S ^XTMP(XTMP,"HLMAIL",+SNO)=""
  1.  .  S ^XTMP(XTMP,"HLMAIL",+SNO+1)=""
  1.  .  S ^XTMP(XTMP,"HLMAIL",+SNO+2)=TXT
  1.  .  S ^XTMP(XTMP,"HLMAIL",1)=""
  1.  .  S ^XTMP(XTMP,"HLMAIL",2)=TXT
  1.  .  S ^XTMP(XTMP,"HLMAIL",3)=""
  1.  S ^XTMP(XTMP,"HLMAIL",+SNO)=TXT
  1.  Q
  1.  ;
  1. EOR ;HLEVSRV2 - Event Monitor SERVER ;5/16/03 14:42