Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORMFN

ORMFN.m

Go to the documentation of this file. 
  1. ORMFN ; SLC/MKB - MFN msg router ;11/21/2006
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**26,97,94,176,215,243**;Dec 17, 1997;Build 242
  1. EN(MSG) ; -- main entry point for OR ITEM RECEIVE
  1.  N ORMSG,ORNMSP,ORDG,MSH,MFI,MFE,ZPKG,ZSY,NTE,ORMFE,ORDITEM,ORACTION,ORDIFN,ORFIEN,ORFLD,ORFDA,NUM,VALUE,X,Y,DA,DIC,DIK,SYS,ZLC,LAST,NAME,ID,INACTIVE,I,ORY,NEXT,DD,DO
  1.  S ORMSG=$G(MSG,"MSG") Q:'$O(@ORMSG@(0))  ; msg array root
  1.  N ORNOW S ORNOW=$$NOW^XLFDT ;M ^XTMP("OR ITEM RECEIVE",ORNOW)=@ORMSG
  1. MSH S MSH=0 F  S MSH=$O(@ORMSG@(MSH)) Q:MSH'>0  Q:$E(@ORMSG@(MSH),1,3)="MSH"
  1.  Q:'MSH  S MSH=MSH_U_@ORMSG@(MSH)
  1.  S X=$P(MSH,"|",3) S:X="RADIOLOGY" X="IMAGING"
  1.  S ORDG=$O(^ORD(100.98,"B",X,0)),ORNMSP=$$NMSP(X) Q:'$L(ORNMSP)
  1.  S MFI=$O(@ORMSG@(+MSH)) Q:$E(@ORMSG@(MFI),1,3)'="MFI"  ; error
  1. MFE S MFE=+MFI ; ** loop through each MFE segment
  1.  F  S MFE=$O(@ORMSG@(+MFE)) Q:MFE'>0  I $E(@ORMSG@(MFE),1,3)="MFE" D
  1.  . K ORFLD,ORFDA
  1.  . S MFE=MFE_U_@ORMSG@(MFE),ORMFE=$P(MFE,"|",2),INACTIVE=$P(MFE,"|",4)
  1.  . S ORDITEM=$P(MFE,"|",5),NAME=$TR($P(ORDITEM,U,5),"~"," ")
  1.  . S ID=$P(ORDITEM,U,4)_";"_$P(ORDITEM,U,6)
  1.  . S ORDIFN=+$O(^ORD(101.43,"ID",ID,0)),ORFIEN=ORDIFN_","
  1.  . S ORACTION=$S(ORMFE="MAD":1,(ORMFE="MAC")&('ORDIFN):1,(ORMFE="MUP")&('ORDIFN):1,'ORDIFN:0,ORMFE="MAC":2,ORMFE="MUP":2,ORMFE="MDC":3,ORMFE="MDL":3,1:0) ; 1=add, 2=change, 3=delete (inactivate)
  1.  . Q:'ORACTION  ; 0=error
  1.  . I ORACTION=3 S ORFDA(101.43,ORFIEN,.1)=$S(INACTIVE:$$HL7TFM^XLFDT(INACTIVE),1:$$NOW^XLFDT) D FILE^DIE("K","ORFDA") Q
  1. ADD . I ORACTION=1,'ORDIFN D  Q:'ORDIFN  ;create item if it doesn't exist
  1.  . . S ORDIFN=$$CREATE(NAME),ORFIEN=ORDIFN_","
  1.  . . S ORFDA(101.43,ORFIEN,5)=+ORDG
  1.  . S ORFLD(.01)=NAME,ORFLD(1.1)=NAME,ORFLD(2)=ID,ORFLD(3)=$P(ORDITEM,U)
  1.  . S SYS=$P(ORDITEM,U,3),ORFLD(4)=$S(+SYS=99:$E(SYS,3,99),1:SYS)
  1.  . S ORFLD(.1)=$S(ORMFE="MAC":"@",(ORMFE="MUP")&('INACTIVE):"@",INACTIVE:$$HL7TFM^XLFDT(INACTIVE),1:"")
  1.  . F NUM=.01,.1,1.1,2,3,4 S VALUE=$S(ORFLD(NUM)="":"@",1:ORFLD(NUM)) D VAL^DIE(101.43,ORFIEN,NUM,"F",VALUE,.ORY,"ORFDA")
  1. ZPKG . S LAST=+MFE,ZPKG=$O(@ORMSG@(+MFE))
  1.  . I ZPKG,$E(@ORMSG@(ZPKG),1,3)=("Z"_ORNMSP) S ZPKG=ZPKG_U_@ORMSG@(ZPKG),LAST=+ZPKG D @ORNMSP ; ZXX segment
  1.  . D FILE^DIE("K","ORFDA") ; file data
  1. ZLC . S NEXT=$O(@ORMSG@(LAST)) I NEXT,$E(@ORMSG@(NEXT),1,3)="ZLC" D
  1.  . . N COMP,CID,CODE,CSYS
  1.  . . K DA,^ORD(101.43,ORDIFN,10) ;S DIC("P")=$P(^DD(101.43,10,0),U,2)
  1.  . . S DA(1)=ORDIFN,DIC="^ORD(101.43,"_DA(1)_",10,",DIC(0)="L",ZLC=LAST
  1.  . . F  S ZLC=$O(@ORMSG@(ZLC)) Q:ZLC'>0  Q:$E(@ORMSG@(ZLC),1,3)'="ZLC"  D
  1.  . . . S COMP=$P(@ORMSG@(ZLC),"|",5),X=$P(COMP,U,5) I X="" S LAST=ZLC Q
  1.  . . . S CID=$P(COMP,U,4)_";"_$P(COMP,U,6) K DIC("DR"),DO,DD
  1.  . . . S CODE=$P(COMP,U),CSYS=$P(COMP,U,3) S:+CSYS=99 CSYS=$E(CSYS,3,99)
  1.  . . . S DIC("DR")="2///^S X=CID;3///^S X=CODE;4///^S X=CSYS"
  1.  . . . D FILE^DICN S LAST=ZLC
  1. ZSY . I $D(^ORD(101.43,ORDIFN,2)) D  ; kill old ones first
  1.  . . S DA(1)=ORDIFN,DIK="^ORD(101.43,"_DA(1)_",2,"
  1.  . . S DA=0 F  S DA=$O(^ORD(101.43,DA(1),2,DA)) Q:DA'>0  D ^DIK
  1.  . . K ^ORD(101.43,ORDIFN,2),DIK,DA
  1.  . S NEXT=$O(@ORMSG@(LAST)) I NEXT,$E(@ORMSG@(NEXT),1,3)="ZSY" D
  1.  . . K DA,DIC S DA(1)=ORDIFN,DIC="^ORD(101.43,"_DA(1)_",2,"
  1.  . . S DIC(0)="L",ZSY=LAST ;,DIC("P")=$P(^DD(101.43,1,0),U,2)
  1.  . . F  S ZSY=$O(@ORMSG@(+ZSY)) Q:ZSY'>0  Q:$E(@ORMSG@(ZSY),1,3)'="ZSY"  D
  1.  . . . S X=$P(@ORMSG@(ZSY),"|",3),LAST=ZSY
  1.  . . . K DD,DO D:$L(X) FILE^DICN
  1. NTE . K ^ORD(101.43,ORDIFN,8) ; replace text
  1.  . S NEXT=$O(@ORMSG@(LAST)) I NEXT,$E(@ORMSG@(NEXT),1,3)="NTE" D
  1.  . . S NTE=LAST,DA=0
  1.  . . F  S NTE=$O(@ORMSG@(NTE)) Q:NTE'>0  Q:$E(@ORMSG@(NTE),1,3)'="NTE"  S DA=DA+1,^ORD(101.43,ORDIFN,8,DA,0)=$P(@ORMSG@(NTE),"|",4) I $O(@ORMSG@(NTE,0)) D
  1.  . . . S I=0 F  S I=$O(@ORMSG@(NTE,I)) Q:I'>0  S DA=DA+1,^ORD(101.43,ORDIFN,8,DA,0)=@ORMSG@(NTE,I)
  1.  . . S ^ORD(101.43,ORDIFN,8,0)="^^"_DA_U_DA_U_DT_U
  1.  Q
  1.  ;
  1. NMSP(NAME) ; -- returns namespace for package
  1.  I NAME="RADIOLOGY" Q "RA"
  1.  I NAME="IMAGING" Q "RA"
  1.  I NAME="LABORATORY" Q "LR"
  1.  I NAME="DIETETICS" Q "FH"
  1.  I NAME="PHARMACY" Q "PS"
  1.  I NAME="CONSULTS" Q "CS"
  1.  I NAME="PROCEDURES" Q "CS"
  1.  Q ""
  1.  ;
  1. CREATE(X) ; -- Create new item in #101.43
  1.  Q:'$L($G(X)) 0 N HDR,LAST,TOTAL,I
  1.  L +^ORD(101.43,0):1 Q:'$T 0
  1.  S HDR=$G(^ORD(101.43,0)) Q:HDR="" 0
  1.  S LAST=$P(HDR,U,3),TOTAL=$P(HDR,U,4)
  1.  F I=(LAST+1):1 Q:'$D(^ORD(101.43,I,0))
  1.  S ^ORD(101.43,I,0)=X,X=$E(X,1,30),^ORD(101.43,"B",$$UP^XLFSTR(X),I)=""
  1.  S $P(^ORD(101.43,0),U,3,4)=I_U_(TOTAL+1)
  1.  L -^ORD(101.43,0)
  1.  Q I
  1.  ;
  1. FH ; -- Dietetics
  1.  S X=$P(ZPKG,"|",2),ORFLD(111.1)=$S(X="":"@",1:X)
  1.  S X=$P(ZPKG,"|",3),ORFLD(111.2)=$S(X="":"@",1:X)
  1.  S X=$P(ZPKG,"|",5),ORFLD(111.3)=$S(X="":"@",1:X)
  1.  F NUM=111.1,111.2,111.3 D VAL^DIE(101.43,ORFIEN,NUM,"F",ORFLD(NUM),.ORY,"ORFDA")
  1.  K ^ORD(101.43,ORDIFN,8) S X=$P(ZPKG,"|",4)
  1.  I $L(X) S ^ORD(101.43,ORDIFN,8,0)="^^1^1^"_DT_U,^(1,0)=X
  1.  Q
  1.  ;
  1. LR ; -- Laboratory
  1.  S X=$P(ZPKG,"|",2),ORFLD(60.1)=$S(X="":"@",1:X)
  1.  S X=$P(ZPKG,"|",3),ORFLD(60.2)=$S(X="":"@",1:X)
  1.  ;S X=$P(ZPKG,"|",4),ORFLD(60.3)=$S(X="":"@",1:X)
  1.  S X=$P(ZPKG,"|",5),ORFLD(60.6)=$S(X="":"@",1:X)
  1.  S X=$P(ZPKG,"|",6),ORFLD(60.4)=$S(X="":"@",1:X)
  1.  S X=$P(ZPKG,"|",7),ORFLD(60.5)=$S(X="":"@",1:X)
  1.  S X=$P(ZPKG,"|",8),ORFLD(6)=$S(X="":"@",1:X)
  1.  S X=$P(ZPKG,"|",9),ORFLD(60.7)=$S(X="":"@",1:X)
  1.  F NUM=6,60.1,60.2,60.4,60.5,60.6,60.7 D VAL^DIE(101.43,ORFIEN,NUM,"F",ORFLD(NUM),.ORY,"ORFDA")
  1.  Q
  1.  ;
  1. PS ; -- Pharmacy
  1.  N ROUTE
  1.  S X=$P(ZPKG,"|",2)
  1.  ;S ORFDA(101.43,ORFIEN,50.1)=$S(X'["I":0,$L($P($P(ORDITEM,U,5),"~",3)):2,1:1)
  1.  S ORFDA(101.43,ORFIEN,50.1)=$S(X["V":2,X["I":1,1:0) ;inpt or iv med
  1.  S ORFDA(101.43,ORFIEN,50.2)=(X["O") ;outpt med
  1.  S ORFDA(101.43,ORFIEN,50.3)=(X["B") ;fluid base/soln
  1.  S ORFDA(101.43,ORFIEN,50.4)=(X["A") ;fluid additive
  1.  S ORFDA(101.43,ORFIEN,50.5)=(X["S") ;supply item
  1.  S ORFDA(101.43,ORFIEN,50.7)=(X["N") ;non-VA med
  1.  S X=$P(ZPKG,"|",3),ORFDA(101.43,ORFIEN,50.6)=$S(X:1,1:0)
  1.  ;Check for default med route
  1.  ;S ROUTE=$$MEDROUTE
  1.  ;I ROUTE>0 S ORFDA(101.43,ORFIEN,50.8)=ROUTE
  1.  Q
  1.  ;
  1. MEDROUTE() ;
  1.  N CNT,ROUTE
  1.  S CNT=0,ROUTE=0
  1.  F  S CNT=$O(@ORMSG@(CNT)) Q:CNT'>0  D
  1.  .I $P($G(@ORMSG@(CNT)),"|")'="ZPB" Q
  1.  .S ROUTE=+$P($G(@ORMSG@(CNT)),"|",4)
  1.  Q ROUTE
  1.  ;
  1. RA ; -- Radiology/Nuc Medicine
  1.  S X=$P(ZPKG,"|",4),ORFLD(6)=$S(X="":"@",1:X)
  1.  S X=$P(ZPKG,"|",5),ORFLD(71.1)=$S(X="":"@",1:X)
  1.  S X=$P(ZPKG,"|",7),ORFLD(71.2)=$S(X="":"@",1:X)
  1.  S X=$P(ZPKG,"|",2),ORFLD(71.3)=$S(X="":"@",1:X)
  1.  S ORFLD(71.4)=$S($P(ZPKG,"|",6)="Y":1,1:0)
  1.  S ORFLD(7)=$S($P(ZPKG,"|",3)="Y":2,1:1)
  1.  F NUM=6,7,71.1,71.2,71.3,71.4 D VAL^DIE(101.43,ORFIEN,NUM,"F",ORFLD(NUM),.ORY,"ORFDA")
  1.  Q
  1.  ;
  1. CS ; -- Consults/Requests
  1.  S X=$P(ZPKG,"|",2),ORFLD(123.1)=$S(X="":"@",1:X)
  1.  D VAL^DIE(101.43,ORFIEN,123.1,"F",ORFLD(123.1),.ORY,"ORFDA")
  1.  Q