Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSBVAR

PSBVAR.m

Go to the documentation of this file. 
  1. PSBVAR ;BIRMINGHAM/EFC-BCMA VARIANCE LOG FUNCTIONS ;Mar 2004
  1.  ;;3.0;BAR CODE MED ADMIN;*31*;Mar 2004;Build 1
  1.  ;Per VHA Directive 2004-038, this routine should not be modified.
  1.  ;
  1.  ; Reference/IA
  1.  ; ^DPT/10035
  1.  ; ^DIC(42/10039
  1.  ;
  1. EN ;
  1.  Q
  1.  ;
  1. CHKPRN(DFN,PSBMIN,PSBLOG) ;
  1.  Q:PSBMIN=""
  1.  Q:PSBMIN'>$$GET^XPAR("DIV","PSB ADMIN PRN EFFECT")
  1.  D ADD(.RESULTS,DFN,3,PSBMIN,"",PSBLOG)
  1.  Q
  1.  ;
  1.  ;CHECK^PSBVAR() calling point is used to create a new variance entry.  Triggered by Order Administration Variance Field # 14 in the BCMA Medication Log File (#53.79).
  1.  ;
  1. CHECK(DFN,PSBMIN,PSBLOG) ;
  1.  Q:PSBMIN=""
  1.  N RESULTS
  1.  ; Checks the timing from the Med Log Entry X-Ref
  1.  I PSBMIN<0 D:(PSBMIN*-1)>$$GET^XPAR("DIV","PSB ADMIN BEFORE") ADD(.RESULTS,DFN,2,PSBMIN,"",PSBLOG)
  1.  I PSBMIN>0 D:PSBMIN>$$GET^XPAR("DIV","PSB ADMIN AFTER") ADD(.RESULTS,DFN,2,PSBMIN,"",PSBLOG)
  1.  Q
  1.  ;
  1. ADD(RESULTS,DFN,PSBEVNT,PSBMIN,PSBDRUG,PSBLOG) ;
  1.  ;
  1.  ; DFN:      Patient File (#2) Pointer
  1.  ; PSBEVNT:  Event Code (See DD for 53.78)
  1.  ; PSBMIN:   Minutes off of schedule (Optional)
  1.  ; PSBDRUG:  Drug File (#50) Pointer (Optional)
  1.  ; PSBLOG:   BCMA Med Log IEN (Optional)
  1.  ;
  1.  ;Do not create variance for med order with missing dose status.
  1.  I $G(PSBLOG),$P($G(^PSB(53.79,PSBLOG,0)),U,9)="M" Q
  1.  ;
  1.  N PSBDT,PSBRB,PSBWRD,PSBXX
  1.  ;
  1.  D EN^DDIOL("Filing Variance...")
  1.  D NOW^%DTC
  1.  L +(^PSB(53.78,0)):5 E  S RESULTS(0)="-1^Variance Log Locked" Q
  1.  S PSBXX=$O(^PSB(53.78,"A"),-1)+1
  1.  S $P(^PSB(53.78,0),U,3)=PSBXX
  1.  S $P(^PSB(53.78,0),U,4)=$P(^PSB(53.78,0),U,4)+1
  1.  ;
  1. WARD ;Extract the ward and room/bed information.
  1.  ;DFN is pre-defined.
  1.  S PSBRB=$P($G(^DPT(DFN,.101)),U)
  1.  S PSBRB=$S(PSBRB'="":PSBRB,1:"***")
  1.  S PSBWRD=$P($G(^DPT(DFN,.1)),U)
  1.  ;Convert Ward Name to Ward IEN
  1.  I PSBWRD'="" D
  1.  . S PSBDT=%
  1.  . S PSBWRD=$$FIND1^DIC(42,"","X",PSBWRD,"","","ERR")
  1.  . S %=PSBDT ;reset after $$FIND1^DIC fileman call
  1.  S PSBWRD=$S($G(PSBWRD):PSBWRD,1:"***")
  1.  ;
  1.  ; Set Variance Entry
  1.  S ^PSB(53.78,PSBXX,0)=DFN_U_PSBRB_U_DUZ_U_%_U_PSBEVNT_U_$G(PSBMIN)_U_$G(PSBDRUG)_U_$G(PSBLOG)_U_PSBWRD
  1.  ;
  1.  S ^PSB(53.78,"ADT",%,PSBXX)=""
  1.  S ^PSB(53.78,"B",DFN,PSBXX)=""
  1.  L -(^PSB(53.78,0))
  1.  S RESULTS(0)="1^Data Filed"
  1.  Q
  1.  ;
  1.  ; Unable to UPDATE^DIE WHILE IN UPDATE^DIE
  1.  W !,"Filing Variance..."
  1.  D EN^DDIOL("Filing Variance...")
  1.  N PSBVFDA,PSBVMSG,PSBVIEN
  1.  D VAL(.01,"`"_DFN) ; Patient Pointer
  1.  S Y=$G(^DPT(DFN,.1),"Unk Ward")_" "_$G(^DPT(DFN,.101),"Unk Bed")
  1.  D VAL(.02,Y) ; Patient Location
  1.  D VAL(.03,"`"_DUZ) ; New Person Pointer
  1.  D VAL(.04,"NOW") ; DT Entered
  1.  D VAL(.05,PSBEVNT) ; Event Code
  1.  D:$G(PSBMIN) VAL(.06,PSBMIN) ; Minutes Early/Late
  1.  D:$G(PSBDRUG) VAL(.07,"`"_PSBDRUG) ; Drug File Pointer
  1.  D:$G(PSBLOG) VAL(.08,"`"_PSBLOG)
  1.  ; Call UPDATE^DIE and set Results(0)
  1.  D UPDATE^DIE("","PSBVFDA","PSBVIEN","PSBVMSG")  ; PSBVFDA set into file 53.68, BCMA MEDICATION VARIANCE LOG at VAL+3
  1.  I $D(PSBVMSG) S RESULTS(0)="-1^"_PSBVMSG("DIERR",1)_": "_PSBVMSG("DIERR",1,"TEXT",1)
  1.  E  S RESULTS(0)="1^Data Successfully Filed^"_PSBVIEN(1)
  1.  W !,RESULTS(0)
  1.  Q
  1.  ;
  1. VAL(PSBVFLD,PSBVVAL) ;
  1.  N PSBVRET
  1.  K ^TMP("DIERR",$J)
  1.  D VAL^DIE(53.78,"+1,",PSBVFLD,"F",PSBVVAL,.PSBVRET,"PSBVFDA")
  1.  I PSBVRET="^" F X=0:0 S X=$O(^TMP("DIERR",$J,X)) Q:'X  S Y=^TMP("DIERR",$J,X)_": "_$G(^(X,"TEXT",1),"**"),RESULTS($O(RESULTS(""),-1)+1)="Data Validation Error: "_Y
  1.  K ^TMP("DIERR",$J)
  1.  Q
  1.  ;