Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORIN1005

ORIN1005.m

Go to the documentation of this file. 
  1. ORIN1005 ;IHS/CIA/DKM - KIDS Inits for OR patch 1005 ;16-Apr-2010 14:25;PLS
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**1005**;Dec 17, 1997
  1.  ;=================================================================
  1. EC ;EP - Environment check
  1.  Q
  1. PRE ;EP - Preinit
  1.  D ADDL4SSN
  1.  D ADDPDEAN
  1.  Q
  1. POST ;EP - Postinit
  1.  N PKG
  1.  F PKG="LAB SERVICE","OUTPATIENT PHARMACY","PHARMACY DATA MANAGEMENT" D
  1.  .D ADDPMT("OR GTX CLININD",PKG,"Indication:","clinical indicator",10,99,"%40")
  1.  .D ADDPMT("OR GTX CLININD2",PKG,"Indication ICD9:","clinical indicator ICD9",10.5,-1)
  1.  .Q:PKG="LAB SERVICE"
  1.  .D ADDPMT("OR GTX CMF",PKG,"Chronic Med:","chronic med",4.7,10)
  1.  .D ADDPMT("OR GTX DAW",PKG,"Dispense as Written:","dispense as written",4.8,10.1)
  1.  .D ADDPMT("OR GTX PHARMACY",PKG,"Pharmacy:","pharmacy",7.1,99)
  1.  .D ADDPMT("OR GTX SSREFREQ",PKG,"REFREQ Msg:","REFREQ Msg",7.2,99.1,"@",0)
  1.  .D ADDPMT("OR GTX SSRREQIEN",PKG,"REFREQ IEN:","REFREQ IEN",7.3,99.2,"@")
  1.  D REMPRG
  1.  D ADDCHILD("BEHOEN VISIT SUMMARY1")
  1.  D ADDCHILD("BEHOEN VISIT SUMMARY2")
  1.  D ADDCHILD("BEHOEN VISIT SUMMARIES")
  1.  D CHGMXNM("OUTPATIENT MEDICATIONS","Outpt. Meds")
  1.  I $$REGRPC^CIAURPC("ORWDXC MANUAL","CIAV VUECENTRIC")
  1.  I $$REGRPC^CIAURPC("ORWDXC RENEW","CIAV VUECENTRIC")
  1.  Q
  1.  ; Add a report to the ORRPW ADT VISITS report header.
  1. ADDCHILD(RPT) ;
  1.  N X,Y,FDA
  1.  S X=$$FIND1^DIC(101.24,,"X","ORRPW ADT VISITS")
  1.  S Y=$$FIND1^DIC(101.24,,"X",RPT)
  1.  I X,Y D
  1.  .S:'$O(^ORD(101.24,X,10,"B",Y,0)) FDA(101.241,"+1,"_X_",",.01)="`"_Y
  1.  .S FDA(101.24,Y_",",.13)="ORWRP REPORT TEXT"
  1.  .D UPDATE^DIE("E","FDA")
  1.  Q
  1.  ; Add prompt to selected order and quick order dialogs
  1. ADDPMT(PMT,PKG,LBL,DX,SEQ,OTS,FMT,REQ) ;
  1.  N DLG,TYP,ITM,QO,X,Y
  1.  S REQ=$G(REQ,1)
  1.  S:PMT'=+PMT PMT=$$FIND1^DIC(101.41,,"XQ",PMT)
  1.  S:PKG'=+PKG PKG=$$FIND1^DIC(9.4,,"XQ",PKG)
  1.  Q:'PMT!'PKG
  1.  S QO='OTS,TYP=$S(QO:"Q",1:"D"),ITM=0,FMT=$G(FMT)
  1.  F DLG=0:0 S DLG=$O(^ORD(101.41,DLG)) Q:'DLG  S X=$G(^(DLG,0)) D
  1.  .N FDA,IEN,NAM,SUB,SFN
  1.  .Q:$P(X,U,4)'=TYP
  1.  .S Y=$P(X,U,7)
  1.  .I 'Y,QO D
  1.  ..S Y=$P(X,U,5)
  1.  ..S:Y Y=$P($G(^ORD(100.98,Y,0)),U,4)
  1.  ..S:Y Y=$P($G(^ORD(101.41,Y,0)),U,7)
  1.  .Q:Y'=PKG
  1.  .S SUB=$S(QO:6,1:10),SFN=$S(QO:101.416,1:101.412)
  1.  .Q:'$O(^ORD(101.41,DLG,SUB,"D",0))
  1.  .S IEN=$O(^ORD(101.41,DLG,SUB,"D",PMT,0))
  1.  .S NAM=$$GET1^DIQ(101.41,DLG,.01)
  1.  .S FDA=$NA(FDA(SFN,$S(IEN:IEN,1:"+1")_","_DLG_","))
  1.  .D ADDQO:QO,ADDDG:'QO
  1.  .D UPDATE^DIE("","FDA","IEN")
  1.  .S X=$S(IEN:IEN,1:+$G(IEN(1)))
  1.  .S:'ITM ITM=X
  1.  .D BMES^XPDUTL($S(IEN:"Updated ",X:"Added ",1:"Unable to add ")_DX_" prompt "_$S(IEN:"in ",1:"to ")_NAM_".")
  1.  I 'QO,ITM D ADDPMT(PMT,PKG,LBL,DX,ITM,0)
  1.  Q
  1. ADDDG S @FDA@(.01)=SEQ
  1.  S @FDA@(2)=PMT
  1.  S @FDA@(6)=REQ  ;required field
  1.  S @FDA@(9)="*"
  1.  S @FDA@(17)="S Y="""""
  1.  S:OTS>0 @FDA@(21)=OTS
  1.  S:$L(FMT) @FDA@(22)=FMT
  1.  S @FDA@(24)=LBL
  1.  Q
  1. ADDQO S @FDA@(.01)=SEQ
  1.  S @FDA@(.02)=PMT
  1.  S @FDA@(.03)=1
  1.  Q
  1.  ; Change Mixed Name field value for Display Group
  1. CHGMXNM(DSPGRP,MXNM) ;
  1.  N FDA,IEN
  1.  Q:'$L($G(DSPGRP))!('$L($G(MXNM)))
  1.  S IEN=$$FIND1^DIC(100.98,,"XQ",DSPGRP)
  1.  Q:'IEN
  1.  S FDA(100.98,IEN_",",2)=MXNM
  1.  D FILE^DIE("","FDA")
  1.  Q
  1.  ; Remove ORPF GRACE DAYS BEFORE PURGE parameter from
  1.  ; ORP ORDER MISC parameter template
  1. REMPRG N PAR,TPL,LP,FDA
  1.  S PAR=$$FIND1^DIC(8989.51,,"XQ","ORPF GRACE DAYS BEFORE PURGE")
  1.  S TPL=$$FIND1^DIC(8989.52,,"XQ","ORP ORDER MISC")
  1.  Q:'PAR!'TPL
  1.  F LP=0:0 S LP=$O(^XTV(8989.52,TPL,10,LP)) Q:'LP  D:$P($G(^(LP,0)),U,2)=PAR
  1.  .S FDA(8989.521,LP_","_TPL_",",.01)="@"
  1.  D:$D(FDA) FILE^DIE("","FDA")
  1.  Q
  1.  ;
  1. ADDL4SSN ;EP
  1.  Q:$$FIND1^DIC(100.22,,,"L4 SSN of Patient")  ; Already exists
  1.  N FDA,FN,IEN
  1.  S IEN=$P(^ORD(100.22,0),U,3)  ; Check next ien value. Set to 1 if not between 1 and 999
  1.  S:IEN>999 $P(^ORD(100.22,0),U,3)=0  ; Move range of new entries to start with 1(or the next valid ien)
  1.  S FN=100.22,IEN="+1,"
  1.  S FDA(FN,IEN,.01)="L4 SSN of Patient"
  1.  S FDA(FN,IEN,.02)="L4S:"
  1.  S FDA(FN,IEN,.03)=2293
  1.  S FDA(FN,IEN,.04)="L4SSN"
  1.  S FDA(FN,IEN,1)="S L4SSN=$S($D(^DPT(+$G(ORVP),0)):$E($P(^(0),U,9),6,9),1:"""")"
  1.  D STORE(.FDA)
  1.  Q
  1. ADDPDEAN ;
  1.  Q:$$FIND1^DIC(100.22,,,"PROVIDER DEA#")  ; Already exists
  1.  N FDA,FN,IEN
  1.  S IEN=$P(^ORD(100.22,0),U,3)  ; Check next ien value. Set to 1 if not between 1 and 999
  1.  S:IEN>999 $P(^ORD(100.22,0),U,3)=0  ; Move range of new entries to start with 1(or the next valid ien)
  1.  S FN=100.22,IEN="+1,"
  1.  S FDA(FN,IEN,.01)="PROVIDER DEA#"
  1.  S FDA(FN,IEN,.02)="DEA#"
  1.  S FDA(FN,IEN,.03)="TESTDEA123"
  1.  S FDA(FN,IEN,.04)="ORDEAN"
  1.  S FDA(FN,IEN,1)="S ORDEAN=$$GET1^DIQ(200,+$$GET1^DIQ(100,+ORIFN,1,""I""),53.2)"
  1.  D STORE(.FDA)
  1.  Q
  1.  ;
  1.  ; File entry
  1. STORE(FDA) ;EP
  1.  N MSG
  1.  D UPDATE^DIE(,"FDA",,"MSG")
  1.  I $D(MSG) D
  1.  .W !,"The following error occurred:"
  1.  .W !,$G(MSG("DIERR",1,"TEXT",1))
  1.  .S XPDQUIT=1
  1.  K FDA
  1.  Q