Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LA7VLIN4

LA7VLIN4.m

Go to the documentation of this file. 
  1. LA7VLIN4 ;VA/DALOI/JMC - Process Incoming UI Msgs, continued ;JUL 06, 2010 3:14 PM
  1.  ;;5.2;AUTOMATED LAB INSTRUMENTS;**46,64,1027**;NOV 01, 1997
  1.  ;This routine is a continuation of LA7VIN1 and is only called from there.
  1.  Q
  1.  ;
  1. OBR ; Process OBR segments
  1.  N I,LA7CUP,LA7ENTRY,LA7IDE,LA7INST,LA7PDUZ,LA7TRAY,LA7X,LA7Y
  1.  I $G(LA7OTYPE)="" S LA7OTYPE="RE"  ;ihs/cmi/maw 8/18/2010 for missing labcorp orc segment
  1.  ;
  1.  ; OBR Set ID
  1.  S LA7SOBR=$$P^LA7VHLU(.LA7SEG,2,LA7FS)
  1.  ;
  1.  S LA7X=$$P^LA7VHLU(.LA7SEG,19,LA7FS)
  1.  S LA7X=$$UNESC^LA7VHLU3(LA7X,LA7FS_LA7ECH)
  1.  ;S LA7624=0,LA7INST=$P(LA7X,"^") ; extracting 1st piece  cmi/maw 3/2/10 split this line
  1.  ;cmi/maw 3/2/10 modified for reference lab inbound next 3 lines
  1.  S LA7624=0
  1.  ;S LA7INST=$P(LA7X,"^") ; extracting 1st piece
  1.  S LA7INST=$$GET1^DIQ(9009029,DUZ(2),3001)
  1.  ;cmi/maw 3/2/10 end of mods
  1.  ; Look up #62.4 entry from instrument name.
  1.  I LA7INST'="" S LA7624=+$O(^LAB(62.4,"B",LA7INST,0))
  1.  ;
  1.  ; If none then use sending application name to look up #62.4 entry.
  1.  I 'LA7624 S LA7624=+$O(^LAB(62.4,"B",LA7SAP,0))
  1.  ;
  1.  ; Instrument name not found in xref
  1.  I 'LA7624 D  Q
  1.  . I LA7INST="" D  Q
  1.  . . S LA7ERR=10,LA7QUIT=2
  1.  . . D CREATE^LA7LOG(LA7ERR)
  1.  . S LA7ERR=11,LA7QUIT=2
  1.  . D CREATE^LA7LOG(LA7ERR)
  1.  S LA7624(0)=$G(^LAB(62.4,LA7624,0))
  1.  S LA7ID=$P(LA7624(0),"^")_"-I-"
  1.  ;
  1.  S LA7LWL=+$P(LA7624(0),"^",4) ;  Load/Work List
  1.  S LA7ENTRY=$P(LA7624(0),"^",6) ;LOG,LLIST,IDENT or SEQN
  1.  S:LA7ENTRY="" LA7ENTRY="LOG"
  1.  ;
  1.  ; Placer(sender)/filler order numbers
  1.  S LA7X=$$P^LA7VHLU(.LA7SEG,3,LA7FS)
  1.  S LA7SID=$P(LA7X,$E(LA7ECH)) F I=2:1:4 S LA7SID(I)=$P(LA7X,$E(LA7ECH),I)
  1.  S LA7X=$$P^LA7VHLU(.LA7SEG,4,LA7FS)
  1.  S LA7FID=$P(LA7X,$E(LA7ECH)) F I=2:1:4 S LA7FID(I)=$P(LA7X,$E(LA7ECH),I)
  1.  ;
  1.  ; Test order code - find order NLT code
  1.  ; If POC interface then see if NLT is used for ordering code
  1.  S LA7X=$$P^LA7VHLU(.LA7SEG,5,LA7FS),LA7ONLT=""
  1.  F I=1,4 D  Q:LA7ONLT'=""
  1.  . I $P(LA7X,LA7CS,I)'?5N1"."4N Q
  1.  . I $P(LA7X,LA7CS,I+2)="99VA64" S LA7ONLT=$P(LA7X,LA7CS,I),LA7ONLT(0)=$P(LA7X,LA7CS,I+1) Q
  1.  . I LA7INTYP>19,LA7INTYP<30,$P(LA7X,LA7CS,I+2)="" S LA7ONLT=$P(LA7X,LA7CS,I),LA7ONLT(0)=$P(LA7X,LA7CS,I+1) Q
  1.  ;
  1.  ; Specimen collection date/time
  1.  S LA7CDT=$$HL7TFM^XLFDT($P($$P^LA7VHLU(.LA7SEG,8,LA7FS),LA7CS),"L")
  1.  ;
  1.  ; Pull info from placer field #2 (OBR-19)
  1.  S LA7X=$$P^LA7VHLU(.LA7SEG,20,LA7FS)
  1.  S LA7X=$$UNESC^LA7VHLU3(LA7X,LA7FS_LA7ECH)
  1.  S LA7TRAY=+$P(LA7X,"^",1) ;Tray
  1.  S LA7CUP=+$P(LA7X,"^",2) ; Cup
  1.  ; If POC interface set cup to file #62.49 ien
  1.  I LA7INTYP>19,LA7INTYP<30 S LA7CUP=LA76249
  1.  ;S LA7AA=$P(LA7X,"^",3) ;  Accession Area  ;cmi/maw 3/2/10 not used for ihs ref lab
  1.  S LA7AA=+$O(^LRO(68,"B","SO",0))         ;  Accession Area  ;cmi/maw 3/2/10 ihs reference lab
  1.  S LA7AD=$P(LA7X,"^",4) ;  Accession Date
  1.  S LA7AN=$P(LA7X,"^",5) ;  Accession Entry
  1.  S LA7ACC=$P(LA7X,"^",6) ;  Accession
  1.  ;cmi/maw 3/2/10 not used ihs ref lab next 2 lines
  1.  ;S LA7UID=$P(LA7X,"^",7) ;  Unique ID
  1.  ;I LA7UID'?1(10UN,15UN) S LA7UID=""
  1.  ;cmi/maw 3/2/10 ihs ref lab
  1.  S LA7UID=LA7SID  ;cmi/maw 3/2/10 OBR-3 contains the UID
  1.  ;
  1.  ; Sequence Number
  1.  ; If point of care interface (20-29) then use file #62.49 ien as IDE
  1.  S LA7IDE=$P(LA7X,LA7CS,8)
  1.  I LA7INTYP>19,LA7INTYP<30 S LA7IDE=LA76249
  1.  ;
  1.  ; UID might come as Sample ID
  1.  I LA7UID="",LA7SID?1(10UN,15UN) S LA7UID=LA7SID
  1.  ;
  1.  ; Try to figure out LA7AA LA7AD LA7AN by using the unique ID (UID)
  1.  ; accession may have rolled over, use UID to get current accession info.
  1.  I LA7UID]"" D
  1.  . N X
  1.  . S X=$Q(^LRO(68,"C",LA7UID))
  1.  . I $QS(X,3)'=LA7UID S LA7UID="" Q  ; UID not on file.
  1.  . S LA7AA=+$QS(X,4),LA7AD=+$QS(X,5),LA7AN=+$QS(X,6)
  1.  . D SETID^LA7VHLU1(LA76249,LA7ID,LA7UID)
  1.  ;
  1.  ; If still not known, compute from default accession date and area.
  1.  ; Calculate accession date based on accession transform.
  1.  I LA7AA<1!(LA7AD<1)!(LA7AN<1) D
  1.  . N X
  1.  . S LA7AA=+$P(LA7624(0),"^",11)
  1.  . S X=$P($G(^LRO(68,LA7AA,0)),U,3)
  1.  . S LA7AD=$S(X="D":DT,X="M":$E(DT,1,5)_"00",X="Y":$E(DT,1,3)_"0000",X="Q":$E(DT,1,3)_"0000"+(($E(DT,4,5)-1)\3*300+100),1:DT)
  1.  . S LA7AN=+LA7SID
  1.  . I LA7AN>0 D SETID^LA7VHLU1(LA76249,LA7ID,LA7AN)
  1.  . E  D SETID^LA7VHLU1(LA76249,LA7ID,$S(LA7PNM]"":LA7PNM,LA7SSN]"":LA7SSN,1:"NO ID"))
  1.  ;
  1.  ; Zeroth node of acession area.
  1.  S LA7AA(0)=$G(^LRO(68,+LA7AA,0))
  1.  ; Accession's subscript
  1.  S LA7SS=$P(LA7AA(0),"^",2)
  1.  ;
  1.  ; Specimen action code
  1.  S LA7SAC=$$P^LA7VHLU(.LA7SEG,12,LA7FS)
  1.  ;
  1.  ; Specimen(topography), collection sample, HL7 specimen source
  1.  S (LA761,LA762,LA70070,LA7SPEC)=""
  1.  S LA7SPTY=$$P^LA7VHLU(.LA7SEG,16,LA7FS)
  1.  ;
  1.  ; Check if using HL7 table 0070
  1.  S LA7X=$P($P(LA7SPTY,LA7CS),$E(LA7ECH,4),3)
  1.  I LA7X=""!(LA7X="HL70070") S LA7SPEC=$P($P(LA7SPTY,LA7CS),$E(LA7ECH,4))
  1.  ;
  1.  I $O(^LRO(68,LA7AA,1,LA7AD,1,LA7AN,5,0)) D
  1.  . N X
  1.  . S X=$O(^LRO(68,LA7AA,1,LA7AD,1,LA7AN,5,0))
  1.  . ; specimen^collection sample
  1.  . S X(0)=$G(^LRO(68,LA7AA,1,LA7AD,1,LA7AN,5,X,0))
  1.  . S LA761=$P(X(0),"^") ; specimen
  1.  . S LA762=$P(X(0),"^",2) ; collection sample
  1.  . ; HL7 code
  1.  . I LA761 S LA70070=$$GET1^DIQ(61,LA761_",","LEDI HL7:HL7 ABBR")
  1.  ;
  1.  ; Log error when specimen source does not match accession's specimen
  1.  I LA70070'="",LA7SPEC'="",LA70070'=LA7SPEC D
  1.  . N LA7OBR
  1.  . S LA7OBR(15)=LA7SPEC ; backward compatible with old code
  1.  . S LA7ERR=22,LA7QUIT=2
  1.  . D CREATE^LA7LOG(LA7ERR)
  1.  ;
  1.  ; Don't continue if flag set to skip this segment
  1.  I LA7QUIT Q
  1.  ;
  1.  ; Placer's ordering provider (id^duz^last name, first name, mi [id])
  1.  I $G(LA7POP)="" D
  1.  . S LA7POP="",LA7X=$$P^LA7VHLU(.LA7SEG,17,LA7FS)
  1.  . I LA7X="" Q
  1.  . S LA7POP=$$XCNTFM^LA7VHLU4(LA7X,LA7ECH)
  1.  . I LA7POP="^^" S LA7POP=""
  1.  ;
  1.  ; Create entry in LAH for supported subscripts.
  1.  I LA7MTYP="ORR",$G(LA7OTYPE)'="OK","CHMI"[LA7SS D
  1.  . D LAGEN
  1.  . I $G(LA7ISQN)="" D CREATE^LA7LOG(14) Q
  1.  . S LA7I=$O(^TMP("LA7 ORDER STATUS",$J,""),-1),LA7I=LA7I+1
  1.  . I LA7ONLT="" S X=$$P^LA7VHLU(.LA7SEG,5,LA7FS),LA7X=$P(X,LA7CS),LA7X(0)=$P(X,LA7CS,2)
  1.  . E  S LA7X=LA7ONLT,LA7X(0)=LA7ONLT(0)
  1.  . S X=LA7LWL_"^"_LA7ISQN_"^"_LA7X_"^"_LA7X(0)_"^"_LA76248_"^"_LA76249_"^"_LA7OTYPE_"^^"_$P($G(LA7SM),"^",2)
  1.  . S ^TMP("LA7 ORDER STATUS",$J,LA7I)=X
  1.  . I $G(LA7OCR)'="" S ^TMP("LA7 ORDER STATUS",$J,LA7I,"OCR")=$TR(LA7OCR,LA7CS,"^")
  1.  . I $G(LA7MSATM)'="" S ^TMP("LA7 ORDER STATUS",$J,LA7I,"MSA")=LA7MSATM
  1.  ;
  1.  I LA7MTYP="ORU","CHMI"[LA7SS D
  1.  . D LAGEN
  1.  . I $G(LA7ISQN)<1 D CREATE^LA7LOG(14) Q
  1.  . I LA7INTYP=10,LA7SAC?1(1"A",1"G") D
  1.  . . S LA7I=$O(^TMP("LA7 ORDER STATUS",$J,""),-1),LA7I=LA7I+1,LA7SAC(0)=LA7I
  1.  . . I LA7ONLT="" S X=$$P^LA7VHLU(.LA7SEG,5,LA7FS),LA7X=$P(X,LA7CS),LA7X(0)=$P(X,LA7CS,2)
  1.  . . E  S LA7X=LA7ONLT,LA7X(0)=LA7ONLT(0)
  1.  . . S X=LA7LWL_"^"_LA7ISQN_"^"_LA7X_"^"_LA7X(0)_"^"_LA76248_"^"_LA76249_"^"_LA7OTYPE_"^"_LA7SAC_"^"_$P($G(LA7SM),"^",2)
  1.  . . S ^TMP("LA7 ORDER STATUS",$J,LA7I)=X
  1.  ;
  1.  I LA7INTYP=10,$G(LA7SM)'="",$G(LA7UID)'="" D SMUPDT
  1.  Q
  1.  ;
  1.  ;
  1. LAGEN ; Sets up variables for call to ^LAGEN,  build entry in LAH
  1.  ; requires LA7INST,LA7TRAY,LA7CUP,LA7AA,LA7AD,LA7AN,LA7LWL
  1.  ; returns LA7ISQN=subscript to store results in ^LAH global
  1.  ;
  1.  I LA7ENTRY="LOG" D
  1.  . I LA7INTYP>19,LA7INTYP<30 Q
  1.  . I '$D(^LRO(68,LA7AA,1,LA7AD,1,LA7AN,0)) D CREATE^LA7LOG(13)
  1.  I LA7ENTRY="LLIST" S:'LA7CUP LA7CUP=LA7IDE ;cup=sequence number
  1.  ;
  1.  K LA7ISQN,LADT,LAGEN
  1.  K TRAY,CUP,LWL,WL,LROVER,METH,LOG,IDENT,ISQN
  1.  ;
  1.  S LA7ISQN=""
  1.  S TRAY=+$G(LA7TRAY) S:'TRAY TRAY=1
  1.  S CUP=+$G(LA7CUP) S:'CUP CUP=1
  1.  ;
  1.  S LWL=LA7LWL
  1.  I '$D(^LRO(68.2,+LWL,0)) D  Q
  1.  . D CREATE^LA7LOG(19)
  1.  ;
  1.  ; Set accession area to area of specimen, allow multiple areas on same instrument.
  1.  S WL=LA7AA
  1.  I '$D(^LRO(68,+WL,0)) D  Q
  1.  . D CREATE^LA7LOG(20)
  1.  S LROVER=$P(LA7624(0),"^",12)
  1.  S METH=$P(LA7624(0),"^",10)
  1.  S LOG=LA7AN
  1.  S IDENT=$P($G(^LRO(68,LA7AA,1,LA7AD,1,LA7AN,0)),"^",6) ;identity field
  1.  S IDE=+LA7IDE
  1.  S LADT=LA7AD
  1.  ;
  1.  ; If POC interface call special entry point
  1.  D
  1.  . N LRDFN ; Protect LRDFN - call into LAGEN can set to 0
  1.  . I LA7INTYP>19,LA7INTYP<30 S IDE=LA76249 D POC^LAGEN Q
  1.  . D @(LA7ENTRY_"^LAGEN") ;this disregards the CROSS LINK field in 62.4
  1.  S LA7ISQN=$G(ISQN)
  1.  ;
  1.  I LA7ISQN<1 Q
  1.  ;
  1.  ; Build/store patient demographics array
  1.  N I,J,LA7OBRA,LA7PIDA,X,Y
  1.  S J="DFN^DOB^ICN^LOC^LRDFN^LRTDFN^PNM^SEX^SSN"
  1.  S J(0)="DFN^LA7DOB^LA7ICN^LA7LOC^LRDFN^LRTDFN^LA7PNM^LA7SEX^LA7SSN"
  1.  F I=1:1 S X=$P(J,"^",I) Q:X=""  D
  1.  . S Y=$P(J(0),"^",I)
  1.  . I $G(@Y)'="" S LA7PIDA(X)=@Y
  1.  I $D(LA7PIDA) D POI^LAGEN(LA7LWL,LA7ISQN,"PID",.LA7PIDA)
  1.  ;
  1.  ; Build/store order info array
  1.  N LA7ONLTS
  1.  I LA7POP'="" S LA7POP=$P(LA7POP," [")
  1.  S X=$G(^LAH(LA7LWL,1,LA7ISQN,.1,"OBR","ORDNLT"))
  1.  I X'="",LA7ONLT'="",X'[LA7ONLT S LA7ONLTS=X_"^"_LA7ONLT
  1.  E  S LA7ONLTS=LA7ONLT
  1.  S J="EOL^FID^ORCDT^ORDNLT^ORDP^ORDSPEC^PON^SID^PEB^PVB"
  1.  S J(0)="LA7EOL^LA7FID^LA7CDT^LA7ONLTS^LA7POP^LA7SPEC^LA7PON^LA7SID^LA7PEB^LA7PVB"
  1.  F I=1:1 S X=$P(J,"^",I) Q:X=""  D
  1.  . S Y=$P(J(0),"^",I)
  1.  . I $G(@Y)'="" S LA7OBRA(X)=@Y
  1.  I $D(LA7OBRA) D POI^LAGEN(LA7LWL,LA7ISQN,"OBR",.LA7OBRA)
  1.  ;
  1.  ; Store interface type with results
  1.  D LATYP^LAGEN(LA7LWL,LA7ISQN,LA7INTYP)
  1.  ; 
  1.  ; Store #62.49 ien with results
  1.  D LAMSGID^LAGEN(LA7LWL,LA7ISQN,LA76249)
  1.  ;
  1.  ; Store method name with LAH entry
  1.  D METH^LAGEN(LA7LWL,LA7ISQN,METH)
  1.  ;
  1.  ; Set flag if POC interface to start POC processing routine when
  1.  ; finished - tasked by LA7VIN before shutdown
  1.  I LA7INTYP>19,LA7INTYP<30 S LA7INTYP("LWL",LA7LWL)=""
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. SMUPDT ; Update shipping manifest in shipping event file #62.85
  1.  N LA7DATA,LA7NCS,LA7TST,LA7USID
  1.  ;
  1.  S LA7USID=$$P^LA7VHLU(.LA7SEG,5,LA7FS) ; Universal Service ID (OBR-4)
  1.  S LA7TST=$P(LA7USID,LA7CS,1) ; Test code
  1.  S LA7NCS=$P(LA7USID,LA7CS,3) ; Name of coding system
  1.  S LA7TST(2)=$P(LA7USID,LA7CS,4) ; Alternate test code
  1.  S LA7NCS(2)=$P(LA7USID,LA7CS,6) ; Alternate coding system
  1.  ;
  1.  ; Determine ordered test, check primary and alternate
  1.  S LA7OTST=$$DOT^LA7SMU1(LA7TST,LA7NCS,LA7UID,$P(LA7SM,"^"))
  1.  I 'LA7OTST,LA7TST(2)'="" S LA7OTST=$$DOT^LA7SMU1(LA7TST(2),LA7NCS(2),LA7UID,$P(LA7SM,"^"))
  1.  ;
  1.  ; Flag the Results Received Event in #62.85
  1.  I LA7MTYP="ORU" D
  1.  . S LA7DATA="SM70"_"^"_LA7MEDT_"^"_$G(LA7OTST)_"^"_$P(LA7SM,"^",2)
  1.  . D SEUP^LA7SMU(LA7UID,"2",LA7DATA)
  1.  ;
  1.  ; Flag the Test Received Event in #62.85
  1.  I LA7MTYP="ORR" D
  1.  . S LA7DATA="SM55"_"^"_LA7MEDT_"^"_$G(LA7OTST)_"^"_$P(LA7SM,"^",2)
  1.  . D SEUP^LA7SMU(LA7UID,"2",LA7DATA)
  1.  Q