Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: MCARAM

MCARAM.m

Go to the documentation of this file. 
  1. MCARAM ;WASH ISC/JKL-MUSE AUTO INSTRUMENT DATA LOAD INTO DHCP ;5/28/96  14:53
  1.  ;;2.3;Medicine;;09/13/1996
  1.  ;
  1.  ;
  1. START ; Driver for MUSE-run by task manager
  1.  ; WHERE: LANM,TSK,MCINST,T are required for MCARASE
  1.  ; LANM = routine name, T and TSK = auto instrument IEN,
  1.  ; MCINST = auto instrument name
  1.  ; MCL = data type line number,  MCLT = data transmission line number
  1.  ; MCD = one line of lab data, MCA = array of local data,
  1.  ; MCE = internal record number of EKG file where data is stored
  1.  ; MCRD = attempts to read lab data
  1.  ; MCCD= current data transmission number
  1.  ; MCPRO= EKG procedure number from Procedure/Subspecialty file
  1.  N LANM,TSK,MCINST,T,MCL,MCLT,MCA,MCCD,MCCNT,MCE,MCERR,MCRD,MCPRO,MCPRNM
  1.  N MCS,MCTOT,MCTYPE,MCZ,MCREC
  1.  S LANM=$T(+0),TSK=$O(^LAB(62.4,"C",LANM,0)),U="^" I TSK="" Q
  1.  ; Quit if no MUSE data
  1.  I '$D(^LA(TSK,"I",0)) Q
  1.  S MCINST=$P(^LAB(62.4,TSK,0),U) D ^MCARASE I 'TSK Q
  1.  S @TRAP
  1.  ;initial error condition
  1.  S MCA("ERR")=0
  1.  ;get EKG procedure number from Procedure/Subspecialty file
  1.  S MCPRO=$O(^MCAR(697.2,"C","MCAR(691.5",0))
  1.  ;print name for ECG procedure, type of transmission
  1.  S MCPRNM=$$ORPRM(MCPRO),MCTYPE="M"
  1.  ;delay process until record data is complete
  1.  D DELPRO
  1.  ;
  1. READ S MCRD=0,MCL=0,MCCD=-1,MCA("CONT")="@"
  1.  I ^LA(TSK,"I",0)'=0 S MCLT=^LA(TSK,"I",0)+1,MCCD=MCLT-1
  1.  D IN G QUIT
  1. IN S MCLT=^LA(TSK,"I",0)+1 I '$D(^(MCLT)) S MCRD=MCRD+1 Q:MCRD>6  H 8 G IN
  1.  S ^LA(TSK,"I",0)=MCLT,MCRD=0,MCERR=0
  1.  I '$D(MCREC) F MCZ=1:1 D:'$D(^LA(TSK,"I",MCLT+MCZ)) DELPRO I ($D(^LA(TSK,"I",MCLT+MCZ))#2),((^LA(TSK,"I",MCLT+MCZ)["EOR")!(^LA(TSK,"I",MCLT+MCZ)["ERR")!(^LA(TSK,"I",MCLT+MCZ)["BYE")) S MCREC="" Q
  1.  I '$D(MCA("ERR")) S MCA("ERR")=0
  1.  ;ignore set if retransmit set of data lines
  1.  I $D(^LA(TSK,"I",MCLT+3)),^LA(TSK,"I",MCLT+3)=^LA(TSK,"I",MCLT),^LA(TSK,"I",MCLT)?.E1.A.E S MCCD=MCCD+3,^LA(TSK,"I",0)=MCLT+2 G IN
  1.  ;check for start of transmission-suppressed H
  1.  I $E(^LA(TSK,"I",MCLT),1,5)="HELLO" S MCCD=MCLT-3
  1.  ;check for start of transmission-IRM
  1.  I $E(^LA(TSK,"I",MCLT),1,3)="IRM" S MCCD=MCLT-3
  1.  ;transfer one line of lab data to local array
  1.  I MCCD+3=MCLT S MCERR=$$RLAB^MCARAM(.MCA,.MCL,MCLT)
  1.  ;transmission error
  1.  I +MCERR=5 K MCA,MCERR,MCREC N MCA,MCERR G IN
  1.  ;transfer local array data into DHCP
  1.  ;record successful or unsuccessful data transfer attempt
  1.  I +MCERR=10 S:$$GRERR^MCARAM7(.MCA)=0 MCERR=$$LDHCP^MCARAM3(.MCA,.MCE) S MCERR=$$KPERR^MCARAM7(.MCA,.MCS) K MCA,MCERR,MCE,MCS,MCREC N MCA,MCERR,MCE,MCS
  1.  G IN
  1.  ;
  1. DELPRO ;delay process until record data is complete
  1.  S MCCNT=0
  1. DELP I $D(^LA(TSK,"I")) S MCTOT=^LA(TSK,"I"),MCCNT=MCCNT+1 H 15 I MCTOT=^LA(TSK,"I"),MCCNT<7 G DELP
  1.  K MCTOT,MCCNT
  1.  Q
  1.  ;
  1.  ;
  1. OUT S MCLT=^LA(TSK,"O")+1,^("O")=MCLT,^("O",MCLT)=OUT
  1.  L +^LA("Q") S Q=^LA("Q")+1,^("Q")=Q,^("Q",Q)=TSK L -^LA("Q") Q
  1.  Q
  1.  ;
  1.  ;
  1. RLAB(MCA,MCL,MCLT) ; Read Lab data and place in local array
  1.  ; USAGE: S X=$$RLAB^MCARAM(.A,.B,C)
  1.  ; WHERE: .A=Array into which data is placed
  1.  ;        .B=Data type line number
  1.  ;         C=Data transmission line number
  1.  ;
  1.  ;lab data
  1.  S MCD=^LA(TSK,"I",MCLT)
  1.  I ($E(MCD,1,5)="HELLO")!($E(MCD,1,3)="EOT") S MCL=0,MCA("CONT")="@",MCCD=MCLT-1 Q 0
  1.  I $E(MCD,1,3)="BYE" S MCL=0,MCA("CONT")="@",MCCD=MCLT-2 Q 0
  1.  I $E(MCD,1,3)="IRM" S MCL=0,MCA("CONT")="@",MCCD=MCLT Q 0
  1.  I $E(MCD,1,3)="EOR" S MCERR="10-End of record" S MCCD=MCLT Q MCERR
  1.  I $E(MCD,1,3)="ERR" S MCERR="5-Transmission error-expect retry of record" S MCL=0,MCA("CONT")="@",MCCD=MCLT-1 Q MCERR
  1.  S MCL=MCL+1,MCA("CONT")=$C($A(MCA("CONT"))+1)
  1.  ;transfer lab data to local
  1.  I MCL<13 S MCTR=$S(MCL<7:"S MCERR=$$L"_MCL_"^MCARAM1(.MCA,MCD)",MCL=12:"S MCERR=$$L"_MCL_"^MCARAM3(.MCA,MCD)",MCL>6:"S MCERR=$$L"_MCL_"^MCARAM2(.MCA,MCD)") X MCTR S MCCD=MCLT Q:+MCERR>0 MCERR  Q 0
  1.  ;fill diagnosis array
  1.  I MCL>12 S MCERR=$$DGCT^MCARAM4(.MCA,MCD,MCL),MCCD=MCLT I +MCERR>0 Q MCERR
  1.  Q 0
  1.  ;
  1. TRAP ;entry from MCARASE
  1.  K ^LA("LOCK",TSK) S T=TSK D SET^MCARASE
  1.  S ^LA(TSK,"Q")=0 D ERROR^MCARASE
  1.  G @(U_LANM)
  1.  ;
  1. ORPRM(MCPRO) ;Get print name for ECG procedure
  1.  ;USAGE: S X=$$ORPRM(MCPRO)
  1.  ;WHERE: X = print name for ECG procedure/subspecialty
  1.  ;       MCPRO = EKG procedure number from Procedure/Subspecialty file
  1.  I '$D(MCOEON) D ORDER^MCPARAM I '$D(MCOEON) Q ""
  1.  Q $P(^MCAR(697.2,MCPRO,0),U,8)
  1.  ; 
  1. HSHAKE ; MUSE dialog, called by LAB which executes HANDSHAKE fld of AI file
  1.  ; Does checksum on MUSE input, sets OUT to ACK or NAK
  1.  I IN="BYE" S OUT="" K MCSM Q
  1.  I IN="HELLO" S T=T-BASE,OUT="ACK" K MCSM
  1.  I IN?.E1.A.E N MCI S MCSM=0 F MCI=1:1:$L(IN) S MCSM=MCSM+$A(IN,MCI)
  1.  I IN?1.5N,$D(MCSM) S T=T-BASE S:MCSM'=IN OUT="NAK" S:MCSM=IN OUT="ACK" K MCSM
  1.  K MCI Q
  1. QUIT L +^LA(TSK) H 1
  1.  K ^LA(TSK)
  1.  L -^LA(TSK)
  1.  K ^LA("LOCK",TSK)
  1.  D DQ^%ZTLOAD
  1.  S:$D(ZTQUEUED) ZTREQ="@" K ZTSK
  1.  Q