Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LR7OSAP2

LR7OSAP2.m

Go to the documentation of this file. 
  1. LR7OSAP2 ;ISL/RAB/WTY/KLL - Silent Routine for autopsy report;3/28/2002
  1.  ;;5.2;LAB SERVICE;**1030**;NOV 01, 1997
  1.  ;;5.2;LAB SERVICE;**230,256,259,317,365**;Sep 27, 1994;Build 11
  1.  ;
  1.  ;Reference  to ^DD(63 supported by IA #999
  1.  ;
  1. EN(LRDFN) ;
  1.  N CCNT,GIOM,XPOS,LR,LRSS,X,I,LRAU,LRS,VERIFIED,LRTEXT,LRPTR,X2
  1.  S XPOS=0,(LRS(5),LR("M"),CCNT)=1,LRSS="AU",GIOM=80
  1.  D EN^LRUA,^LRAPU
  1.  S X=$S($D(^LRO(69.2,+Y,0)):^(0),1:""),LRAU(3)=$P(X,"^",3),LRAU(4)=$P(X,"^",4)
  1.  D LINE,LN
  1.  S ^TMP("LRH",$J,"AUTOPSY")=GCNT,^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(28,CCNT,"---- AUTOPSY ----")
  1.  S VERIFIED=$P($G(^LR(LRDFN,"AU")),U,15)
  1.  I 'VERIFIED D  Q
  1.  . D LN
  1.  . S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(XPOS,CCNT,"Report not verified.")
  1.  D TIUCHK^LRAPUTL(.LRPTR,LRDFN,LRSS)
  1.  I +$G(LRPTR) D  Q
  1.  .D MAIN^LR7OSAP3(LRPTR)
  1.  D ZZ,LINE
  1.  I $D(^LR(LRDFN,84)) D
  1.  .D LN
  1.  .S LRTEXT="SUPPLEMENTARY REPORT HAS BEEN ADDED"
  1.  .S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(14,CCNT,"*+* "_LRTEXT_" *+*")
  1.  .D LN
  1.  .S LRTEXT="REFER TO BOTTOM OF REPORT"
  1.  .S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(19,CCNT,"*+* "_LRTEXT_" *+*")
  1.  .D LN
  1.  I $D(^LR(LRDFN,81)) D
  1.  . D LN
  1.  . S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(XPOS,CCNT,LRAU(3))
  1.  . D F(81)
  1.  I $D(^LR(LRDFN,82)) D
  1.  . D LN
  1.  . S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(XPOS,CCNT,LRAU(4))
  1.  . D F(82)
  1.  I $O(^LR(LRDFN,84,0)) D
  1.  . S I=0 F  S I=$O(^LR(LRDFN,84,I)) Q:'I  S X=^(I,0) D
  1.  .. ;Don't print supp date and text if supp has not been released
  1.  .. S X1=$P(X,"^",1),X2=$P(X,"^",2)
  1.  .. Q:'X2
  1.  .. D LINE,LN
  1.  .. S LRTEXT="SUPPLEMENTARY REPORT DATE: "_$$FMTE^XLFDT(X1,"1P")
  1.  .. S ^TMP("LRC",$J,GCNT,0)=LRTEXT
  1.  .. I $O(^LR(LRDFN,84,I,2,0)) D MODSR
  1.  .. D WRAP^LR7OSAP1("^LR("_LRDFN_",84,"_I_",1)",79)
  1.  Q:'$D(^LR(LRDFN,"AW"))&('$D(^("AY")))&('$D(^("AWI")))
  1.  D WT
  1.  D LRAPT3
  1.  ;Removed code that prints SNOMED codes per LR*5.2*259
  1.  Q
  1. MODSR ;Modified Autopsy Supplementary Report Audit Info
  1.  N LRTEXT,LRSP1,LRSP2,LRFILE,LRIENS,LRR1,LRR2
  1.  S LRFILE=63.3242
  1.  D LN
  1.  S LRTEXT="SUPPLEMENTARY REPORT HAS BEEN ADDED/MODIFIED"
  1.  S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(14,CCNT,"*** "_LRTEXT_" ***")
  1.  D LN
  1.  S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(1,CCNT,"(Added/Last modified: ")
  1.  S LRIENS=I_","_LRDFN_","
  1.  S LRSP1=0
  1.  F  S LRSP1=$O(^LR(LRDFN,84,I,2,LRSP1)) Q:'LRSP1  D
  1.  .S LRSP2=LRSP1
  1.  Q:'$D(^LR(LRDFN,84,I,2,LRSP2,0))
  1.  S LRS2=^LR(LRDFN,84,I,2,LRSP2,0),Y=+LRS2,LRS2A=$P(LRS2,"^",2),LRSGN=" typed by "
  1.  ;If supp rpt is released, display 'signed by' instead of 'typed by'
  1.  I $P(LRS2,"^",3) S Y=$P(LRS2,"^",4),LRS2A=$P(LRS2,"^",3),LRSGN=" signed by "
  1.  S LRS2A=$S($D(^VA(200,LRS2A,0)):$P(^(0),"^"),1:LRS2A)
  1.  D D^LRU
  1.  S LRR1=Y,LRR2=LRS2A
  1.  S ^(0)=^TMP("LRC",$J,GCNT,0)_LRR1_LRSGN_LRR2_")"
  1.  ;If RELEASED SUPP REPORT MODIFIED set to 1, display "NOT VERIFIED"
  1.  I $P(^LR(LRDFN,84,I,0),"^",3) D
  1.  .D LN
  1.  .S LRTEXT="NOT VERIFIED"
  1.  .S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(25,CCNT,"**-* "_LRTEXT_" *-**")
  1.  Q
  1. LN ;Increment the counter
  1.  S GCNT=GCNT+1,CCNT=1
  1.  Q
  1. LINE ;Fill in the global with bank lines
  1.  N X
  1.  D LN
  1.  S X="",$P(X," ",GIOM)="",^TMP("LRC",$J,GCNT,0)=X
  1.  Q
  1. F(NODE) ;;
  1.  D WRAP^LR7OSAP1("^LR("_LRDFN_","_NODE_")",79)
  1.  Q
  1. D ;
  1.  N LRB,M,X
  1.  S LRB=0
  1.  F  S LRB=$O(^LR(LRDFN,"AY",I,1,LRB)) Q:'LRB  S X=^(LRB,0) D LN S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(5,CCNT,$P(^LAB(61.4,+X,0),"^"))
  1.  S LRB=0
  1.  F  S LRB=$O(^LR(LRDFN,"AY",I,3,LRB)) Q:'LRB  S X=^(LRB,0) D LN S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(5,CCNT,$P(^LAB(61.3,+X,0),"^"))
  1.  S LRB=0
  1.  F  S LRB=$O(^LR(LRDFN,"AY",I,4,LRB)) Q:'LRB  S X=^(LRB,0) D LN S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(5,CCNT,$P(^LAB(61.5,+X,0),"^"))
  1.  S M=0
  1.  F  S M=$O(^LR(LRDFN,"AY",I,2,M)) Q:'M  S X=^(M,0) D LN S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(5,CCNT,$P(^LAB(61.1,+X,0),"^")) D E
  1.  Q
  1. E ;
  1.  N E
  1.  S E=0
  1.  F  S E=$O(^LR(LRDFN,"AY",I,2,M,1,E)) Q:'E  S X=^(E,0) D LN S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(7,CCNT,$P(^LAB(61.2,+X,0),"^"))
  1.  Q
  1. HD ;
  1.  D LINE
  1.  D LN
  1.  S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(XPOS,CCNT,"Organ/tissue:")_$$S^LR7OS(33,CCNT,"SNOMED CODING")
  1.  Q
  1. WT ;
  1.  N B,X,OUT
  1.  I '$D(^LR(LRDFN,"AW")) D
  1.  . D LINE,LN
  1.  . S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(20,CCNT,"No organ weights entered.")
  1.  . D LINE
  1.  I $D(^LR(LRDFN,"AW")) S X=^("AW") D
  1.  . S B(9)=$P(X,"^",9),B(1)=$P(X,"^",11,99)
  1.  . D LINE,LN
  1.  . S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(XPOS,CCNT,"Rt--Lung--Lt  Liver Spleen  RT--Kidney--Lt  Brain  Body Wt(lb)    Ht(in)")
  1.  I $D(B) D
  1.  . D LN
  1.  . S OUT=$$S^LR7OS(XPOS,CCNT,$J($P(X,"^",3),4))_$$S^LR7OS(9,CCNT,$J($P(X,"^",4),4))_$$S^LR7OS(15,CCNT,$J($P(X,"^",5),5))_$$S^LR7OS(22,CCNT,$J($P(X,"^",6),5))_$$S^LR7OS(29,CCNT,$J($P(X,"^",7),4))_$$S^LR7OS(39,CCNT,$J($P(X,"^",8),4))
  1.  . S OUT=OUT_$$S^LR7OS(45,CCNT,$J($P(X,"^",10),4))_$$S^LR7OS(55,CCNT,$P(X,"^",2))_$$S^LR7OS(68,CCNT,$P(X,"^"))
  1.  . S ^TMP("LRC",$J,GCNT,0)=OUT
  1.  D LINE,LN
  1.  S ^TMP("LRC",$J,GCNT,0)=""
  1.  I $D(B) S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(XPOS,CCNT,"Heart(gm)")
  1.  I $D(^LR(LRDFN,"AV")) S X=^("AV"),B(2)=$P(X,"^",7,99),^(0)=^TMP("LRC",$J,GCNT,0)_$$S^LR7OS(12,CCNT,"TV(cm)  PV(cm)  MV(cm)  AV(cm)  RV(cm)  LV(cm)")
  1.  D LN
  1.  S ^TMP("LRC",$J,GCNT,0)=""
  1.  I $D(B(9)) S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(XPOS,CCNT,$J(B(9),5))
  1.  I $D(B(2)) D
  1.  . S OUT=$$S^LR7OS(12,CCNT,$J($P(X,"^"),4))_$$S^LR7OS(20,CCNT,$J($P(X,"^",2),4))_$$S^LR7OS(28,CCNT,$J($P(X,"^",3),4))_$$S^LR7OS(36,CCNT,$J($P(X,"^",4),4))_$$S^LR7OS(44,CCNT,$J($P(X,"^",5),4))_$$S^LR7OS(52,CCNT,$J($P(X,"^",6),4))
  1.  . S ^(0)=^TMP("LRC",$J,GCNT,0)_OUT
  1.  . D LINE,LN
  1.  . S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(XPOS,CCNT,"Cavities(ml): Rt--Pleural--Lt  Pericardial  Peritoneal")
  1.  . D LN
  1.  . S OUT=$$S^LR7OS(14,CCNT,$J($P(B(2),"^",2),4))_$$S^LR7OS(25,CCNT,$J($P(B(2),"^"),4))_$$S^LR7OS(33,CCNT,$J($P(B(2),"^",3),4))_$$S^LR7OS(45,CCNT,$J($P(B(2),"^",4),4))
  1.  . S ^TMP("LRC",$J,GCNT,0)=OUT
  1.  I $D(B(1)) F B=1:1:8 D
  1.  . I $P(B(1),"^",B) D
  1.  .. S X="25."_B
  1.  .. D LN
  1.  .. S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(XPOS,CCNT,$P(^DD(63,X,0),"^")_": "_$P(B(1),"^",B))
  1.  I $D(^LR(LRDFN,"AWI")) S Y=^("AWI") F B=1:1:5 I $P(Y,"^",B) D LN S X=$S(B=1:25.9,1:25.9_(B-1)),^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(XPOS,CCNT,$P(^DD(63,X,0),"^")_": "_$P(Y,"^",B))
  1.  Q
  1. ZZ ;;
  1.  D LN
  1.  N OUT,X,LRLLOC,DA,A,B,C,LR,Y
  1.  S:$G(PNM)="" PNM=$P(^DPT(DFN,0),U) ;DBIA #10035
  1.  S OUT=$$S^LR7OS(XPOS,CCNT,"Acc #")_$$S^LR7OS(9,CCNT,"Date/time Died")_$$S^LR7OS(27,CCNT,"Age")_$$S^LR7OS(33,CCNT,"AUTOPSY DATA")_$$S^LR7OS(53,CCNT,"Date/time of Autopsy"),^TMP("LRC",$J,GCNT,0)=OUT
  1.  S X=^LR(LRDFN,"AU"),LRLLOC=$P(X,"^",8),DA=LRDFN
  1.  D D^LRAUAW
  1.  S Y=LR(63,12)
  1.  D D^LRU,LN
  1.  S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(XPOS,CCNT,($P(X,"^",6)_" "_Y))_$$S^LR7OS(26,CCNT,$J($P(X,"^",9),3))_$$S^LR7OS(33,CCNT,$G(PNM))
  1.  S Y=+X
  1.  D D^LRU
  1.  I Y'[1700 S ^(0)=^TMP("LRC",$J,GCNT,0)_$$S^LR7OS(53,CCNT,Y)
  1.  D LN
  1.  S ^TMP("LRC",$J,GCNT,0)=""
  1.  F X(1)=7,10 D
  1.  . S Y=$P(X,"^",X(1)),Y=$S(Y="":Y,$D(^VA(200,Y,0)):$P(^(0),"^"),1:Y)
  1.  . I Y]"" S ^TMP("LRC",$J,GCNT,0)=^TMP("LRC",$J,GCNT,0)_$S(X(1)=7:$$S^LR7OS(1,CCNT,"Resident: ")_Y,1:$$S^LR7OS(38,CCNT,"Senior: ")_Y)
  1.  Q
  1. LRAPT3 ;COPIED FROM ^LRAPT3
  1.  ;;
  1.  N A,C,X,T,F
  1.  S (F,A)=0
  1.  F  S A=$O(^LR(LRDFN,"AY",A)) Q:'A  D
  1.  .I $D(^LR(LRDFN,"AY",A,0)) S T=+^(0) D
  1.  ..S T(1)=$P($G(^LAB(61,T,0)),"^")
  1.  ..S C=0 F  S C=$O(^LR(LRDFN,"AY",A,5,C)) Q:'C  D
  1.  ...S X=^LR(LRDFN,"AY",A,5,C,0) D SP(X) S F=1
  1.  ;Removed code that prints ICD codes per LR*5.2*259
  1.  Q
  1. SP(NODE) ;
  1.  N Y,E,X,A1,B
  1.  S Y=$P(NODE,"^",2),E=$P(NODE,"^",3),X=$P(NODE,"^")_":",A1=$P($P(LRAU("S"),X,2),";",1)
  1.  D D^LRU
  1.  S T(2)=Y
  1.  I 'F D LINE,LN S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(1,CCNT,T(1))
  1.  D LN S ^TMP("LRC",$J,GCNT,0)=$$S^LR7OS(1,CCNT,A1_" "_E_" Date: "_T(2))
  1.  D WRAP^LR7OSAP1("^LR("_LRDFN_",""AY"","_A_",5,"_C_",1)",80)
  1.  Q
  1. OUT ;Show output
  1.  Q:'$D(^TMP("LRC",$J))
  1.  N I
  1.  S I=0
  1.  F  S I=$O(^TMP("LRC",$J,I)) Q:'I  W !,^(I,0)
  1.  Q