Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORPRS01

ORPRS01.m

Go to the documentation of this file. 
  1. ORPRS01 ; slc/dcm - Hot'n Summary Report utilities ;6/10/97  15:37
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**11**;Dec 17, 1997
  1. P ; Get Patient(s)
  1.  N %X,%Y,C,DIC,DFN,I,ORATTEND,Y
  1.  K ORSCPAT,^XUTL("OR",$J,"ORU"),^("ORV"),^("ORW"),^("ORLP")
  1.  S ORSHORT=$$SHORT^ORPRS02
  1.  D PATIENT^ORU1(.ORSCPAT,,1)
  1.  I $S($D(DIROUT):1,$D(DUOUT):1,1:0) S (OREND,XQORPOP)=1
  1.  Q
  1. DAY(DAY) ; Get a date for 24 hr printing
  1.  ;DAY=Optional date for default date prompt
  1.  ;Returns: ORSSTRT=Internal Start date/time_"^"_Formatted Start date/time
  1.  ;         ORSSTOP=Internal Stop date/time_"^"_Formatted Stop date/time
  1.  ;         OREND,XQORPOP=1 if user ^'s or times out
  1.  ;         DIROUT=1 if user ^^'s out
  1.  N %,%DT,%I,%T,%H,ORSDFLT,X,Y
  1. D1 ;
  1.  S OREND=0,ORSDFLT=$S($G(DAY):$S($P(DAY,".",2)=2359:DAY+.7641,1:DAY),1:"T")
  1.  W !!,"Order Entry Date: "_$S(+ORSDFLT>0:$$DATE^ORU(ORSDFLT,"AMTH DD, CCYY"),1:"T")_"// "
  1.  R X:$S($D(DTIME):DTIME,1:300)
  1.  I $S(X="^":1,X="^^":1,'$T:1,1:0) S (OREND,XQORPOP)=1 S:X="^^" DIROUT=1 Q
  1.  S:X="" X=ORSDFLT
  1.  S %DT="EX"
  1.  D ^%DT
  1.  I X["?" K DAY G D1
  1.  I Y<1 W $C(7),?40,"Invalid Date." K DAY G D1
  1.  S ORSSTRT=Y-.7641_"^"_$$FMTE^XLFDT(Y-.7641),ORSSTOP=Y+.2359_"^"_$$FMTE^XLFDT(Y+.2359)
  1.  Q
  1. RANGE(X1,X2) ; Get a date range for printing
  1.  ;X1=Default Start Date/time
  1.  ;X2=Default Stop Date/time
  1.  N %DT,%T,ORSDFLT,X,Y
  1.  I $D(ORPRES),+ORPRES=6!(+ORPRES=15)!(+ORPRES=16)!(+ORPRES=17) S (ORSSTRT,ORSSTOP)="" Q
  1. R ;
  1.  S OREND=0,ORSDFLT=$S($G(X1)>0:$S($P(X1,".",2)=2359:X1+.7641,1:X1),1:"T")
  1.  W !!,"Start Date [Time]: "_$S(ORSDFLT>0:$$DATE^ORU(ORSDFLT,"AMTH DD, CCYY"),1:ORSDFLT)_"// "
  1.  R X:$S($D(DTIME):DTIME,1:300)
  1.  S:X="^"!('$T) (OREND,XQORPOP)=1
  1.  Q:OREND
  1.  S:X="" X=ORSDFLT
  1.  S %DT="EXT"
  1.  D ^%DT
  1.  G R:X["?"
  1.  I Y<1 W ?55,"Invalid Start Date/time." G R
  1.  S ORSSTRT=Y
  1. E ; Get Ending Date/time
  1.  S ORSDFLT=$S($G(X2):$S($P(X2,".",2)'=2359:$P(X2,".")_".2359",1:X2),$G(ORSSTRT):$S($P(ORSSTRT,".",2)=2359:(ORSSTRT+.7641)_".2359",1:$P(ORSSTRT,".")_".2359"),1:"T@2359")
  1.  W !!,"Ending Date [Time] (inclusive): "_$S(+ORSDFLT>0:$$DATE^ORU(ORSDFLT,"AMTH DD, CCYY HR:MIN"),1:ORSDFLT)_"// "
  1.  R X:$S($D(DTIME):DTIME,1:300)
  1.  S:X="^"!('$T) (OREND,XQORPOP)=1
  1.  Q:OREND
  1.  S:X="" X=ORSDFLT
  1.  S %DT="EXT"
  1.  D ^%DT
  1.  G E:X["?"
  1.  I Y<1 W ?57,"Invalid End Date/time." G E
  1.  S ORSSTOP=Y
  1.  I ORSSTOP<ORSSTRT S X=ORSSTOP,ORSSTOP=ORSSTRT,ORSSTRT=X
  1.  S ORSSTOP=$S($L(ORSSTOP,".")=2:ORSSTOP,1:ORSSTOP+1)_"^"_$$FMTE^XLFDT(ORSSTOP)
  1.  S ORSSTRT=$S($L(ORSSTRT,".")=2:ORSSTRT,1:ORSSTRT-.7641)_"^"_$$FMTE^XLFDT(ORSSTRT)
  1.  Q
  1. CUSTOM ; Selects order status and display group
  1.  N %,%Y,C,DIC,I,X,Y,XQORM,XQORSPEW,XQORNOD
  1.  S ORBUF=1
  1.  I $D(DIROUT)!($D(DTOUT)) S (OREND,XQORPOP)=1 Q
  1.  S:'$D(ORPRES) ORPRES="2;ACTIVE ORDERS"
  1.  D PRES^ORPRS09
  1.  I $G(OREND) S XQORPOP=1 Q
  1.  D SERV^ORPRS09
  1.  I $G(OREND) S XQORPOP=1 Q
  1.  Q
  1. HSTS(X) ;Help for status descriptions (ORRP STATUS MENU protocol)
  1.  W !,"Valid selections are: "
  1.  I X["???" W ! D HACT1 W ! Q  ;show descriptions and quit
  1.  D DISP^XQORM1
  1.  W !
  1.  Q
  1. HACT1 ;
  1.  K ^TMP("ORRX",$J)
  1.  S Y=0 F I=0:0 S Y=$O(^ORD(101,+XQORNOD,10,Y)) Q:Y'>0  I $D(^ORD(101,+XQORNOD,10,Y,0)) S W=^(0),^TMP("ORRX",$J,$P(W,"^",3))=W
  1.  S Y=0 F I=1:1 S Y=$O(^TMP("ORRX",$J,Y)) Q:Y'>0  S X1=^(Y),W=+X1 D:I=20 READ^ORUTL W !,$P(X1,"^",2),?5 I W,$D(^ORD(101,W,0)) W $P(^(0),"^",2) I $P(^(0),"^",2)'="   ",$D(^ORD(101,W,1,1,0)) W " - "_^(0)
  1.  K W,X,^TMP("ORRX")
  1.  Q
  1. EN(ORDG,ORSEL) ;Setup/Display groups
  1.  ;ORDG(optional)=ptr to display group to setup (All is the default)
  1.  ;ORSEL(optional)=Line label of action to take (BILD<default>, DISP)
  1.  ;Returns: ORGRP if ORSEL="BILD"
  1.  I $G(ORSEL)'="DISP" S ORSEL="BILD"
  1.  I '$G(ORDG) S ORDG=1 ;All if not specified
  1.  N ORMEM,ORSTK
  1.  S ORSTK=0
  1.  D @ORSEL
  1.  S ORSTK=1,ORSTK(ORSTK)=ORDG_"^0",ORSTK(0)=0,ORMEM=0
  1.  F I=0:0 S ORMEM=$O(^ORD(100.98,+ORSTK(ORSTK),1,ORMEM)) D @$S(+ORMEM'>0:"POP",1:"PROC") Q:ORSTK<1
  1.  Q
  1. POP ;
  1.  S ORSTK=ORSTK-1,ORMEM=$P(ORSTK(ORSTK),"^",2)
  1.  Q
  1. PROC ;
  1.  S $P(ORSTK(ORSTK),"^",2)=ORMEM,ORDG=$P(^ORD(100.98,+ORSTK(ORSTK),1,ORMEM,0),"^",1)
  1.  D @ORSEL
  1.  S ORSTK=ORSTK+1,ORSTK(ORSTK)=ORDG_"^0",ORMEM=0
  1.  Q
  1. DISP ;
  1.  I $Y>(IOSL-4) D READ^ORUTL W @IOF
  1.  S W=^ORD(100.98,ORDG,0)
  1.  W !,?((ORSTK*2)),$P(W,"^")
  1.  Q
  1. BILD ;
  1.  S ORGRP(ORDG)=""
  1.  Q
  1. STOP ; Call DIR at bottom of screen
  1.  N DIR,X,Y
  1.  Q:$E(IOST)'="C"
  1.  I IOSL>($Y+5) F  W ! Q:IOSL<($Y+6)
  1.  S DIR(0)="FO^1:1",DIR("A")="Press RETURN to continue or '^' to exit"
  1.  S DIR("?")="Enter '^' to quit present report or '^^' to quit to menu"
  1.  D ^DIR
  1.  Q
  1. TERM(IOST) ;Setup terminal display values
  1.  ;IOST=Terminal type
  1.  ;Returns ORTERM(5)=REVERSE VIDEO ON^REVERSE VIDEO OFF
  1.  ;        ORTERM(7)=HIGH INTENSITY^LOW INTENSITY^NORMAL INTENSITY
  1.  S (ORTERM(7),ORTERM(5))=""
  1.  I $D(IOST),$L(IOST) S X=$O(^%ZIS(2,"B",IOST,0)) I X,$D(^%ZIS(2,X)) S ORTERM(5)=$S($D(^(X,5)):$P(^(5),"^",4,5),1:""),ORTERM(7)=$S($D(^(7)):$P(^(7),"^",1,3),1:"") S:'$L($P(ORTERM(7),"^",3)) $P(ORTERM(7),"^",3)=$P(ORTERM(7),"^",2)
  1.  F I=1:2:3 I '$L($P(ORTERM(7),"^",I)) S ORTERM(7)="" Q
  1.  Q