Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBCU41

IBCU41.m

Go to the documentation of this file. 
  1. IBCU41	;ALB/ARH - THIRD PARTY BILLING UTILITIES (OP VISIT DATES) ; 6-JUN-93
  1. 	;;Version 2.0 ; INTEGRATED BILLING ;; 21-MAR-94
  1. 	;;Per VHA Directive 10-93-142, this routine should not be modified.
  1. 	;
  1. 	;
  1. OPV(DATE,IFN)	;input transform for outpatient visit dates (399,43,.01)
  1. 	;input:  DATE - to add
  1. 	;        IFN  - bill to add to
  1. 	;returns: 1 - if OK to add
  1. 	;         0 - if not
  1. 	N X,Y S X=1
  1. 	I '$$OPV2(DATE,IFN,1) S X=0
  1. 	I '$$OPV1(IFN,1) S X=0
  1. 	S Y=$$APPT^IBCU3(DATE,$P($G(^DGCR(399,IFN,0)),U,2),1)
  1. 	S Y=$$DUPCHK(DATE,IFN,1)
  1. 	Q X
  1. 	;
  1. OPV1(IFN,DISP,CNT)	;edit checks for adding visit dates, if any of these fail then no visit date should be added to the bill
  1. 	;these are the types of checks that if they fail a message should be displayed to the user
  1. 	;does not check date passed in against existing dates, assumes new visit date
  1. 	;input:  IFN  - required, internal file number of bill to check
  1. 	;        DISP - if true then error messager will be printed, if any
  1. 	;        CNT  - number of visit dates user wants to add to bill
  1. 	;returns: "1^warning message" - if OK to add more visit dates to the bill
  1. 	;         "0^error message" - if no more visit dates should added to the bill
  1. 	;
  1. 	N X,Y S Y=1 S:$G(CNT)="" CNT=1 S:$G(UN)="" UN=$G(^DGCR(399,+IFN,"U"))
  1. 	I '$P(UN,U,1) S Y="0^No 'Statement From' date on file ... Can't enter OP visit dates ..." G OPV1E
  1. 	I '$P(UN,U,2) S Y="0^No 'Statement To' date on file ... Can't enter OP visit dates ..." G OPV1E
  1. 	G:'$O(^DGCR(399,IFN,"OP",0))&(CNT<2) OPV1E
  1. 	I $P($G(^DGCR(399,IFN,"OP",0)),U,4)+CNT>30 S Y="0^Maximum of 30 visit dates allowed per bill!" G OPV1E
  1. 	I +$P($G(^DGCR(399,+IFN,0)),U,19)'=2,$D(^DGCR(399,IFN,"CP","ASC")) S Y="0^Only one visit date allowed on bills with Billable Amb. Surg. Codes!" G OPV1E
  1. 	;warnings:
  1. 	I +Y,+$P($G(^DIC(36,+$G(^DGCR(399,IFN,"M")),0)),U,8) S Y="1^This insurance Company will only accept one visit per bill!" G OPV1E
  1. OPV1E	I +$G(DISP),$P(Y,U,2)'="" W !,?10,$P(Y,U,2)
  1. 	Q Y
  1. 	;
  1. OPV2(DATE,IFN,DISP,UN)	;edit checks for adding visit dates, if any if these fail then the given date should not be added to the bill
  1. 	;these are the types of checks that determine if a particular visit date should be presented to the user for possible addition to the bill
  1. 	;does not check date passed in against existing dates, assumes new visit date
  1. 	;also being used for Procedure Date (399,304,1) input transform
  1. 	;input:  DATE - required, date to check for addition to the bill
  1. 	;        IFN  - required, internal file number of bill to check
  1. 	;        DISP - if true then error messager will be printed, if any
  1. 	;        UN   - the "U" node of the bill, pass if alrady defined in a var
  1. 	;returns: "1^warning message" - if date is OK to add to the bill
  1. 	;         "0^error message" - if date should not be added to the bill
  1. 	;
  1. 	N X,Y S Y=1,DATE=$P(DATE,".",1) S:$G(UN)="" UN=$G(^DGCR(399,+IFN,"U"))
  1. 	I DATE<+UN S Y="0^Can't enter a visit date prior to the 'Statement From' date ..." G OPV2E
  1. 	I DATE>+$P(UN,U,2) S Y="0^Can't enter a visit date later than the 'Statement To' date ..." G OPV2E
  1. OPV2E	I +$G(DISP),$P(Y,U,2)'="" W !,?10,$P(Y,U,2)
  1. 	Q Y
  1. 	;
  1. DUPCHK(DATE,IFN,DISP,DFN,RTG)	;Check for duplicate billing of opt visit - checks for given visit date on other
  1. 	;bills with the same rate type and that have not been cancelled (if not IFN then use DFN and RTG)
  1. 	;input:   DATE - visit date to check
  1. 	;         IFN - internal file number of bill date is being added to
  1. 	;         DISP - true if error message should be printed before exit, if any
  1. 	;         DFN - patient'S IFN (required only if IFN is not passed)
  1. 	;         RTG - rate group to check for (""), if no rate group (0 passed and/or no IFN) then any bill found for
  1. 	;               visit date will cause error message
  1. 	;returns: 0 - if another bill was not found with this visit date, patient, and rate type
  1. 	;         (dup IFN)_"^error message" - if duplicate date found, same rate group, IFN of other bill w/visit date
  1. 	;(initially set up to check for same rate group because MT billing was done on the UB-82 so it was valid to have multiple bills with different rate groups for the same episode)
  1. 	N IFN2,Y,X S Y=0,DATE=$P(+$G(DATE),".",1),IFN=+$G(IFN),X=$G(^DGCR(399,IFN,0))
  1. 	S DFN=$S(+$G(DFN):$G(DFN),1:$P(X,U,2)),RTG=$S($G(RTG)'="":RTG,1:$P(X,U,7)) G:'DFN DUPCHKE
  1. 	I '$D(^DGCR(399,"AOPV",DFN,DATE)) G DUPCHKE
  1. 	S IFN2=0 F  S IFN2=$O(^DGCR(399,"AOPV",DFN,DATE,IFN2)) Q:'IFN2  I IFN2'=IFN D  Q:+Y
  1. 	. S X=$G(^DGCR(399,IFN2,0)) I $P(X,U,13)=7 Q  ; bill for date cancelled
  1. 	. I +RTG,RTG'=$P(X,U,7) Q  ; different rate group
  1. 	. S Y=IFN2_"^A "_$P($G(^DGCR(399.3,+$P(X,U,7),0)),U,1)_" bill ("_$P(X,U,1)_") exists for visit date ("_$$DAT1^IBOUTL(DATE)_")."
  1. DUPCHKE	I +$G(DISP),+Y W !,?10,$P(Y,U,2)
  1. 	Q Y