Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: KMPRUTL3

KMPRUTL3.m

Go to the documentation of this file. 
  1. KMPRUTL3 ;SF/RAK - Resource Usage Monitor Utilities ;1/20/00  07:37
  1.  ;;1.0;CAPACITY MANAGEMENT - RUM;**1**;Dec 09, 1998
  1.  ;
  1. HRSDAYS(KMPRSDT,KMPREDT,KMPRKILL,KMPRRES) ;-- hours/days.
  1.  ;-----------------------------------------------------------------------
  1.  ; KMPRSDT.. Stat Date in internal fileman format.
  1.  ; KMPREDT.. End Date in internal fileman format.
  1.  ; KMPRKILL. Kill node after processing: 
  1.  ;              0 - do not kill.
  1.  ;              1 - kill
  1.  ; KMPRRES.. Array (passed by reference) containing days/hours info
  1.  ;           in format: KMPRRES(KMPRSDT,Node)=Data 
  1.  ;              Where Data equals:
  1.  ;              '^' Piece 1 - Prime Time Days
  1.  ;              '^' Piece 2 - Prime Time Hours
  1.  ;              '^' Piece 3 - Non-Prime Time Days
  1.  ;              '^' Piece 4 - Non-Prime Time Hours
  1.  ;           Example:
  1.  ;              KMPRRES(2990130,"999A01")=5^9^7^15
  1.  ;              KMPRRES(2990130,"999A02")=5^4^7^10
  1.  ;              KMPRRES(2990130,"999A03")=5^9^7^15
  1.  ;              KMPRRES(...,...)=...
  1.  ;-----------------------------------------------------------------------
  1.  ;
  1.  K KMPRRES
  1.  ;
  1.  Q:'$G(KMPRSDT)
  1.  Q:'$G(KMPREDT)
  1.  S KMPRKILL=+$G(KMPRKILL)
  1.  ;
  1.  N DATA,DATE,DAYS,HOURS,I,NODE
  1.  ;
  1.  D HOURS(KMPRSDT,KMPREDT,KMPRKILL,.HOURS) Q:'$D(HOURS)
  1.  S NODE=""
  1.  F  S NODE=$O(HOURS(NODE)) Q:NODE=""  D 
  1.  .S (DATE,DAYS,HOURS)=0
  1.  .F  S DATE=$O(HOURS(NODE,DATE)) Q:'DATE  D 
  1.  ..S DATA=HOURS(NODE,DATE)
  1.  ..; piece 1 - prime time.
  1.  ..; piece 2 - non-prime time.
  1.  ..F I=1,2 D 
  1.  ...; total hours.
  1.  ...S $P(HOURS,U,I)=$P(HOURS,U,I)+$P(DATA,U,I)
  1.  ...; if current day has hours then increment total days.
  1.  ...S:$P(DATA,U,I) $P(DAYS,U,I)=$P(DAYS,U,I)+1
  1.  .; back to NODE level.
  1.  .S KMPRRES(KMPRSDT,NODE)=$P(DAYS,U)_"^"_$P(HOURS,U)_"^"_$P(DAYS,U,2)_"^"_$P(HOURS,U,2)
  1.  Q
  1.  ;
  1. HOURS(KMPRSDT,KMPREDT,KMPRKILL,KMPRRES) ;-- determine prime time & non-prime time hours
  1.  ;-----------------------------------------------------------------------
  1.  ; KMPRSDT.. Stat Date in internal fileman format.
  1.  ; KMPREDT.. End Date in internal fileman format.
  1.  ; KMPRKILL. Kill node after processing: 
  1.  ;              0 - do not kill.
  1.  ;              1 - kill
  1.  ; KMPRRES.. Array (passed by reference) containing days/hours info
  1.  ;           in format: KMPRRES(Date,Node)=Data 
  1.  ;              Where Data equals:
  1.  ;              '^' Piece 1 - Prime Time Days
  1.  ;              '^' Piece 2 - Prime Time Hours
  1.  ;              '^' Piece 3 - Non-Prime Time Days
  1.  ;              '^' Piece 4 - Non-Prime Time Hours
  1.  ;           Example:
  1.  ;              KMPRRES(2990130,"999A01")=5^9^7^15
  1.  ;              KMPRRES(2990130,"999A02")=5^4^7^10
  1.  ;              KMPRRES(2990131,"999A01")=5^9^7^15
  1.  ;              KMPRRES(...,...)=...
  1.  ;-----------------------------------------------------------------------
  1.  ;
  1.  K KMPRRES
  1.  ;
  1.  Q:'$G(KMPRSDT)
  1.  Q:'$G(KMPREDT)
  1.  S KMPRKILL=+$G(KMPRKILL)
  1.  ;
  1.  N DATA,DATE,DOW,END,HOURS,HRS,I,NODE,PIECE
  1.  ; end date.
  1.  S END=KMPREDT
  1.  S DATE=KMPRSDT-.1,(DAYS,HOURS)=""
  1.  F  S DATE=$O(^XTMP("KMPR","HOURS",DATE)) Q:'DATE!(DATE>END)  D 
  1.  .Q:DATE<KMPRSDT!(DATE>END)
  1.  .S NODE="",DOW=$$DOW^XLFDT(DATE,1)
  1.  .; prime time (8am to 5pm).
  1.  .; if not saturday or sunday or holiday then prime time (piece 1).
  1.  .; if saturday or sunday then non-prime time (piece 2).
  1.  .S PIECE=$S(DOW'=0&(DOW'=6)&('$G(^HOLIDAY(DATE,0))):1,1:2)
  1.  .F  S NODE=$O(^XTMP("KMPR","HOURS",DATE,NODE)) Q:NODE=""  D
  1.  ..S DATA=$G(^XTMP("KMPR","HOURS",DATE,NODE)) Q:DATA=""
  1.  ..S (HOURS,HRS)=0
  1.  ..;
  1.  ..;*** times are offset by 1  so zero hour is in piece 1
  1.  ..;***                            one hour is in piece 2
  1.  ..;***                            two hour is in piece 3
  1.  ..;***                            etc.
  1.  ..; prime time.
  1.  ..F I=9:1:17 S HRS=HRS+$P(DATA,U,I)
  1.  ..S $P(HOURS,U,PIECE)=$P(HOURS,U,PIECE)+HRS
  1.  ..; non-prime time.
  1.  ..S HRS=0
  1.  ..F I=1:1:8,18:1:24 S HRS=HRS+$P(DATA,U,I)
  1.  ..S $P(HOURS,U,2)=$P(HOURS,U,2)+HRS
  1.  ..S KMPRRES(NODE,DATE)=HOURS
  1.  ..K:KMPRKILL ^XTMP("KMPR","HOURS",DATE,NODE)
  1.  ;
  1.  Q
  1.  ;
  1. PURGE(KMPRDDT,KMPRHRS) ;-- purge data in file #8971.1
  1.  ;-----------------------------------------------------------------------
  1.  ; KMPRDDT.. Date to begin purge in internal fileman format. Purge will
  1.  ;           reverse $order and delete entries 'EARLIER' than KMPRDDT.
  1.  ; KMPRHRS.. Purge Hours/Days data from ^XTMP("KMPR","HOURS". Entries
  1.  ;           'EARLIER' than KMPRDDT will be deleted.
  1.  ;           0 - do not purge hours/days data.
  1.  ;           1 - purge hours/days data.
  1.  ;-----------------------------------------------------------------------
  1.  ;
  1.  Q:'$G(KMPRDDT)
  1.  S KMPRHRS=+$G(KMPRHRS)
  1.  ;
  1.  N DA,DATE,DIK,IEN
  1.  W:'$D(ZTQUEUED) !,"Deleting old records..."
  1.  S DATE=KMPRDDT
  1.  F  S DATE=$O(^KMPR(8971.1,"B",DATE),-1) Q:'DATE!(DATE>KMPRDDT)  D 
  1.  .F IEN=0:0 S IEN=$O(^KMPR(8971.1,"B",DATE,IEN)) Q:'IEN  D 
  1.  ..; quit if not 'sent to cm database'.
  1.  ..Q:'$P($G(^KMPR(8971.1,IEN,0)),U,2)
  1.  ..; Delete entry.
  1.  ..S DA=IEN,DIK="^KMPR(8971.1," D ^DIK
  1.  ;
  1.  Q:'KMPRHRS
  1.  W:'$D(ZTQUEUED) !,"Deleting old entries from ^XTMP(""KMPR"",""HOURS""..."
  1.  S DATE=KMPRDDT
  1.  F  S DATE=$O(^XTMP("KMPR","HOURS",DATE),-1) Q:'DATE!(DATE>KMPRDDT)  D 
  1.  .K ^XTMP("KMPR","HOURS",DATE)
  1.  ;
  1.  Q