Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LRSORA

LRSORA.m

Go to the documentation of this file. 
  1. LRSORA ;VA/DRH/DALISC - HIGH/LOW VALUE REPORT ;2/19/91  11:42 ;
  1.  ;;5.2;LAB SERVICE;**1030**;NOV 01, 1997
  1.  ;;5.2;LAB SERVICE;**344,357,369**;Sep 27, 1994;Build 2
  1. MAIN D INIT,GDT,GAA:'LREND,GLRT:'LREND,GLOG:'LREND,SORTBY^LRSORA1:'LREND
  1.  D PATS^LRSORA1:'LREND,LOCS^LRSORA1:'LREND,GDV:'LREND,RUN:'LREND
  1.  D STOP
  1.  Q
  1. RUN ;
  1.  K ^TMP("LR",$J)
  1.  S:$D(ZTQUEUED) ZTREQ="@" U IO
  1.  S (LRPAG,LREND)=0,$P(LRDASH,"-",IOM)="-"
  1.  K %DT S X=$P(LRSDT,"."),%DT="X" D ^%DT,DD^LRX S LRSDAT=Y
  1.  K %DT S X=LREDT,%DT="X" D ^%DT,DD^LRX S LREDAT=Y
  1.  S LRHDR2="For date range: "_LREDAT_" to "_LRSDAT
  1.  D:'LREND START^LRSORA2
  1.  D:$D(ZTQUEUED) STOP
  1.  Q
  1. STOP ;
  1.  D STOP^LRSORA0
  1.  Q
  1. GAA ;
  1.  D GAA^LRSORA0
  1.  Q
  1. GLRT ;
  1.  W ! K LRTST S LRTST=1
  1.  F I=0:0 D GTSC Q:'$D(LRTST(LRTST,1))  W ! S LRTST=LRTST+1
  1.  K LRTST(LRTST) S LRTST=LRTST-1 Q
  1. GTSC ;
  1.  S LRA=1
  1.  F I=0:0 D @$S(LRA=2:"SPEC",LRA=3:"CND",LRA=4:"GV",1:"TST") Q:LRA=0
  1.  Q
  1. TST ;
  1.  K DIC S DIC="^LAB(60,",DIC(0)="AEMOQ"
  1.  S DIC("S")="I $P(^(0),U,5)[""CH"",""BO""[$P(^(0),U,3)" D ^DIC
  1.  S LRA=$S(Y>0:2,1:0)
  1.  S:X["^" LREND=1
  1.  I Y>0 S $P(LRTST(LRTST,3),"^",1)=$P($P(^LAB(60,+Y,0),U,5),";",2)
  1.  I  S $P(LRTST(LRTST,2),"^",1)=$P(Y,"^",2)
  1.  Q
  1. SPEC ;
  1.  S LRCNT=LRCNT+1
  1.  K DIC S DIC="^LAB(61,",DIC(0)="AEMOQ"
  1.  S DIC("A")="Select SPECIMEN/SITE: ANY// " D ^DIC
  1.  S:Y<1 $P(LRTST(LRTST,3),"^",2)="",$P(LRTST(LRTST,2),"^",2)=""
  1.  S LRA=$S(X["^":1,1:3)
  1.  I Y>0 S $P(LRTST(LRTST,3),"^",2)=+Y,$P(LRTST(LRTST,2),"^",2)=$P(Y,"^",2)
  1.  Q
  1. CND ;
  1.  W !,"Select CONDITION: " R X:DTIME S:'$T X="^"
  1.  D @$S(X?1.N1":"1.N:"RNG",1:"GC") Q
  1. RNG ;
  1.  N Y
  1.  S LRV=+$P(X,":",1),LRV2=+$P(X,":",2),LRA=0
  1.  S:LRV>LRV2 X=LRV,LRV=LRV2,LRV2=X
  1.  S $P(LRTST(LRTST,2),U,3)="BETWEEN "_LRV_" AND "_LRV2
  1.  S X=$P(LRTST(LRTST,3),U,1)
  1.  S Y="I $D(^("_X
  1.  S Y=Y_")) S LRVX=$P(^("_X
  1.  S Y=Y_"),U),LRVX=$S(LRVX?1A.E:LRVX,"
  1.  S Y=Y_"""<>""[$E(LRVX):$E(LRVX,2,$L(LRVX)),1:LRVX)"
  1.  S LRTST(LRTST,1)=Y_" I LRVX>"_LRV_",LRVX<"_LRV2
  1.  D ASPC Q
  1. GC ;
  1.  S DIC="^DOPT(""DIS"",",DIC(0)="EMQZ",DIC("S")="I $L($P(^(0),U,2))"
  1.  D ^DIC K DIC
  1.  S LRA=$S(X["^":2,Y<0:3,1:4) D:X["?" HLP1 W:'$L(X) " ??" Q:Y<0
  1. GV ;
  1.  N LY,ALPHA,DEC,II,TT
  1.  W !,"Enter VALUE: "
  1.  R X:DTIME S:'$T X="^"
  1.  S LRA=$S(X["^":3,"?"[X:4,1:0)
  1.  W:X="" " ??" D:X["?" HLP2 Q:LRA
  1.  S:"<>"[$P(Y(0),U,2) X=+X
  1.  S $P(LRTST(LRTST,2),"^",3)=$P(Y(0),"^",1)_" "_X
  1.  ;
  1.  ; determine if entered value is alphanumeric
  1.  S (ALPHA,DEC)=0
  1.  F II=1:1 S TT=$E(X,II) Q:TT=""  D  Q:ALPHA
  1.  . I TT?1N Q
  1.  . I TT?1"." S DEC=DEC+1 S:DEC>1 ALPHA=1 Q
  1.  . S ALPHA=1
  1.  I X="""""" S ALPHA=0 ;ADDED FOR LR*5.2*357
  1.  ;
  1.  S LY="I $D(^("_$P(LRTST(LRTST,3),U)
  1.  S LY=LY_")) S LRVX=$P(^("
  1.  S LY=LY_$P(LRTST(LRTST,3),U)
  1.  S LY=LY_"),U),LRVX=$S(LRVX?1A.E:LRVX,"
  1.  S LY=LY_"""<>""[$E(LRVX):$E(LRVX,2,$L(LRVX)),1:LRVX) I LRVX"
  1.  S LRTST(LRTST,1)=LY_$P(Y(0),U,2)_$S(ALPHA:""""_X_"""",1:X) D ASPC Q
  1. ASPC ;
  1.  S:$L($P(LRTST(LRTST,3),U,2)) LRTST(LRTST,1)=LRTST(LRTST,1)_",$P(^(0),U,5)="_$P(LRTST(LRTST,3),U,2) Q
  1. INIT ;
  1.  S LRCNT=0
  1.  S U="^"
  1.  S LREND=0
  1.  S LRLONG=0
  1.  S LRSDT="TODAY"
  1.  S LREDT="T-1"
  1.  S LRTW=.00001
  1.  S:'$D(DTIME) DTIME=300
  1.  W !,"SPECIAL REPORT - Search for high/low values" Q
  1. GDT ;
  1.  F W=0:0 D SDF,GSD Q:LREND  S LRSDT=Y D GED I Y>0 S LREDT=Y S:LREDT>LRSDT X=LREDT,LREDT=LRSDT,LRSDT=X D CXR W:Y'>0 !!,"No data for the year selected.",! Q:Y>0
  1.  K %DT S X=$P(LRSDT,"."),%DT="X" D ^%DT,DD^LRX S LRSDAT=Y
  1.  K %DT S X=$P(LREDT,"."),%DT="X" D ^%DT,DD^LRX S LREDAT=Y
  1.  S LRHDR2="For date range: "_LREDAT_" to "_LRSDAT
  1.  K LRSDAT,LREDAT,%DT Q
  1. GSD ;
  1.  S %DT("A")="Enter START date: ",%DT("B")=LRSDT,%DT="AET"
  1.  D ^%DT S LREND=Y<1 Q
  1. GED ;
  1.  S %DT("A")="Enter END date: ",%DT("B")=LREDT D ^%DT Q
  1. CXR ;
  1.  S Y=$E(LREDT,1,3)_"0000" F I=0:0 S Y=$O(^LRO(69,Y)) Q:Y=""!($D(^LRO(69,+Y,1,"AN")))
  1.  I Y>LREDT D DD^LRX W !,"The earliest date in the X-ref is ",Y,".  Long search required.",! D CXR1
  1.  Q
  1. CXR1 ;
  1.  F I=0:0 S %=2 W "  OK to continue" D YN^DICN S:%=2!(%<0) LREND=1 S:%=1 LRLONG=1 Q:%  W !,"Enter 'YES' for the long search, 'NO' to exit.",!
  1.  Q
  1. SDF ;
  1.  I LRSDT?1.7N S Y=LRSDT D DD^LRX S LRSDT=Y
  1.  I LREDT?1.7N S Y=LREDT D DD^LRX S LREDT=Y
  1.  Q
  1. GLOG ;
  1.  S:LRTST=1 LRTST(0)="A" D:LRTST>1 EN^LRSORA1 S:LRTST<1 LREND=1 Q
  1. GDV ;
  1.  S %ZIS="Q" D ^%ZIS K %ZIS I POP S LREND=1 Q
  1.  I $D(IO("Q")) K IO("Q") S (LRQUE,LREND)=1,ZTRTN="RUN^LRSORA",ZTDESC="Lab Special Report",ZTSAVE("LR*")="" D ^%ZTLOAD
  1.  Q
  1. HLP1 ;
  1.  W !,"A VALUE RANGE may also be entered (value:value).",!,"  For Example, 100:200 will search for values between 100 and 200.",!
  1.  Q
  1. HLP2 ;
  1.  W !,"Enter a value for the comparison:  "
  1.  W $P(LRTST(LRTST,2),U,1)," ",$P(Y(0),U,1)_" _____."
  1.  Q
  1. XX ;
  1. WAIT K DIR S DIR(0)="E" D ^DIR S:($D(DUOUT))!($D(DTOUT)) LREND=1
  1.  Q